CDS View-Part11 实例消费CDS View

原文：
https://sapyard.com/how-to-consume-cds-view-in-smart-business-service-kpi-fiori-apps/
尊重版权，仅供个人学习

CDS Annotation online help:
https://help.sap.com/viewer/cc0c305d2fab47bd808adcad3ca7ee9d/1709%20000/en-US/630ce9b386b84e80bfade96779fbaeec.html

本文主要是用一个实际的例子演示了如何创建和消费CDS View并且不需编写代码就可以配置出一个KPI 磁贴。

需求：创建一个分析应用程序，以分析用户输入的特定年份的销售文档行项目级别的退货数量，根据客户和周期(月)进行分组。

后台创建 CDS View并发布为OData

先整体说一下，免得后面看晕了

1. 创建一个取明细数据的#BASIC 类型的View ‘ZGJZ_I_DEMO_CUST’，取的都是基础字段，包括字符串处理的MON 和 YYEAR。
2. 在第一个view的基础上汇总数据，创建一个#COMPOSITE类型的view ‘ZGJZ_C_DEMO_CUSTCNT’，这时有了分组汇总字段。
3. 使用第一个view做主数据源，Associate第二个View，再加上选择参数‘P_MJAHR’创建第三个#COMPOSITE类型的view ‘ZGJZ_C_DEMO_CUSTCOMB’，关联字段使用‘kunnr’ ‘MON’ ‘YYEAR’，此时要加入 @Aggregation.default: #SUM 声明了measure字段。
4. 使用第三个View创建一个带参数的#CONSUMPTION类型的View ‘ZGJZ_C_DEMO_CUSTANA’，这里将其发布为OData，并且使用@Analytics.query: true将其分类，这是一个Query View。
   ADT提供了一个很好的工具可以直观看到对象的dependency关系，这在分析复杂的View时非常有用。
   
   

• 创建CDS Basic View 'ZGJZ_I_DEMO_CUST' 分别从表VBAK/VBAP/TVAGT取销售订单头、行项目以及拒绝原因描述。
  参考代码

@AbapCatalog.sqlViewName: 'ZGJZIDEMOCUST'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #BASIC
@EndUserText.label: 'Basic View for customer rejection'
define view ZGJZ_I_DEMO_CUST
  as select from    vbak
    inner join      vbap  on  vbak.vbeln = vbap.vbeln
                          and vbap.abgru != ''
    left outer join tvagt on  vbap.abgru = tvagt.abgru
                          and spras      = 'E'
{
      @EndUserText.label: 'Sale Document No'
  key vbak.vbeln,
      @EndUserText.label: 'Line Item No'
      vbap.posnr,
      @EndUserText.label: 'Material'
      vbap.matnr,
      @EndUserText.label: 'Description'
      vbap.arktx,
      @EndUserText.label: 'Customer Number'
      vbak.kunnr,
      @EndUserText.label: 'Reason For Rejection'
      vbap.abgru,
      @EndUserText.label: 'Description'
      tvagt.bezei,
      @EndUserText.label: 'Document No Date'
      vbak.audat,
      @EndUserText.label: 'Month'
      substring(vbak.audat,5,2) as MON,
      @EndUserText.label: 'Year'
      substring(vbak.audat,1,4) as YYEAR
}

1. annotation标签 @VDM.viewType: #BASIC 声明虚拟数据模型VDM的类型(VDM旨在由视图浏览器和其他基于虚拟数据模型的功能框架来解析。)。BASIC:没有数据冗余的形成核心数据基础的视图。
2. 这里用了一个annotation标签 @EndUserText.label: 'xxx' 顾名思义，文本标签

• 创建带参数CDS Composite View 'ZGJZ_C_DEMO_CUSTCNT'
  

