开机脚本之——限制单进程运行

飞跃-

于 2020-06-05 01:36:24 发布

阅读量531

点赞数 1

分类专栏： AutoHotkey 文章标签： AutoHotkey

本文链接：https://blog.csdn.net/xshlong1981/article/details/106562161

版权

AutoHotkey 专栏收录该内容

31 篇文章

订阅专栏

本文介绍了一个AutoHotkey脚本技巧，通过内置函数限制脚本仅以单个实例运行，避免重复启动，提高资源利用效率。适用于需要防止多次执行同一任务的场景。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

把这个函数丢到任何AHK脚本中，就可以限制单进程运行。

;-----------------------------
;  限制单进程运行  By FeiYue
;
;  用法：把本函数丢到任何脚本中，设定标记即可（修改001）
;-----------------------------

; 例子：同时启动10个本脚本，只会保留1个进程
#SingleInstance Off
MsgBox, 4096,, % A_Now
return

;-- 限制单进程运行  By FeiYue
OnlyOne(flag="") {
  static init:=OnlyOne("001")
  DetectHiddenWindows, % (bak:=A_DetectHiddenWindows) ? "On":"On"
  mypid:=DllCall("GetCurrentProcessId")
  flag:="Ahk_OnlyOne_Ahk<<" . flag . ">>"
  Gui, Ahk_OnlyOne_Ahk: Show, Hide, %flag%
  WinGet, list, List, %flag% ahk_class AutoHotkeyGUI
  Loop, % list
  IfWinExist, % "ahk_id " . list%A_Index%
  {
    WinGet, pid, PID
    IfEqual, pid, %mypid%, Continue
    WinClose, ahk_pid %pid% ahk_class AutoHotkey,, 3
    IfWinNotExist,,, Continue
    Process, Close, %pid%
    WinWaitClose
  }
  WinGet, list, List, %flag% ahk_class AutoHotkeyGUI
  IfNotEqual, list, 1, ExitApp
  DetectHiddenWindows, %bak%
}