【SDOI2010】星际竞速

题目

10年一度的银河系赛车大赛又要开始了。作为全银河最盛大的活动之一，夺得这个项目的冠军无疑是很多人的梦想，来自杰森座α星的悠悠也是其中之一。
　　赛车大赛的赛场由N颗行星和M条双向星际航路构成，其中每颗行星都有一个不同的引力值。大赛要求车手们从一颗与这N颗行星之间没有任何航路的天体出发，访问这N颗行星每颗恰好一次，首先完成这一目标的人获得胜利。
　　由于赛制非常开放，很多人驾驶着千奇百怪的自制赛车来参赛。这次悠悠驾驶的赛车名为超能电驴，这是一部凝聚了全银河最尖端科技结晶的梦幻赛车。作为最高科技的产物，超能电驴有两种移动模式：高速航行模式和能力爆发模式。在高速航行模式下，超能电驴会展开反物质引擎，以数倍于光速的速度沿星际航路高速航行。在能力爆发模式下，超能电驴脱离时空的束缚，使用超能力进行空间跳跃——在经过一段时间的定位之后，它能瞬间移动到任意一个行星。
　　天不遂人愿，在比赛的前一天，超能电驴在一场离子风暴中不幸受损，机能出现了一些障碍：在使用高速航行模式的时候，只能由每个星球飞往引力比它大的星球，否则赛车就会发生爆炸。
　　尽管心爱的赛车出了问题，但是悠悠仍然坚信自己可以取得胜利。他找到了全银河最聪明的贤者——你，请你为他安排一条比赛的方案，使得他能够用最少的时间完成比赛。

分析

这道题就是给你一个图，让你求遍历每一个点使得费用最小，且每个点只能走一次。
那么我们便可以去思考了，这道题的等价的是让你找方案的同时费用最小，那么自然就是最小费用最大流了。
我们接着去想如何建图。
我们先往最大流的角度去思考，那么就往每个点向源点和汇点连一条流量为x，费用为0边，才能保证这是流的出来的。
那么我们接着考虑x是多少，因为这题要求没个点只能走一次，所以x=1.
然后我们便可以相互连边。
但我们会发现，我们很难去处理瞬移，怎么办呢？
我们便可以拆点！
所以我们便大致确定了：
从源点向x’连费用为瞬移费用，容量为1的边。
从源点向x连费用为0，容量为1的边。
从源点向x连y’费用为高速费用，容量为1的边。（这个和上面的连边就是指这个点流1，也就是控制成每个点只能走一次）
从x’向汇点连费用为0，容量为1的边。（x’->T指的是已经走过这个点了）

代码

var
    i,n,m,nu,t,x,y,z,ans,ts:longint;
    dis:array[0..2001] of longint;
    d:array[1..100000] of longint;
    las,nex,b,f,v,re:array[0..60000] of longint;
    bz:array[0..2001] of boolean;
procedure insert(x,y,z,k:longint);
begin
    inc(nu);b[nu]:=y;nex[nu]:=las[x];las[x]:=nu;f[nu]:=z;v[nu]:=k;
    inc(nu);b[nu]:=x;nex[nu]:=las[y];las[y]:=nu;f[nu]:=0;v[nu]:=-k;
end;
function min(l,r:longint):longint;
begin
   if l<r then exit(l);exit(r);
end;
function spfa:boolean;
var l,r,p:longint;
begin
    l:=0;r:=1;d[1]:=0;fillchar(dis,sizeof(dis),127);fillchar(bz,sizeof(bz),false);dis[0]:=0;bz[0]:=true;
    while l<r do begin
    inc(l);p:=las[d[l]];
    while p<>0 do begin
        if (dis[b[p]]>dis[d[l]]+v[p])and(f[p]>0) then begin
           dis[b[p]]:=dis[d[l]]+v[p];re[b[p]]:=p;
           if not bz[b[p]] then begin bz[b[p]]:=true;inc(r);d[r]:=b[p];end;
        end;p:=nex[p];
    end;bz[d[l]]:=false;
    end;
    if dis[t]<>dis[2001] then ans:=ans+dis[t];
    exit(dis[t]<>dis[2001]);
end;
procedure find;
var x,sum,p:longint;
begin
    x:=t;sum:=maxlongint;
    while x<>0 do begin
       sum:=min(sum,f[re[x]]);x:=b[re[x]xor 1];
    end;x:=t;
    while x<>0 do begin
       dec(f[re[x]],sum);inc(f[re[x] xor 1],sum);x:=b[re[x]xor 1];
    end;
end;

begin
    readln(n,m);nu:=1;t:=n*2+1;
    for i:=1 to n do begin
        read(x);
        insert(0,i,1,0);
        insert(0,i+n,1,x);
        insert(i+n,t,1,0);
    end;
    for i:=1 to m do begin
        readln(x,y,z);
        if x>y then begin ts:=x;x:=y;y:=ts;end;
        insert(x,n+y,1,z);
    end;
    while spfa do
    find;
    writeln(ans);
end.