MySQL 启动助手v1.0.bat 批处理

MySQL 启动助手v1.0.bat 批处理

 

测试：MySQL 5.5.25 绝对可以用。

 

今天写了一个方便MySQL 在Windows下启动和备份，等待小白来测试，有问题请留言告诉我，谢谢使用。

 

功能：1.启动服务 2.关闭服务 3.查询分析器 4.导出数据 5.导入数据 6.退出

 

使用说明：

1.请将下面的文件保存成 MySQL 启动助手v1.0.bat

2.直接在Windows下双击运行。

 

@echo off
title MySQL启动助手 v1.0

:: MySQL 用户名 
set USERNAME=root 
:: MySQL 密码 
set PASSWORD=123456

::设置保存路径
set BACKUP_NAME=%date:~0,4%%date:~5,2%%date:~8,2%^_%time:~0,2%%time:~3,2%%time:~6,2%

:menu
cls
echo.  ------------------------------------------------------------
echo.  +               欢迎使用MySQL启动助手                      +
echo.  +  指令菜单：                                              +
echo.  +  1.启动服务 2.关闭服务 3.查询分析器                      +
echo.  +  4.导出数据 5.导入数据 6.退出                            +
echo.  +                                                          +
echo.  +  温馨提醒：                                              +
echo.  +  1.请启动服务器后，再进行备份                            +
echo.  +  2.导出数据存放在当前目录，文件名(数据库名.日期_时间.sql)+
echo.  +  作者：风云无痕 QQ：925776958 版本 1.0 时间：2012-06-15  +
echo.  ------------------------------------------------------------
echo.  
echo.  日期：%date% 时间：%time%
echo.
set choose=""
set /p choose= 请输入指令[1/2/3/4/5/6]:
if /i "%choose%"=="1" (goto:start)
if /i "%choose%"=="2" (goto:stop)
if /i "%choose%"=="3" (goto:login)
if /i "%choose%"=="4" (goto:backup)
if /i "%choose%"=="5" (goto:import)
if /i "%choose%"=="6" (goto:exit)

:: 1 → start
:start
echo.
net start mysql
echo 服务启动完毕!
pause
goto:menu

:: 2 → stop
:stop
echo.
net stop mysql
echo 服务已关闭!
pause
goto:menu

:: 3 → login
:login
echo. 输入密码：
mysql -uroot -p
goto:menu

:: 4 → backup
: backup 
set /p DATABASES= 需要导出的数据库名字(多个用空格分隔):
echo. 开始导出数据库... 
for %%D in (%DATABASES%) do ( 
echo. 正在导出 %%D 数据库... 
mysqldump -u%USERNAME% -p%PASSWORD% %%D > %%D.%BACKUP_NAME%.sql 2>nul 
) 
echo. 完成数据库导出！
pause
goto menu

:: 5 → import
:import
set /p DATABASES= 需要导入的数据库名字:
set /p file_name= 需要导入的文件路径:
echo. 开始导入数据库... 
for %%D in (%file_name%) do ( 
echo. 正在导入 %%D 数据库... 
mysql -u%USERNAME% -p%PASSWORD% %DATABASES% < %%D 
) 
echo. 完成数据库导入！
pause
goto menu

:: 6 → exit
:exit
cls
echo. 谢谢使用MySQL启动助手...
ping -n 2 127.0.0.1>nul
exit