用32位指令编写程序
上面用补充机器码的方式编写32位指令实在是麻烦,我们可以把16位与32位指令分离,分别编写16位与32位程序,这样就方便多了。
kernelloader跳转到32位的kernel.asm程序
修改kernelloader.asm,源码如下:
[BITS 16]
jmp main
;--------------------------------------------------------------------------------------------------------
;;数据区说明(物理地址)
;;0x07c00 boot 程序
;;0x10000 kernelloader 程序 参见boot.asm
;;0x80000 kernel程序
;-------------------------------------------------------------------------------------------------------
gdt_entries equ 3 ;共有三个段描述符:null,os code32,os data32
pe equ 1 ;bit PE in CR0
null equ 0h
os_code32_sel equ 8h ;1,gdt,rpl=00
os_data32_sel equ 10h ;2,gdt,rpl=00
pdescr times 6 db 0
gdt_table times (gdt_entries*8) db 0
;--------------------------------------------------------------------------------------------------------
read_kernel: ;;读入 kernel 程序
push es
.rk:
mov ax , 0x8000 ;;kernel.bin 所在的段基址
mov es , ax
mov bx , 0 ;;写入到内存0x8000:0000 物理地址=0x80000
mov ah , 2
mov dl , 0 ;;驱动器号
mov ch , 0 ;;柱面(磁道)0
mov cl , 4 ;;第4个扇区开始
mov al , 1 ;;读入扇区数,每个扇区为 512B
int 0x13
jc .rk
pop es
ret
main:
mov ax,1000h
mov ds,ax
;;读入 kernel 程序
call read_kernel
;打开 A 20 地址线
mov ax , 0x2401
int 0x15
;[1]built up GDT table
cli
mov eax,gdt_table
;item 0:null descriptor,
mov dword[eax],0
mov dword[eax+4],0
add eax,8
;item 1,OS code32 descriptor,
;Base=00000000h,limit=0ffffh,G=1,D=1,type=a,dpl=0
mov word[eax],0ffffh
mov word[eax+2],0
mov byte[eax+4],00h
mov byte[eax+5],09ah
mov byte[eax+6],0c0h
mov byte[eax+7],00h
add eax,8
;item 2,OS data32 descriptor
;Base=00000000h,Limit=0ffffh,G=1,D=1,Type=2,DPL=0
mov word[eax],0ffffh
mov word[eax+2],0000h
mov byte[eax+4],00h
mov byte[eax+5],092h
mov byte[eax+6],0c0h
mov byte[eax+7],00h
add eax,8
;[2]built false GDT descriptor
mov word[pdescr+0],(gdt_entries*8)
mov dword[pdescr+2],gdt_table+00010000h
lgdt [pdescr]
;[3]enter into protected mode
;刷新CR0
mov eax,cr0
or eax,pe
mov cr0,eax
jmp flush
flush:
mov ax,os_data32_sel
mov ds,ax
mov es,ax
mov ss,ax
mov fs,ax
mov gs,ax
jmp dword os_code32_sel:0x80000 ;跳转到0x8000:0000保护模式 物理地址0x80000
kernel.asm,现在可以使用32位语句了,编写是不是变简单了?源码如下:
[BITS 32]
jmp start
start:
mov ebx,0B8900h
mov edi,ebx ;es:edi=0010:000b8900=0b8900h
mov al,'A'
mov ah,34h
stosw
jmp $
修改makefile
######################
#声明要编译的所有组成,这里的xxx是本工程名称,可以取任何名字,这里就用xxx
######################
xxx:out/boot.bin out/kernelloader.bin out/kernel.bin out/creat_img.exe out/write_in_img.exe A B C D
#开始对各部分编译,注意不是空格是Tab键
out/boot.bin:code/boot.asm
nasm code/boot.asm -o out/boot.bin
out/kernelloader.bin:code/kernelloader.asm
nasm code/kernelloader.asm -o out/kernelloader.bin
out/kernel.bin:code/kernel.asm
nasm code/kernel.asm -o out/kernel.bin
# 制作内核映象文件
out/creat_img.exe:code/creat_img.c
gpp code/creat_img.c -o out/creat_img.exe
# 执行dos命令,在final目录下生成a.img文件
A:
out/creat_img.exe final/a.img
# 写入文件,argv[1]=目标文件 argv[2]=源文件 argv[3]=写入偏移量
#在DOS下用法: write.exe a.img kernelloader.bin 512
out/write_in_img.exe:code/write_in_img.c
gpp code/write_in_img.c -o out/write_in_img.exe
# 执行dos命令,向a.img写入代码,内容是boot.bin
# 写入磁盘位置从0偏移量起始,占1个扇区512字节
B:
out/write_in_img.exe final/a.img out/boot.bin 0
# 执行dos命令,向a.img写入代码,内容是kernelloader.bin
# boot.bin已经占用了512字节,写入磁盘位置从512偏移量起始,占2个扇区1024字节
C:
out/write_in_img.exe final/a.img out/kernelloader.bin 512
# 执行dos命令,向a.img写入代码,内容是kernel.bin
# boot.bin+kernelloader.bin已经占用了512+1024 = 1536字节,写入磁盘位置从1536偏移量起始,占1个扇区512字节
D:
out/write_in_img.exe final/a.img out/kernel.bin 1536
######################
boot.asm读取扇区数值改变2
运行模拟器,结果显示如图: