VBA 移除用户窗体右上角关闭按钮

chunyu.wu

于 2024-09-12 14:09:20 发布

阅读量86

点赞数

分类专栏： VBA 文章标签： UserForm

原文链接：https://worksheetsvba.com/en/remove-close-button-from-userform

版权

VBA 专栏收录该内容

64 篇文章 3 订阅

订阅专栏

1. 用户窗体

2. 标准模块代码

在标准模块中加入如下代码：

Option Explicit

Private Const GWL_STYLE As Long = -16
Private Const WS_SYSMENU As Long = &H80000

Private Declare PtrSafe Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As LongPtr
#If Win64 Then
    Private Declare PtrSafe Function GetWindowLong Lib "user32" Alias "GetWindowLongPtrA" (ByVal hWnd As LongPtr, ByVal nIndex As Long) As LongPtr
    Private Declare PtrSafe Function SetWindowLong Lib "user32" Alias "SetWindowLongPtrA" (ByVal hWnd As LongPtr, ByVal nIndex As Long, ByVal dwNewLong As LongPtr) As LongPtr
#Else
    Private Declare PtrSafe Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hWnd As LongPtr, ByVal nIndex As Long) As LongPtr
    Private Declare PtrSafe Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As LongPtr, ByVal nIndex As Long, ByVal dwNewLong As LongPtr) As LongPtr
#End If

Public Sub RemoveCloseButton(frm As Object)
    #If VBA7 Then
        Dim lStyle As LongPtr, lFrmHandle As LongPtr
    #Else
        Dim lStyle As Long, lFrmHandle As Long
    #End If
    lFrmHandle = FindWindow("ThunderDFrame", frm.Caption)
    lStyle = GetWindowLong(lFrmHandle, GWL_STYLE)
    lStyle = lStyle And Not WS_SYSMENU
    SetWindowLong lFrmHandle, GWL_STYLE, lStyle
End Sub

3. 用户窗体代码

在用户窗体中加入如下代码

Option Explicit

Private Sub UserForm_Initialize()
    RemoveCloseButton Me
End Sub

Private Sub btnClose_Click()
    Unload FrmRemoveCloseButton
End Sub