gnuplot 画折线图

最新推荐文章于 2022-04-29 11:36:59 发布

xiaov58

最新推荐文章于 2022-04-29 11:36:59 发布

阅读量4.5k

点赞数

分类专栏：实用文章标签： terminal thread output linux 图形

实用专栏收录该内容

3 篇文章 0 订阅

订阅专栏

相信很多人用过gnuplot画图。这里我也不罗嗦这个软件是干什么的了。直接贴例子来解释它的用法：
比如我们如果要画折线图的话可以用下面的例子：

#本文示例是画折线图。
set title "A demonstration of gnuplot"
set grid

#下面这一行是用来描述图的每根线代表的意义的那个框框的属性。在本例中就是“Throutput-WorkLoad”　
#其中right top表示位置显示。　Left 表示框子里的字左对齐。　width X用来限定框子大小。
#box X用来表示选用哪种类型的框子--颜色可能不同。这里在png图里，如果width是0的画，会显得box很
#大，但是，没有关系，如果把它改成jpg格式的话，box正好合适。
set key right top Left reverse width 0 box 3

#下面这两行用来表示x,y轴的意思。引号内的内容会显示在图的轴旁边。
#其中，右边的两个数字表示引号内的内容在图中与x,y轴之间的相对距离。
#第一个0代表水平方向。第二个代表垂直方向。
set xlabel "Number of workload thread" 0,0
set ylabel "Throughput(%)" 0,0

#下面这一行非常重要。它表示你的x或者y轴的显示范围。
#有的时候图形并不一定要从0开始显示。就可以在这里设置。比如这里的y轴零点就是80.
set yrange [80:100]

#下面两行是用来标注x,y轴的标度。引号内的内容是显示时的标度。没有打引号的是真实的度量。
set xtics ("0" 0,"5" 5,"10" 10,"15" 15,"20" 20,"25" 25,"30" 30,"35" 35,"40" 40,"45" 45,"50" 50)
set ytics ("80" 80,"85" 85,"90" 90,"95" 95,"100" 100)

#下面这一行是用来限制图的大小。但是不包括前面第二行中讲的那个box。
#"0.7"表示横向的相对大小　"0.6"表示纵向的相对大小。
set size 0.7,0.6

#画图中断类型。这里是windows.这个gnuplot有linux版本。
set terminal windows

#这里就是用来指定画图的数据来自"t_w_1_date.txt"文件。这个文件很好写。只需要把你要画的数据写成两列。
#左边一列是x周的数据,右边一列是y轴的数据。　tittle表示你这根线要用什么标示。它会显示在前面第二行所
#述的那个box里面。with指定线的类型。这里也可以同时制定画多条线对比。例如：
#plot "t_w_1_date.txt" title "Throughput-Workload" with linespoints,"t_w_2_date.txt" title
#"Throughput-Workload2" with linespoints, ...
plot "t_w_1_date.txt" title "Throughput-Workload" with linespoints

#下面两行用来标示输出的图片的类型。好像不支持jpg。但是你可以直接把文件改名为jpg.
set terminal png
set output "t_w_1.png"

replot

************************************************************************************************************************
#下面是上面例子的数据文件
1    98.23
2    97.08
3    96.95
5    94.30
8    92.91
13    90.63
21    88.58
34    85.93
40    84.55
48    84.64
50    83.15

**************************************************************************************************************************
运行gnuplot,在提示符下输入 load "t_w_1.txt" 回车，输出如下：