开机脚本之——下一页热键

开机脚本之——下一页热键

阅读小说等有上一页、下一页的页面时，如果网站没有自带方向键翻页，我们可以使用自己的热键来翻页。

start_01() {
  static init:=start_01()
  SetTitleMatchMode, 2  ;//匹配部分标题
  GroupAdd, MyBrowser, 360安全浏览器
  GroupAdd, MyBrowser, 360极速浏览器
  GroupAdd, MyBrowser, 搜狗高速浏览器
  GroupAdd, MyBrowser, 世界之窗浏览器
  GroupAdd, MyBrowser, 2345加速浏览器
  GroupAdd, MyBrowser, GreenBrowser
  GroupAdd, MyBrowser, Firefox
  GroupAdd, MyBrowser, Chrome
  GroupAdd, MyBrowser, ahk_class IEFrame
  GroupAdd, MyBrowser, ahk_class 360se5_Frame
  GroupAdd, MyBrowser, ahk_class 360se6_Frame
  GroupAdd, MyBrowser, ahk_class Chrome_WidgetWin_1
  GroupAdd, MyBrowser, ahk_class ShockwaveFlashFullScreen
}

*$ScrollLock:: Left_Right := !Left_Right  ;//设置一个开关热键

#If (Left_Right) and WinActive("ahk_group MyBrowser") and (A_Cursor!="IBeam")

$Right::  ;//下一页
$Left::   ;//上一页

js=
(LTrim Join`s
try {
  var Re=new RegExp("(下|后)(一|\s)*(页|頁|章|篇|翻)","i");
  var a=document.getElementsByTagName("A");
  for (var i=0;i<a.length;i++) {
    if (Re.test(a[i].innerHTML)) {
      if (a[i].href.substr(0,11).toLowerCase()=="javascript:")
        a[i].click();
      else
        document.location.href=a[i].href;
      break;
    }
  }
} catch (e){}
)
js:=InStr(A_ThisLabel,"Right") ? js : StrReplace(js,"下|后","上|前")

AhkRunJs(js)
return

AhkRunJs(js)
{
  js:="@javascript:" js
  Loop, 10
  {
    SendInput {Alt Down}d{Alt Up}
    Sleep, 50
    Loop
      Clipboard:=js
    Until (Clipboard=js)
    SendInput {Ctrl Down}v{Ctrl Up}
    Sleep, 50
    Loop
      Clipboard:=""
    Until (Clipboard="")
    SendInput {Home}{Del}{Ctrl Down}ac{Ctrl Up}
    ClipWait, 0.1
    if (Clipboard=SubStr(js,2))
    {
      SendInput {Enter}
      Sleep, 500
      return
    }
  }
}

#If