Oracle UTL_SMTP邮件发送

CREATE OR REPLACE PROCEDURE send_mail(p_recipient VARCHAR2, -- 邮件接收人   

                                      p_subject   VARCHAR2, -- 邮件标题   

                                      p_message   VARCHAR2 -- 邮件正文   

                                      ) IS

  --下面四个变量请根据实际邮件服务器进行赋值   

  v_mailhost VARCHAR2(30) := 'smtp.126.com'; --SMTP服务器地址   

  v_user     VARCHAR2(30) := 'yehaver'; --登录SMTP服务器的用户名；只是用户名，不包括163.com部分 

  v_pass     VARCHAR2(20) := 'XXXXXXX'; --登录SMTP服务器的密码   

  v_sender   VARCHAR2(50) := 'yehaver@126.com'; --发送都邮箱，一般与 ps_user 对应  

  v_conn     UTL_SMTP.connection; --到邮件服务器的连接   

  v_msg      varchar2(4000); --邮件内容  

BEGIN

  v_conn := UTL_SMTP.open_connection(v_mailhost, 25);  --建立连接

--有些服务器要用UTL_SMTP.ehlo() 来与服务器打招呼

  UTL_SMTP.ehlo(v_conn, v_mailhost); --是用 ehlo() 而不是 helo() 函数，否则会报：ORA-29279: SMTP 永久性错误: 503 5.5.2 Send hello first.   

---外网邮箱登陆后发送邮件需加如下代码

  UTL_SMTP.command(v_conn, 'AUTH LOGIN'); -- smtp外网服务器登录校验   

--支持邮件的协议必须加UTL_ENCODE.base64_encode

  UTL_SMTP.command(v_conn,UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(UTL_RAW.cast_to_raw(v_user))));

  UTL_SMTP.command(v_conn,UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(UTL_RAW.cast_to_raw(v_pass))));

--'<' || v_sender || '>'两边加中括号

  UTL_SMTP.mail(v_conn, '<' || v_sender || '>'); --设置发件人   

  UTL_SMTP.rcpt(v_conn, '<' || p_recipient || '>'); --设置收件人   

  -- 创建要发送的邮件内容 注意报头信息和邮件正文之间要空一行   

  v_msg := 'Date:' || TO_CHAR(SYSDATE, 'dd mon yy hh24:mi:ss') ||

           UTL_TCP.CRLF || 'From: ' || v_sender || '<' || v_sender || '>' ||

           UTL_TCP.CRLF || 'To: ' || p_recipient || '<' || p_recipient || '>' ||

           UTL_TCP.CRLF || 'Subject: ' || p_subject || UTL_TCP.CRLF ||

           UTL_TCP.CRLF -- 这前面是报头信息    

           || p_message; -- 这个是邮件正文   

  UTL_SMTP.open_data(v_conn); --打开流   

  UTL_SMTP.write_raw_data(v_conn, UTL_RAW.cast_to_raw(v_msg)); --这样写标题和内容都能用中文   

  UTL_SMTP.close_data(v_conn); --关闭流   

  UTL_SMTP.quit(v_conn); --关闭连接   

EXCEPTION

  WHEN OTHERS THEN

    DBMS_OUTPUT.put_line(DBMS_UTILITY.format_error_stack);

    DBMS_OUTPUT.put_line(DBMS_UTILITY.format_call_stack);

  

END send_mail;

  -- 如果需要加入抄送，则在MSG中加入'CC:'作为NAME的行即可，如果需要多个接受者，则在收件人中列明，并分别用UTL_SMTP.RCPT连接，如下：

  CREATE OR REPLACE PROCEDURE send_mail(SENDER     IN VARCHAR2 DEFAULT 'WANGXIAOQI@XXXX.COM',

                                     RECIPIENT1 IN VARCHAR2 DEFAULT 'WANGXIAOQI@XXXX.COM',

                                     RECIPIENT2 IN VARCHAR2 DEFAULT 'TEST01@XXXX.COM',

                                     RECIPIENT3 IN VARCHAR2 DEFAULT 'TEST02@XXXX.COM',

                                     SUBJECT    IN VARCHAR2 DEFAULT 'THE WRONG DATA NOTICEMENT',

                                     MESSAGE    IN VARCHAR2) IS

  MAILHOST VARCHAR2(30) := '10.27.9.24';

  C        UTL_SMTP.CONNECTION;

  MSG      VARCHAR2(1000);

BEGIN

  MSG := 'DATE: ' || TO_CHAR(SYSDATE - 1, 'DD MON YY HH24:MI:SS') ||

         UTL_TCP.CRLF || 'FROM: <' || SENDER || '>' || UTL_TCP.CRLF ||

         'SUBJECT: ' || SUBJECT || UTL_TCP.CRLF || 'TO: <' || RECIPIENT1 ||

         '>;<' || RECIPIENT2 || '>' || UTL_TCP.CRLF || 'CC: <' ||

         RECIPIENT3 || '>' || UTL_TCP.CRLF || '' || UTL_TCP.CRLF || MESSAGE;

  C   := UTL_SMTP.OPEN_CONNECTION(MAILHOST, 25);

  UTL_SMTP.HELO(C, MAILHOST);

  UTL_SMTP.MAIL(C, SENDER);

  UTL_SMTP.RCPT(C, RECIPIENT1);

  UTL_SMTP.RCPT(C, RECIPIENT2);

  UTL_SMTP.RCPT(C, RECIPIENT3);

  UTL_SMTP.OPEN_DATA(C);

  UTL_SMTP.WRITE_RAW_DATA(C, UTL_RAW.CAST_TO_RAW(MSG));

  UTL_SMTP.CLOSE_DATA(C);

  UTL_SMTP.QUIT(C);

END send_mail;

--相互逆转函数，常用于加密

UTL_RAW.CAST_TO_RAW('FDA11')  --先转换为ACSII码然后再转换为16进制

UTL_RAW.CAST_TO_VARCHAR2('4644413131') --先转换为十进制，然后转换为CHR

--可以发送附件，但是不能超过32KB

1、确定是否安装了utl_mail,如果没有用下面的语句安装utl_mail

  sqlplus sys/

  SQL> @$ORACLE_HOME/rdbms/admin/utlmail.sql

  SQL> @$ORACLE_HOME/rdbms/admin/prvtmail.plb

2、设置smtp_out_server参数