存储控制器

最新推荐文章于 2023-06-14 15:47:29 发布

心芯晴

最新推荐文章于 2023-06-14 15:47:29 发布

阅读量4.5k

点赞数

分类专栏： ARM 裸板部分

本文链接：https://blog.csdn.net/yanshaodan/article/details/70168150

版权

ARM 裸板部分专栏收录该内容

5 篇文章 0 订阅

订阅专栏

目的：了解总线形式扩展的外设，比如nandflash、norflash、网卡等，了解总线的使用方法之后，再根据具体的外设特性，就可以驱动该外设了。

例子：使用SDRAM

读手册知道前提：主控芯片的引出地址线为addr0-addr26（128M），有八个bank （各有引出信号）所以可以访问的1个g的存储空间。

主控芯片是32位cpu，理论上可以访问4g的地址空间，剩余的用来访问内部的寄存器地址以及未使用。

看图我们知道bank6控制着SDRAM。

sdrom 结构：
可以认为为4层，硬件上要对它进行操作需要以下几步：
1.片选选中sdrom
2.选中哪一层
3.被选中的一层进行行列寻址。

其中行地址为13位对应于地址空间的bit【23:11】，列地址为9位对应于地址空间的bit【10:2】。LnSRAS、LnSCAS控制着行地址与列地址的选择。

我们来看看这个知道行选列选选择后方可读写，那么我们就可以计算出sdrom每一层的最大取值范围为2^13 = 8M，一片有4层，4*8 = 32M，有两片sdrom 2*32 = 64M。

该存储控制器寄存器的起始地址和结束地址。

下面是存储控制器的寄存器：

位宽和等待控制器寄存器bwscon ，32位每4位控制着一个bank，bank6由以下4位控制。

对于sdrom，st6为0，对于SRAMst6为1，waw6为0。DW6为01。

bankcon控制寄存器

MT为11，Trcd为01（推荐值），scan 列地址位数01。其他的使用默认值。

刷新控制寄存器。

REFEN【23】为1使能，TREFMD【22】为1，Trp【21:20】为0即可，Tsrc,19:18】11

我们要操作的是mrs6，保守值为0x30。

知道了这些后基本上可以开始编程了。

先介绍几个汇编伪指令：

ldr指令从内存读取到寄存器中，str指令从寄存器读取到内存中，

.text 部分是处理器开始执行代码的地方,指定了后续编译出来的内容放在代码段【可执行】,是arm-gcc编译器的关键词。

.global关键字用来让一个符号对链接器可见，可以供其他链接对象模块使用;告诉编译器后续跟的是一个全局可见的名字【可能是变量，也可以是函数名】

.global _start 让 _start 符号成为可见的标识符，这样链接器就知道跳转到程序中的什么地方并开始执行。

_start是一个函数的起始地址，也是编译、链接后程序的起始地址。由于程序是通过加载器来加载的，必须要找到 _start名字的函数，因此_start必须定义成全局的，以便存在于编译后的全局符合表中，供其它程序【如加载器】寻找到。

Linux寻找这个 _start 标签作为程序的默认进入点。

.equ是一个代码替换指令,类似于C中的#define。

@*************************************************************************
@ File：head.S
@ 功能：设置SDRAM，将程序复制到SDRAM，然后跳到SDRAM继续执行
@*************************************************************************
.equ MEM_CTL_BASE, 0x48000000 @ 定义存储控制器寄
.equ SDRAM_BASE, 0x30000000
.text
.global _start
_start:
bl disable_watch_dog @ 关闭WATCHDOG，否则CPU会不断重启
bl memsetup @ 设置存储控制器
bl copy_steppingstone_to_sdram @ 复制代码到SDRAM中
ldr pc, =on_sdram @ 跳到SDRAM中继续执行
on_sdram:
ldr sp, =0x34000000 @ 设置堆栈
bl main
halt_loop:
b halt_loop
disable_watch_dog:
@ 往WATCHDOG寄存器写0即可
mov r1, #0x53000000
mov r2, #0x0
str r2, [r1]
mov pc, lr @ 返回
copy_steppingstone_to_sdram:
@ 将Steppingstone的4K数据全部复制到SDRAM中去
@ Steppingstone起始地址为0x00000000，SDRAM中起始地址为0x30000000
mov r1, #0
ldr r2, =SDRAM_BASE
mov r3, #4*1024
1:
ldr r4, [r1],#4 @ 从Steppingstone读取4字节的数据，并让源地址加4
str r4, [r2],#4 @ 将此4字节的数据复制到SDRAM中，并让目地地址加4
cmp r1, r3 @ 判断是否完成：源地址等于Steppingstone的未地址？
bne 1b @ 若没有复制完，继续
mov pc, lr @ 返回
memsetup:
@ 设置存储控制器以便使用SDRAM等外设
mov r1, #MEM_CTL_BASE @ 存储控制器的13个寄存器的开始地址
adrl r2, mem_cfg_val @ 这13个值的起始存储地址
add r3, r1, #52 @ 13*4 = 54
1:
ldr r4, [r2], #4 @ 读取设置值，并让r2加4
str r4, [r1], #4 @ 将此值写入寄存器，并让r1加4
cmp r1, r3 @ 判断是否设置完所有13个寄存器
bne 1b @ 若没有写成，继续
mov pc, lr @ 返回
.align 4
mem_cfg_val:
@ 存储控制器13个寄存器的设置值
.long 0x22011110 @ BWSCON
.long 0x00000700 @ BANKCON0
.long 0x00000700 @ BANKCON1
.long 0x00000700 @ BANKCON2
.long 0x00000700 @ BANKCON3
.long 0x00000700 @ BANKCON4
.long 0x00000700 @ BANKCON5
.long 0x00018005 @ BANKCON6
.long 0x00018005 @ BANKCON7
.long 0x008C07A3 @ REFRESH
.long 0x000000B1 @ BANKSIZE
.long 0x00000030 @ MRSRB6
.long 0x00000030 @ MRSRB7

测试代码：

#define GPFCON (*(volatile unsigned long *)0x56000050)
#define GPFDAT (*(volatile unsigned long *)0x56000054)
#define GPF4_out (1<<(4*2))
#define GPF5_out (1<<(5*2))
#define GPF6_out (1<<(6*2))
void wait(volatile unsigned long dly)
{
for(; dly > 0; dly--);
}
int main(void)
{
unsigned long i = 0;
GPFCON = GPF4_out|GPF5_out|GPF6_out; // 将LED1,2,4对应的GPF4/5/6三个引脚设为输出
while(1){
wait(30000);
GPFDAT = (~(i<<4)); // 根据i的值，点亮LED1,2,4
if(++i == 8)
i = 0;
}
return 0;
}

makefile：

sdram.bin : head.S leds.c
arm-linux-gcc -c -o head.o head.S
arm-linux-gcc -c -o leds.o leds.c
arm-linux-ld -Ttext 0x30000000 head.o leds.o -o sdram_elf
arm-linux-objcopy -O binary -S sdram_elf sdram.bin
arm-linux-objdump -D -m arm sdram_elf > sdram.dis
clean:
rm -f sdram.dis sdram.bin sdram_elf *.o