目录
1、下载JDK1.8并配置环境
关于怎么下载和配置本文不赘述,网络上自行搜索配置。
2、下载node并配置
关于怎么下载和配置本文不赘述,网络上自行搜索配置。
3、下载MYSQL并安装
关于怎么下载和配置本文不赘述,网络上自行搜索配置。
4、配置数据库
新建数据库,并执行若依项目下的sql文件夹里的quartz.sql和ry_20220625.sql两个脚本
5、下载Redis并设置开机启动
(1)下载地址
- Github下载地址:Releases · microsoftarchive/redis · GitHub
(2)安装并设置开机启动
解压压缩包,并在压缩解压文件夹里创建"redis控制面板.bat" 批处理文件,批处理代码如下
@echo off
rem 提供Windows下redis的启动,重启,关闭功能
echo ==================begin========================
cls
::redis 所在的盘符
set REDIS_PATH=F:
::redis 所在目录
set REDIS_DIR=F:\Gsoft\Redis-x64-5.0.14.1\
set RedisDesktopManager_DIR=F:\Gsoft\Redis-x64-5.0.14.1\redis-desktop-manager-2019.4.0\redis-desktop-manager-2019.4.0\RedisDesktopManager 2019\
color 0a
TITLE redis 管理程序增强版
CLS
echo.
echo. ** redis 管理程序 ***
echo. *** create 2019-03-31 ***
echo.
:MENU
echo. ***** redis 进程list ******
::tasklist|findstr /i "redis-server.exe"
tasklist /fi "imagename eq redis-server.exe"
echo.
if ERRORLEVEL 1 (
echo redis-server.exe不存在
) else (
echo redis-server.exe存在
)
echo.
::*************************************************************************************************************
echo.
echo. [1] 启动临时REDIS
echo. [2] 关闭临时REDIS
echo. [3] 重启临时REDIS
echo. [4] 注册REDIS服务
echo. [5] REDIS服务状态
echo. [6] 启动REDIS服务
echo. [7] 停止REDIS服务
echo. [8] 重启REDIS服务
echo. [9] 卸载REDIS服务
echo. [10] Redis命令行操作工具
echo. [11] Redis性能测试工具
echo. [12] Redis桌面管理工具
echo. [13] 查看REDIS version
:: echo. [91] 重新加载REDIS配置文件
:: echo. [92] 检查测试REDIS配置文件
echo. [99] 刷新控制台
echo. [0] 退 出
echo.
echo.请输入选择的序号:
set /p ID=
IF "%id%"=="1" GOTO start
IF "%id%"=="2" GOTO stop
IF "%id%"=="3" GOTO restart
IF "%id%"=="4" GOTO register
IF "%id%"=="5" GOTO state
IF "%id%"=="6" GOTO startServer
IF "%id%"=="7" GOTO stopServer
IF "%id%"=="8" GOTO restartServer
IF "%id%"=="9" GOTO uninstall
IF "%id%"=="10" GOTO cli
IF "%id%"=="11" GOTO benchmark
IF "%id%"=="12" GOTO desktop
IF "%id%"=="13" GOTO showVersion
:: IF "%id%"=="91" GOTO reloadConf
:: IF "%id%"=="92" GOTO checkConf
IF "%id%"=="99" GOTO MENU
IF "%id%"=="0" EXIT
PAUSE
::*************************************************************************************************************
::启动临时REDIS
:start
call :startREDIS
GOTO MENU
::停止临时REDIS
:stop
call :shutdownREDIS
GOTO MENU
::重启临时REDIS
:restart
call :shutdownREDIS
call :startREDIS
GOTO MENU
::注册REDIS服务
:register
call :shutdownREDIS
call :registerREDIS
GOTO MENU
::查看REDIS服务状态
:state
call :showState
GOTO MENU
::启动REDIS服务
:startServer
call :startRedisServer
GOTO MENU
::停止REDIS服务
:stopServer
call :stopRedisServer
GOTO MENU
::重启REDIS服务
:restartServer
call :stopRedisServer
call :startRedisServer
GOTO MENU
::卸载REDIS服务
:uninstall
call :stopRedisServer
call :uninstallREDIS
GOTO MENU
::Redis命令行操作工具
:cli
call :clientRedis
GOTO MENU
::Redis性能测试工具
:benchmark
call :redisBenchmark
GOTO MENU
::Redis桌面管理工具
:desktop
call :desktopManager
GOTO MENU
::检查测试配置文件
:checkConf
call :checkConfREDIS
GOTO MENU
::重新加载REDIS配置文件
:reloadConf
call :checkConfREDIS
call :reloadConfREDIS
GOTO MENU
::显示REDIS版本
:showVersion
call :showVersionREDIS
GOTO MENU
::*************************************************************************************
::底层
::*************************************************************************************
:shutdownREDIS
echo.
echo.关闭REDIS......
taskkill /F /IM redis-server.exe > nul
echo.OK,关闭所有REDIS 进程
goto :eof
:startREDIS
echo.
echo.启动REDIS......
IF NOT EXIST "%REDIS_DIR%redis-server.exe" (
echo "%REDIS_DIR%redis-server.exe"不存在
goto :eof
)
%REDIS_PATH%
cd "%REDIS_DIR%"
IF EXIST "%REDIS_DIR%redis-server.exe" (
echo "start '' redis-server.exe redis.windows.conf"
start "" redis-server.exe redis.windows.conf
)
echo.OK
echo.
goto :eof
:registerREDIS
echo.
echo.注册REDIS服务......
for /f "skip=3 tokens=4" %%i in ('sc query Redis') do set "zt=%%i" &goto :next
:next
if /i "%zt%"=="" (
IF NOT EXIST "%REDIS_DIR%redis-server.exe" (
echo "%REDIS_DIR%redis-server.exe"不存在
goto :eof
)
%REDIS_PATH%
cd "%REDIS_DIR%"
IF EXIST "%REDIS_DIR%redis-server.exe" (
echo "start '' redis-server.exe --service-install redis.windows.conf --loglevel verbose"
start "" redis-server.exe --service-install redis.windows.conf --loglevel verbose
)
) else (
echo 该服务已注册!
)
echo.OK
echo.
goto :eof
:showState
echo.
echo.查看REDIS服务状态......
for /f "skip=3 tokens=4" %%i in ('sc query Redis') do set "zt=%%i" &goto :next
:next
if /i "%zt%"=="" (
echo 该服务已被卸载!
) else (
if /i "%zt%"=="RUNNING" (
echo 正在运行!
) else (
echo 暂停!
)
)
echo.OK
echo.
goto :eof
:startRedisServer
echo.
echo.启动REDIS服务......
for /f "skip=3 tokens=4" %%i in ('sc query Redis') do set "zt=%%i" &goto :next
:next
if /i "%zt%"=="" (
echo 该服务已被卸载!
) else (
if /i "%zt%"=="RUNNING" (
echo 该服务正在运行!
) else (
IF NOT EXIST "%REDIS_DIR%redis-server.exe" (
echo "%REDIS_DIR%redis-server.exe"不存在
goto :eof
)
%REDIS_PATH%
cd "%REDIS_DIR%"
IF EXIST "%REDIS_DIR%redis-server.exe" (
echo "start '' redis-server.exe --service-start"
start "" redis-server.exe --service-start
)
)
)
echo.OK
echo.
goto :eof
:stopRedisServer
echo.
echo.停止REDIS服务......
for /f "skip=3 tokens=4" %%i in ('sc query Redis') do set "zt=%%i" &goto :next
:next
if /i "%zt%"=="" (
echo 该服务已被卸载!
) else (
if /i "%zt%"=="RUNNING" (
IF NOT EXIST "%REDIS_DIR%redis-server.exe" (
echo "%REDIS_DIR%redis-server.exe"不存在
goto :eof
)
%REDIS_PATH%
cd "%REDIS_DIR%"
IF EXIST "%REDIS_DIR%redis-server.exe" (
echo "start '' redis-server.exe --service-stop"
start "" redis-server.exe --service-stop
)
) else (
echo 该服务已暂停!
)
)
echo.OK
echo.
goto :eof
:uninstallREDIS
echo.
echo.卸载REDIS服务......
IF NOT EXIST "%REDIS_DIR%redis-server.exe" (
echo "%REDIS_DIR%redis-server.exe"不存在
goto :eof
)
%REDIS_PATH%
cd "%REDIS_DIR%"
IF EXIST "%REDIS_DIR%redis-server.exe" (
echo "start '' redis-server.exe --service-uninstall"
start "" redis-server.exe --service-uninstall
echo 关闭重启批处理
timeout /nobreak /t 5
EXIT
)
echo.OK
echo.
goto :eof
:clientRedis
echo.
echo.启用Redis命令行操作工具......
IF NOT EXIST "%REDIS_DIR%redis-cli.exe" (
echo "%REDIS_DIR%redis-cli.exe"不存在
goto :eof
)
%REDIS_PATH%
cd "%REDIS_DIR%"
IF EXIST "%REDIS_DIR%redis-cli.exe" (
echo "start '' redis-cli.exe"
start "" redis-cli.exe
)
echo.OK
echo.
goto :eof
:redisBenchmark
echo.
echo.启用Redis性能测试工具......
IF NOT EXIST "%REDIS_DIR%redis-benchmark.exe" (
echo "%REDIS_DIR%redis-benchmark.exe"不存在
goto :eof
)
%REDIS_PATH%
cd "%REDIS_DIR%"
IF EXIST "%REDIS_DIR%redis-benchmark.exe" (
echo "start '' redis-benchmark.exe"
start "" redis-benchmark.exe
)
echo.OK
echo.
goto :eof
:desktopManager
echo.
echo.启用Redis桌面管理工具......
IF NOT EXIST "%RedisDesktopManager_DIR%rdm.exe" (
echo "%RedisDesktopManager_DIR%rdm.exe"不存在
goto :eof
)
%REDIS_PATH%
cd "%RedisDesktopManager_DIR%"
IF EXIST "%RedisDesktopManager_DIR%rdm.exe" (
echo "start '' rdm.exe"
start "" rdm.exe
)
echo.OK
echo.
goto :eof
:checkConfREDIS
echo.
echo.检查测试 REDIS 配置文件......
IF NOT EXIST "%REDIS_DIR%redis-server.exe" (
echo "%REDIS_DIR%redis-server.exe"不存在
goto :eof
)
%REDIS_PATH%
cd "%REDIS_DIR%"
REDIS -t -c redis.windows.conf
goto :eof
::重新加载 REDIS 配置文件
:reloadConfREDIS
echo.
echo.重新加载 REDIS 配置文件......
IF NOT EXIST "%REDIS_DIR%redis-server.exe" (
echo "%REDIS_DIR%redis-server.exe"不存在
goto :eof
)
%REDIS_PATH%
cd "%REDIS_DIR%"
REDIS -s reload
goto :eof
::显示REDIS版本
:showVersionREDIS
echo.
%REDIS_PATH%
cd "%REDIS_DIR%"
redis-cli.exe -v
echo.OK
echo.
goto :eof
运行批处理,安装菜单可以单独运行也可以设置为服务。
6、发布若依服务端
(1)修改配置
ruoyi-admin项目里找到
application.yml文件
ruoyi --> profile 上传文件路径
server-->port 服务端口
spring-->redis redis 配置
application-druid.yml文件
spring-->datasource-->druid-->master 数据库节点
ruoyi-ui 文件夹下找到.vue.config.js文件
port 前端使用端口
这几个节点,根据实际情况修改配置
如果前端和后端不在同一台服务器,
ruoyi-ui 文件夹下找到.env.production文件
VUE_APP_BASE_API 参数改成 后端ip加端口 比如 VUE_APP_BASE_API ='http://192.168.235.134:8080'
如果前端和后端在同一台服务器,但后端ip不是8080端口
ruoyi-ui 文件夹下找到.vue.config.js文件
修改 [process.env.VUE_APP_BASE_API] --> target 节点修改端口号
(2)后端打包
依次点击clean、package两个批处理生成Jar文件,并将各目录下target文件夹下的JAR文件拷贝出来
(2)前端打包
使用编辑器如 Hbuilder -> 运行 -> 运行到终端 -> npm run build,编译生成
然后去目录下查看dist文件夹,这个文件夹得内容即是打包好的前端内容。
7、nginx配置
百度自行搜索,本文不赘述
8、若依前端部署
修改nginx.conf,在nginx -->conf目录下找到nginx.conf,并重启nginx服务
user root;
worker_processes 1
events {
worker_connections 1024;
}
http {
include mime.types;
default_type application/octet-stream;
sendfile on;
keepalive_timeout 65;
server {
listen 80;
server_name localhost;
location / {
root /home/ubuntu/myapp/ruoyi/ruoyi-ui/dist; # 路径改成自己的dist路径
try_files $uri $uri/ /index.html;
index index.html index.htm;
}
location /prod-api/{
proxy_set_header Host $http_host;
proxy_set_header X-Real-IP $remote_addr;
proxy_set_header REMOTE-HOST $remote_addr;
proxy_set_header X-Forwarded-For $proxy_add_x_forwarded_for;
proxy_pass http://localhost:8080/; #设置监控后端启动的端口
}
error_page 500 502 503 504 /50x.html;
location = /50x.html {
root html;
}
}
9、若依后端部署
打开CMD命令行
利用CD,将路径指引到后端所在目录,执行命令
java -jar -Xms256m -Xmx1024m -XX:MetaspaceSize=128m -XX:MaxMetaspaceSize=512m ruoyi-admin.jar