Cmake中文教程（十一）【2022.05.12】

第 11 步：添加导出配置

在本教程的“安装与检测”一节中，我们添加了 CMake 安装项目的库和头文件的功能。在“封装与安装”一节中 ，我们添加了封装信息的功能，以便将其分发给其他人。

下一步是添加必要的信息，以便其他 CMake 项目无论是从构建目录、本地安装还是封装时都可以使用我们的项目。

第一步是更新我们的install(TARGETS)命令不仅可以指定 一个DESTINATION，还可以指定EXPORT。EXPORT关键字生成一个 CMake 文件，其中包含从安装树导入 install 命令中列出的所有目标的代码。因此，让我们继续通过MathFunctions/CMakeLists.txt更新命令来明确EXPORT库，如下所示：

MathFunctions/CMakeLists.txt 
set(installable_libs MathFunctions tutorial_compiler_flags)
if(TARGET SqrtLibrary)
  list(APPEND installable_libs SqrtLibrary)
endif()
install(TARGETS ${installable_libs}
        EXPORT MathFunctionsTargets
        DESTINATION lib)
install(FILES MathFunctions.h DESTINATION include)

现在我们已经有MathFunctions被导出，我们还需要显式安装生成的MathFunctionsTargets.cmake文件。这是通过将以下内容添加到顶层CMakeLists.txt文件的底部来完成的：

CMakeLists.txt 
install(EXPORT MathFunctionsTargets
  FILE MathFunctionsTargets.cmake
  DESTINATION lib/cmake/MathFunctions
)

此时您应该尝试运行 CMake。如果一切设置正确，您将看到 CMake 将生成如下错误：

Target "MathFunctions" INTERFACE_INCLUDE_DIRECTORIES property contains
path:
​
  "/Users/robert/Documents/CMakeClass/Tutorial/Step11/MathFunctions"
​
which is prefixed in the source directory.

CMake 想说的是，在生成导出信息期间，它将导出一个本质上与当前机器相关联的路径，并且在其他机器上无效。解决方法是更新 MathFunctions target_include_directories()以了解它在构建目录和安装/封装中使用时需要不同的INTERFACE位置。这意味着转换 target_include_directories()要求MathFunctions看起来像：

MathFunctions/CMakeLists.txt 
target_include_directories(MathFunctions
                           INTERFACE
                            $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
                            $<INSTALL_INTERFACE:include>
                           )

更新后，我们可以重新运行 CMake 并验证它不再发出警告。

此时，我们已经让 CMake 正确打包了所需的目标信息，但我们仍然需要生成一个MathFunctionsConfig.cmake，以便 CMakefind_package()命令可以找到我们的项目。所以让我们继续在项目的顶层添加一个新文件，其 Config.cmake.in内容如下：

Config.cmake.in 
​
@PACKAGE_INIT@
​
include ( "${CMAKE_CURRENT_LIST_DIR}/MathFunctionsTargets.cmake" )

然后，要正确配置和安装该文件，请将以下内容添加到顶层的底部CMakeLists.txt：

CMakeLists.txt 
install(EXPORT MathFunctionsTargets
  FILE MathFunctionsTargets.cmake
  DESTINATION lib/cmake/MathFunctions
)
​
include(CMakePackageConfigHelpers)

接下来，我们执行configure_package_config_file(). 此命令将配置提供的文件，但与标准有一些特定差异configure_file()方式。@PACKAGE_INIT@要正确使用此功能，输入文件除了所需内容外，还应包含一行文本。该变量将替换为将设置值转换为相对路径的代码块。这些新值可以用相同的名称引用，但前面带有PACKAGE_前缀。

CMakeLists.txt 
install(EXPORT MathFunctionsTargets
  FILE MathFunctionsTargets.cmake
  DESTINATION lib/cmake/MathFunctions
)
​
include(CMakePackageConfigHelpers)
​
#generate the config file that is includes the exports
​
configure_package_config_file(${CMAKE_CURRENT_SOURCE_DIR}/Config.cmake.in
  "${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfig.cmake"
  INSTALL_DESTINATION "lib/cmake/example"
  NO_SET_AND_CHECK_MACRO
  NO_CHECK_REQUIRED_COMPONENTS_MACRO
  )

接下来是write_basic_package_version_file()。此命令将所需包的版本和兼容性信息写入被“find_package”文档使用的文件中。在这里，我们使用Tutorial_VERSION_* 变量并说它与 AnyNewerVersion兼容，这表示该版本或任何更高版本与所需求的版本兼容。

CMakeLists.txt 
write_basic_package_version_file(
  "${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfigVersion.cmake"
  VERSION "${Tutorial_VERSION_MAJOR}.${Tutorial_VERSION_MINOR}"
  COMPATIBILITY AnyNewerVersion
)

最后，设置要安装的两个生成的文件：

CMakeLists.txt 
install(FILES
  ${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfig.cmake
  ${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfigVersion.cmake
  DESTINATION lib/cmake/MathFunctions
  )

至此，我们已经为我们的项目生成了一个可重定位的 CMake 配置，可以在项目安装或封装后使用。如果我们希望我们的项目也可以从构建目录中使用，我们只需将以下内容添加到顶层的底部CMakeLists.txt：

CMakeLists.txt 
export(EXPORT MathFunctionsTargets
  FILE "${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsTargets.cmake"
)

通过这个导出调用，我们现在生成一个Targets.cmake，允许其他项目使用构建目录中的MathFunctionsConfig.cmake配置，而无需安装它。