1. @Analytics:{ dataCategory: #CUBE, dataExtraction.enabled: true}，这两个属性可以参考分别对应了：Query通常构建在#CUBE类型的View之上，其中的数据是从facts表中复制的；标记适合进行数据复制的视图。
2. @VDM.viewType: #COMPOSITE显式声明VDM View Type，COMPOSITE : 由基本视图派生和/或组成的数据视图。
3. @EndUserText.label: 'Year'文本标签
4. @Aggregation.default: #SUM这里将其声明为Measure

• 组合CDS View创建分析数据集和复合虚拟数据模型(VDM)视图ZGJZ_C_DEMO_CUSTCOMB

@AbapCatalog.sqlViewName: 'ZGJZCDEMOCUSTCOM'
//@AbapCatalog.compiler.compareFilter: true
//@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_ALLOWED
@EndUserText.label: 'Customer Rejection Analysis'
@VDM.viewType: #COMPOSITE
@Analytics:{dataCategory: #CUBE, dataExtraction.enabled: true}
define view ZGJZ_C_DEMO_CUSTCOMB
  with parameters
    @EndUserText.label: 'Year'
    P_MJAHR : mjahr
  as select from ZGJZ_C_DEMO_CUSTCNT
                 (P_MJAHR :$parameters.P_MJAHR)
  association [1] to ZGJZ_I_DEMO_CUST as _DETAIL on  $projection.kunnr = _DETAIL.kunnr
                                                 and $projection.MON   = _DETAIL.MON
                                                 and $projection.YYEAR = _DETAIL.YYEAR
{
      @EndUserText.label: 'Customer Number'
  key kunnr,
      @EndUserText.label: 'Month'
      MON,
      @EndUserText.label: 'Fiscal Year'
      YYEAR,
      @EndUserText.label: 'No of Rejections'
      @Aggregation.default: #SUM
      cast(Reject as abap.curr( 4, 0 ) ) as reject,
      @EndUserText.label: 'Document No'
      _DETAIL.vbeln,
      @EndUserText.label: 'Line Item No'
      _DETAIL.posnr,
      @EndUserText.label: 'Material'
      _DETAIL.matnr,
      @EndUserText.label: 'Description'
      _DETAIL.arktx,
      @EndUserText.label: 'Reason For Rejecton'
      _DETAIL.abgru,
      @EndUserText.label: 'Reason Description'
      _DETAIL.bezei
}

1. 还没有搞清楚的Annotation即使是模版带出来的也别乱用
2. COPOSITE类型VDM View
3. 这里使用$projection和view名是一样的
4. 将字段声明为measure

• 创建最终要被发布为OData的CONSUMPTION类型View 'ZGJZ_C_DEMO_CUSTANA'

@AbapCatalog.sqlViewName: 'ZGJZCDEMOCUSTANA'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_ALLOWED
@EndUserText.label: 'Customer Rejection Analysis'
@VDM.viewType: #CONSUMPTION
@Analytics.query: true
@OData.publish: true
@Metadata.ignorePropagatedAnnotations: true
@Analytics.dataExtraction.enabled: true
define view ZGJZ_C_DEMO_CUSTANA
  with parameters
    @EndUserText.label: 'Year'
    P_MJAHR : mjahr
  as select from ZGJZ_C_DEMO_CUSTCOMB
                 (P_MJAHR : $parameters.P_MJAHR)
{
      @EndUserText.label: 'Customer Number'
  key kunnr,
      @EndUserText.label: 'Month'
      MON,
      @EndUserText.label: 'Year'
      YYEAR,
      @EndUserText.label: 'No of Rejections'
      @Aggregation.default: #SUM
      REJECT,
      @EndUserText.label: 'Document No'
      VBELN,
      @EndUserText.label: 'Line Item No'
      posnr,
      @EndUserText.label: 'Material'
      matnr,
      @EndUserText.label: 'Description'
      arktx,
      @EndUserText.label: 'Reason for Rejection'
      abgru,
      @EndUserText.label: 'Reason Description'
      bezei
}

1. @VDM.viewType: #CONSUMPTION 是基于基本视图、复合视图或事务视图定义的消费类型视图
2. @Analytics.query: true将其分类，说明这是一个Query View。
3. @OData.publish: true 激活后自动发布为OData
4. @Aggregation.default: #SUM 字段为measure字段

根据CDS View使用应用’Create KPI’创建磁贴应用

首先要将后台的服务添加到前台，TCODE:/IWFND/MAINT_SERVICE



测试服务，这时可以发现自动自成了两个EntitySets

尝试执行其中一个entityset时报错，no parameter provided，正常，忽略它先

打开 LPD，找到应用 ‘Create KPI’，如果没有从Fiori Libuary中找到按要求配置出来即可，这里就不介绍这个了。

填入标题和描述

选择视图和相应的OData服务以及EntitySet，使用F4填写很方便

如果这里没有正常搜到刚做的CDS View或是Odata服务，一定是CDS View创建的有问题，更正问题后记得刷新服务元数据 ，点击’激活并添加评估’按钮

填入评估描述

以及取值参数，然后点击’激活并配置磁贴’按钮

选择磁贴样式以及填写目录信息和语义对象信息，语义对象是通过TOCDE /ui2/semobj创建的，然后点击’保存并配置下钻’按钮

点击’配置’按钮

先配置一个summary视图，选择’Customer Number’ ‘Month’ ‘Year’三个字段，这也是最初的需求。

切换统计图的类型，默认应该是条形图，这里切换为’柱状图’

再添加一个下钻

显示详细信息字段

切换统计图类型为’表’，保存，此时磁贴会生成成功。

回到用户LPD，使用应用查找器找到这个磁贴，显示磁贴

以下是结果演示：