sourceinsight40120多行注释兼容空行-CSDN博客

本文链接：https://blog.csdn.net/xiangnengji/article/details/114659129

1.打开SourceInsight，【Project】->【Open Project】
2.打开base项目是一个后缀.em的文件
3.在utils.em代码最后添加如下代码


macro Code2Comments()
{
	hwnd = GetCurrentWnd()
	selection = GetWndSel( hwnd )
	lnFirst = GetWndSelLnFirst( hwnd )
	lnLast = GetWndSelLnLast( hwnd )

	hbuf = GetCurrentBuf()

	ln = lnFirst
	buf = GetBufLine( hbuf, ln )
	len = strlen( buf )
	firststart = len
	while( ln <= lnLast )
	{
		buf = GetBufLine( hbuf, ln )
		len = strlen( buf )
		start = 0
		while( start < len )
		{
			if( strmid( buf, start, start + 1 ) == CharFromAscii(32) || strmid( buf, start, start + 1 ) == CharFromAscii(9) )
			{
				start = start + 1
				if( start > len )
					break
			}
			else
				break
		}
		if( start < len && start < firststart )
		{
			firststart = start
		}
		ln = ln + 1
	}

	ln = lnFirst
	while( ln <= lnLast )
	{
		buf = GetBufLine( hbuf, ln )
		len = strlen( buf )
		if( len > 0 )
		{
			buf2 = cat( cat( strmid( buf, 0, firststart ), "//" ), strmid( buf, firststart, len ) )
			PutBufLine ( hbuf, ln, buf2 )
		}
		ln = ln + 1
	}
	SetWndSel( hwnd, selection )
}

macro Comments2Code()
{
	hwnd = GetCurrentWnd()
	selection = GetWndSel( hwnd )
	lnFirst = GetWndSelLnFirst( hwnd )
	lnLast = GetWndSelLnLast( hwnd )

	hbuf = GetCurrentBuf()
	ln = lnFirst
	while( ln <= lnLast )
	{
		buf = GetBufLine( hbuf, ln )
		len = strlen( buf )
		if( len >= 2 )
		{
			start = 0

			while( strmid( buf, start, start + 1 ) == CharFromAscii(32) || strmid( buf, start, start + 1 ) == CharFromAscii(9) )
			{
				start = start + 1
				if( start >= len )
					break
			}
			if( start < len - 2 )
			{
				if( strmid( buf, start, start + 2 ) == "//" )
				{
					buf2 = cat( strmid( buf, 0, start ), strmid( buf, start + 2, len ) )
					PutBufLine( hbuf, ln, buf2 )
				}
			}
		}
		ln = ln + 1
	}
	SetWndSel( hwnd, selection )
}