第 9 步:选择静态或动态库
在本节中,我们将展示如何使用BUILDSHAREDLIBS变量控制add_library()的默认行为, 并允许控制如何构建没有显式类型 ( STATIC、SHARED、 MODULE或OBJECT)的库。
为此,我们需要添加BUILDSHAREDLIBS到顶层CMakeLists.txt。我们使用option()命令,因为它允许用户有选择地选择该值是否应该是ON或OFF。
接下来我们将重构MathFunctions成为一个用mysqrt或sqrt封装起来的真正的库,而不是要求调用代码来做这个逻辑。这也意味着USE_MYMATH不会控制生成MathFunctions,而是会控制这个库的行为。
第一步是更新顶层CMakeLists.txt的起始部分, 如下所示:
*CMakeLists.txt*
cmake_minimum_required(VERSION 3.10)
# set the project name and version
project(Tutorial VERSION 1.0)
# specify the C++ standard
set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED True)
# control where the static and shared libraries are built so that on windows
# we don't need to tinker with the path to run the executable
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}")
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}")
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}")
option(BUILD_SHARED_LIBS "Build using shared libraries" ON)
# configure a header file to pass the version number only
configure_file(TutorialConfig.h.in TutorialConfig.h)
# add the MathFunctions library
add_subdirectory(MathFunctions)
# add the executable
add_executable(Tutorial tutorial.cxx)
target_link_libraries(Tutorial PUBLIC MathFunctions)
现在我们已经使 MathFunctionsalways 被使用,我们将需要更新该库的逻辑。因此,MathFunctions/CMakeLists.txt我们需要创建一个 SqrtLibrary,它会在 USE_MYMATH启用时有条件地构建和安装。现在,由于这是一个教程,我们将明确要求 SqrtLibrary 是静态构建的。
最终结果,MathFunctions/CMakeLists.txt应该如下所示:
*MathFunctions/CMakeLists.txt*
# add the library that runs
add_library(MathFunctions MathFunctions.cxx)
# state that anybody linking to us needs to include the current source dir
# to find MathFunctions.h, while we don't.
target_include_directories(MathFunctions
INTERFACE ${CMAKE_CURRENT_SOURCE_DIR}
)
# should we use our own math functions
option(USE_MYMATH "Use tutorial provided math implementation" ON)
if(USE_MYMATH)
target_compile_definitions(MathFunctions PRIVATE "USE_MYMATH")
# first we add the executable that generates the table
add_executable(MakeTable MakeTable.cxx)
# add the command to generate the source code
add_custom_command(
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/Table.h
COMMAND MakeTable ${CMAKE_CURRENT_BINARY_DIR}/Table.h
DEPENDS MakeTable
)
# library that just does sqrt
add_library(SqrtLibrary STATIC
mysqrt.cxx
${CMAKE_CURRENT_BINARY_DIR}/Table.h
)
# state that we depend on our binary dir to find Table.h
target_include_directories(SqrtLibrary PRIVATE
${CMAKE_CURRENT_BINARY_DIR}
)
target_link_libraries(MathFunctions PRIVATE SqrtLibrary)
endif()
# define the symbol stating we are using the declspec(dllexport) when
# building on windows
target_compile_definitions(MathFunctions PRIVATE "EXPORTING_MYMATH")
# install rules
set(installable_libs MathFunctions)
if(TARGET SqrtLibrary)
list(APPEND installable_libs SqrtLibrary)
endif()
install(TARGETS ${installable_libs} DESTINATION lib)
install(FILES MathFunctions.h DESTINATION include)
接下来,更新MathFunctions/mysqrt.cxx以使用mathfunctions和 detail命名空间:
*MathFunctions/mysqrt.cxx*
#include <iostream>
#include "MathFunctions.h"
// include the generated table
#include "Table.h"
namespace mathfunctions {
namespace detail {
// a hack square root calculation using simple operations
double mysqrt(double x)
{
if (x <= 0) {
return 0;
}
// use the table to help find an initial value
double result = x;
if (x >= 1 && x < 10) {
std::cout << "Use the table to help find an initial value " << std::endl;
result = sqrtTable[static_cast<int>(x)];
}
// do ten iterations
for (int i = 0; i < 10; ++i) {
if (result <= 0) {
result = 0.1;
}
double delta = x - (result * result);
result = result + 0.5 * delta / result;
std::cout << "Computing sqrt of " << x << " to be " << result << std::endl;
}
return result;
}
}
}
我们还需要对 tutorial.cxx进行一些更改,使其不再使用USE_MYMATH:
1.始终包括MathFunctions.h
2.始终使用mathfunctions::sqrt
3.不包括cmath
最后,更新MathFunctions/MathFunctions.h 以使用 dll 导出定义:
*MathFunctions/MathFunctions.h*
#if defined(_WIN32)
# if defined(EXPORTING_MYMATH)
#define DECLSPEC __declspec(dllexport)
# else
#define DECLSPEC __declspec(dllimport)
# endif
#else // non windows
# define DECLSPEC
#endif
namespace mathfunctions {
double DECLSPEC sqrt(double x);
}
此时,如果您构建所有内容,您可能会注意到链接失败,因为我们将没有位置无关代码的静态库与具有位置无关代码的库组合在一起。解决方案是显式设置 SqrtLibrary的目标属性 POSITIONINDEPENDENTCODE为 True,与构建类型无关。
*MathFunctions/CMakeLists.txt*
# state that SqrtLibrary need PIC when the default is shared libraries
set_target_properties(SqrtLibrary PROPERTIES
POSITION_INDEPENDENT_CODE ${BUILD_SHARED_LIBS}
)
target_link_libraries(MathFunctions PRIVATE SqrtLibrary)
练习:我们修改MathFunctions.h以使用 dll 导出定义。使用 CMake 文档你能找到一个帮助模块来简化这个吗?