使用游标

最新推荐文章于 2022-05-18 15:27:07 发布
最新推荐文章于 2022-05-18 15:27:07 发布
阅读量394 收藏 1
点赞数 1
分类专栏： Oracle 文章标签： table reference oracle delete
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/yjlcm1092/article/details/4985871
版权

使用显式游标以及游标属性；显式游标更新或删除数据；参数游标；游标FOR循环；游标变量；FETCH ...BULK  COLLECT   INTO语句和CURSOR表达式。

 

 

为了处理SELECT语句返回的多行数据，可以使用显式游标，使用显示游标包括定义游标、打开游标、提取数据和关闭游标四个阶段。

1)定义游标。在使用显式游标之前，必须首先在定义部分定义游标。定义游标用于指定游标所对应的SELECT语句。

CURSOR  cursor_name  IS  select_statement;

2)打开游标。当打开游标时，Oracle会执行游标所对应的SELECT语句，并且将SELECT语句的结果暂时存放到结果集中。

OPEN cursor_name

3)提取数据。为了处理结果集中的数据，需要使用FETCH语句提取游标数据。使用FETCH语句每次只能提取一行数据，通过使用FETCH...BULK  COLLECT  INTO语句，每次可以提取多行数据。

语法一：FETCH   cursor_name  INTO  variable1,variable2...

语法二：FETCH   cursor_name  BULK  COLLECT  INTO  collect1,collect2,...[LIMIT rows];

variable用于指定接收游标数据的变量；collect用于指定接收游标结果的集合变量。当使用语法一时，必须要使用循环语句处理结果集的所有数据。

4)关闭游标。

CLOSE  cursor_name;

 

 

显示游标属性用于返回显式游标的执行信息，这些属性包括%ISOPEN、%FOUND、%NOTFOUND和%ROWCOUNT。

 

 

--在显式游标中使用FETCH...INTO语句

 

DECLARE

  CURSOR emp_cursor IS

    SELECT ename,sal FROM emp WHERE deptno=10;

  v_ename emp.ename%TYPE;

  v_sal emp.sal%TYPE;

BEGIN

  OPEN emp_cursor;

  LOOP

    FETCH emp_cursor INTO v_ename,v_sal;

    EXIT WHEN emp_cursor%NOTFOUND;

    dbms_output.put_line(v_ename||': '||v_sal);

  END LOOP;

  CLOSE emp_cursor;

END;

 

 

 

--在显示游标中，使用FETCH...BULK  COLLECT  INTO语句提取所有数据

 

DECLARE

  CURSOR emp_cursor IS

    SELECT ename FROM emp WHERE deptno=10;

  TYPE ename_table_type IS TABLE OF VARCHAR2(10);

  ename_table ename_table_type;

BEGIN

  OPEN emp_cursor;

  FETCH emp_cursor BULK COLLECT INTO ename_table;

  FOR i IN 1..ename_table.COUNT LOOP 

    dbms_output.put_line(ename_table(i));

  END LOOP;

  CLOSE emp_cursor;

END;

 

 

 

--在显示游标中，使用FETCH...BULK  COLLECT  INTO...LIMIT语句提取部分数据

 

DECLARE

  TYPE name_array_type IS VARRAY(5) OF VARCHAR2(10);

  name_array name_array_type;

  CURSOR emp_cursor IS SELECT ename FROM emp;

  rows INT:=5;

  v_count INT:=0;

BEGIN

  OPEN emp_cursor;

  LOOP

    FETCH emp_cursor BULK COLLECT INTO name_array LIMIT rows;

    dbms_output.put('雇员名：');

    FOR i IN 1..(emp_cursor%ROWCOUNT-v_count) LOOP

      dbms_output.put(name_array(i)||' ');

    END LOOP;

    dbms_output.new_line;

    v_count:=emp_cursor%ROWCOUNT;

    EXIT WHEN emp_cursor%NOTFOUND;

  END LOOP;

  CLOSE emp_cursor;

END;

 

 

 

--使用游标属性

 

DECLARE

  CURSOR emp_cursor IS

    SELECT ename FROM emp WHERE deptno=10;

  TYPE ename_table_type IS TABLE OF VARCHAR2(10);

  ename_table ename_table_type;

BEGIN

  IF NOT emp_cursor%ISOPEN THEN

    OPEN emp_cursor;

  END IF;

  FETCH emp_cursor BULK COLLECT INTO ename_table;

    dbms_output.put_line(emp_cursor%ROWCOUNT);

  CLOSE emp_cursor;

END;

 

 

 

--基于游标定义记录变量

 

DECLARE

  CURSOR emp_cursor IS

    SELECT ename, sal FROM emp;

  emp_record emp_cursor%ROWTYPE;

BEGIN

  IF NOT emp_cursor%ISOPEN THEN

    OPEN emp_cursor;

  END IF;

  LOOP

    FETCH emp_cursor

      INTO emp_record;

    EXIT WHEN emp_cursor%NOTFOUND;

    dbms_output.put_line('雇员名：' || emp_record.ename || ' ,雇员工资：' ||

                         emp_record.sal);

  END LOOP;

END;

 

 

 

--参数游标

 

DECLARE

  CURSOR emp_cursor(no NUMBER) IS

    SELECT ename FROM emp WHERE deptno=no;

  v_ename emp.ename%TYPE;

BEGIN

  OPEN emp_cursor(10);

  LOOP

    FETCH emp_cursor INTO v_ename;

    EXIT WHEN emp_cursor%NOTFOUND;

    dbms_output.put_line(v_ename);

  END LOOP;

  CLOSE emp_cursor;

END;

 

 

 

使用游标更新或删除数据

CURSOR  cursor_name(parameter_name  datatype)  IS  select_statement  FOR  UPDATE [OF  column_reference][NOWAIT];

FOR  UPDATE子句用于在游标结果集数据上加行共享锁，以防止其他用户在相应行上执行DML操作，当SELECT语句引用到多张表时，使用OF子句可以确定哪些表要加锁，如果没有OF子句，则会在SELECT语句所引用的全部表上加锁；NOWAIT子句用于指定不等待锁。在提取了游标数据之后，为了更新或删除当前游标行数据，必须在UPDATE或DELETE语句中引用WHERE  CURRENT  OF子句。

 

--使用游标更新数据

 

DECLARE

  CURSOR emp_cursor IS

    SELECT ename,sal FROM emp FOR UPDATE;

  v_ename emp.ename%TYPE;

  v_oldsal emp.sal%TYPE;

BEGIN

  OPEN emp_cursor;

  LOOP

    FETCH emp_cursor INTO v_ename,v_oldsal;

    EXIT WHEN emp_cursor%NOTFOUND;

    IF v_oldsal<2000 THEN

      UPDATE emp set sal=sal+100 WHERE CURRENT OF emp_cursor;

    END IF;

    dbms_output.put_line(v_ename);

  END LOOP;

  CLOSE emp_cursor;

END;

 

 

 

--使用OF子句在特定表上加行共享锁

 

DECLARE

  CURSOR emp_cursor IS

    SELECT ename, sal, dname, emp.deptno

      FROM emp, dept

     WHERE emp.deptno = dept.deptno

       FOR UPDATE OF emp.deptno;

  emp_record emp_cursor%ROWTYPE;

BEGIN

  OPEN emp_cursor;

  LOOP

    FETCH emp_cursor

      INTO emp_record;

    EXIT WHEN emp_cursor%NOTFOUND;

    IF emp_record.deptno = 30 THEN

      UPDATE emp set sal = sal + 100 WHERE CURRENT OF emp_cursor;

    END IF;

    dbms_output.put_line('雇员名：' || emp_record.ename || ' ,工资：'

                         ||emp_record.sal);

  END LOOP;

  CLOSE emp_cursor;

END;

 

 

 

--使用NOWAIT子句

 

DECLARE

  CURSOR emp_cursor IS

    SELECT ename,sal FROM emp FOR UPDATE NOWAIT;

  v_ename emp.ename%TYPE;

  v_oldsal emp.sal%TYPE;

BEGIN

  OPEN emp_cursor;

  LOOP

    FETCH emp_cursor INTO v_ename,v_oldsal;

    EXIT WHEN emp_cursor%NOTFOUND;

    IF v_oldsal<2000 THEN

      UPDATE emp set sal=sal+100 WHERE CURRENT OF emp_cursor;

    END IF;

    dbms_output.put_line(v_ename);

  END LOOP;

  CLOSE emp_cursor;

END;

 

 

 

游标FOR循环。Oracle会隐含地打开游标、提取游标数据并关闭游标。

 

DECLARE

  CURSOR emp_cursor IS

    SELECT ename, sal FROM emp;

BEGIN

  FOR emp_record IN emp_cursor LOOP

    dbms_output.put_line('第' || emp_cursor%ROWCOUNT || '个雇员：' ||

                         emp_record.ename);

  END LOOP;

END;

 

 

 

--在游标FOR循环中直接使用子查询

 

BEGIN

  FOR emp_record IN (SELECT ename, sal FROM emp) LOOP

    dbms_output.put_line(emp_record.ename);

  END LOOP;

END;

 

 

 

使用游标变量。其使用步骤：定义游标变量、打开游标、提取游标数据、关闭游标。

1)首先必须定义REF  CURSOR类型，然后才能定义游标变量。

TYPE  ref_type_name  IS  REF  CURSOR[RETURN  return_type];

cursor_variable  ref_type_name;

下面的步骤同显式游标...

 

--在定义REF  CURSOR类型时不指定RETURN子句

 

DECLARE

   TYPE emp_cursor_type IS REF CURSOR;

   emp_cursor emp_cursor_type;

   emp_record emp%ROWTYPE;

BEGIN

   OPEN emp_cursor FOR SELECT * FROM emp where deptno=10;

   LOOP

     FETCH emp_cursor INTO emp_record;

     EXIT WHEN emp_cursor%NOTFOUND;

     dbms_output.put_line(emp_record.ename);

   END LOOP;

   CLOSE emp_cursor;

END;

 

 

 

--在定义REF  CURSOR类型时指定RETURN子句

 

DECLARE

   TYPE emp_record_type IS RECORD(name VARCHAR(10),salary NUMBER(6,2));

   TYPE emp_cursor_type IS REF CURSOR RETURN emp_record_type;

   emp_cursor emp_cursor_type;

   emp_record emp_record_type;

BEGIN

   OPEN emp_cursor FOR SELECT ename,sal FROM emp where deptno=20;

   LOOP

     FETCH emp_cursor INTO emp_record;

     EXIT WHEN emp_cursor%NOTFOUND;

     dbms_output.put_line(emp_record.name||' '||emp_record.salary);

   END LOOP;

   CLOSE emp_cursor;

END;

 

 

 

使用CURSOR表达式，用于返回嵌套游标

 

DECLARE

  TYPE refcursor IS REF CURSOR;

  CURSOR dept_cursor(no NUMBER) IS

    SELECT a.dname,

           CURSOR (SELECT ename, sal FROM emp WHERE deptno = a.deptno)

      FROM dept a

     WHERE a.deptno = no;

  empcur refcursor;

  v_dname dept.dname%TYPE;

  v_ename emp.ename%TYPE;

  v_sal emp.sal%TYPE;

BEGIN

  OPEN dept_cursor(&no);

  LOOP

    FETCH dept_cursor INTO v_dname,empcur;

    EXIT WHEN dept_cursor%NOTFOUND;

    dbms_output.put_line('部门名:'||v_dname);

    LOOP

      FETCH empcur INTO v_ename,v_sal;

      EXIT WHEN empcur%NOTFOUND;

      dbms_output.put_line('雇员名:'||v_ename||', 工资:'||v_sal);

    END LOOP;

  END LOOP;

  CLOSE dept_cursor;

END;

 

 

 

 

 

 

 

 

 

 

yjlcm1092
关注
专栏目录
数据库作业17：SQL练习9 - CURSOR
qq_34899482的博客
06-17 328
运行结果如下： 数据库游标的使用 游标是系统为用户开设的一个数据缓冲区，存放SQL语句的执行结果。由系统或用户以变量的形式定义。用 户可以用SQL语句逐一从游标中获取记录，并赋给主变量，交由主语言进一步处理，主语言是面向记录的， 一组主变量一次只能存放一条记录在某些情况下，需要把数据从存放在磁盘的表中调到计算机内存中进行处 理，最后将处理结果显示出来或最终写回数据库。这样数据处理的速度才会提高，否则频繁的磁盘数据交换会 降低效率。用数据库语言来描述游标就是映射在结果集中一行数据上的位置实体，有了游标，用户
java使用游标案例_怎样在java中使用游标 举例最好
weixin_31360095的博客
02-13 2261
游标是系统为用户开设的一个数据缓冲区，存放SQL语句的执行结果。每个游标区都有一个名字。用户可以用SQL语句逐一从游标中获取记录，并赋给主变量，交由主语言进一步处理。主语言是面向记录的，一组主变量一次只能存放一条记录。仅使用主变量并不能完全满足SQL 语句向应用程序输出数据的要求。嵌入式SQL引入了游标的概念，用来协调这两种不同的处理方式。在数据库开发过程中，当你检索的数据只是一条记录时，你所编写...
SELECT语句定义和Select语句完整的执行顺序
The best are water的博客
03-28 3313
SELECT语句定义： 一个完成的SELECT语句包含可选的几个子句。SELECT语句的定义如下： 　 <SELECT clause> [<FROM clause>] [<WHERE clause>] [<GROUP BY clause>] [<HAVING clause>] [<ORDER BY clause>] [&...
oracle--11游标
05-30 296
 游标-----内存中的一块区域,存放的是select 的结果          游标用来处理从数据库中检索的多行记录（使用SELECT语句）。利用游标，程序可以逐个地处理和遍历一次检索返回的整个记录集。      为了处理SQL语句，Oracle将在内存中分配一个区域，这就是上下文区。这个区包含了已经处理完的行数、指向被分析语句的指针，整个区是查询语句返回的数据行集。游标就是指向上下文...
SQL使用游标
qq_63128704的博客
05-18 1005
//游标选项和特性 1.能使数据只读不该 2.能控制定向操作（向前，第一，最后等） 3.标记某些列可编辑，某些不可编辑 4.规定范围，使游标对某些请求可访问 5.对数据进行复制 游标主要用于交互式应用，用户可以滚动屏幕，对数据进行浏览和更改 //创建游标 SQL Server，My SQL: DECLARE CustCursor CURSOR FOR SELECT * FROM Customers WHERE cust_email IS NULL Oracle: DECLARE CURSOR CustCu.
Java使用mysql游标_MySQL使用游标
weixin_34046298的博客
01-18 876
1. 使用游标创建游标create procedure processorders()begindeclare ordernumbers cursor for select order_num from orders;end;打开游标open ordernumbers;关闭游标close ordernumbers;创建带声明的游标create procedure processorders()be...
oracle能否避免使用游标,Oracle之游标使用以及优缺点
weixin_33367083的博客
04-03 517
游标(cursor)能够根据查询条件从数据表中提取一组记录，将其作为一个临时表置于数据缓冲区中，利用指针逐行对记录数据进行操作。举例带参数的显示游标：如下是查询Oracle Scott下的emp表中empno为7788的姓名和工资。declarecursor cur_emp(p_empno number) isselect e.ename, e.sal from scott.emp e where...
MySQL 使用游标
GSON的博客
04-19 458
前言：MySQL5以上的版本支持游标功能 为什么要使用游标：MySQL检索的操作一般都是返回结果集，使用简单的SELECT语句，但是却没有办法得到第一行、下一行，或每次一行地处理。有时候需要在检索出来的行中前进或后退一行或多行。 游标的介绍：游标是一个存储在MySQL服务器上的数据库查询，它不是一条SELECT语句，在存储了游标之后，应用程序可以根据需要滚动或浏览其中的数据。游标只能用于存储过...
oracle中使用游标,oracle中游标的使用
weixin_30290131的博客
04-10 1350
3.SQL%NOTFOUND布尔型 值为true表示插入、删除、更新或单行查询操作失败。4.SQL%ISOPEN布尔型DML执行过程中为真，结束后为假三，游标的使用隐式游标的使用主要就是以上的四种属性的使用，使用它们来进行一些流程控制。显示游标的声明和使用cursor cursor_name[ 参数1 参数类型，参数2，参数类型...] is select 语句；游标的使用步骤：1...
Mysql存储过程循环内嵌套使用游标示例代码
09-10
在MySQL中，存储过程是一种预编译的SQL语句集合，可以用于执行复杂的数据库操作，包括循环和游标的使用。游标允许我们逐行处理查询结果，这对于迭代数据进行处理非常有用。本示例中，我们将探讨如何在存储过程中循环...
JDBC使用游标实现分页查询的方法
09-01
- 通过`first()`将游标移动到结果集的第一条记录，再使用`relative(startNo-2)`将游标移动到实际要输出的第一条记录。接着，使用`next()`遍历结果集并打印每条记录的第1个字段。 4. **分页查询方法二：先查询所有...
使用游标更新数据库
05-30
使用游标更新数据库 使用游标更新数据库是指在游标定位下，修改或删除表中指定的数据行。使用游标对数据进行更新可以提高数据库的性能和效率。 1. 游标更新的基本概念 游标是数据库中的一种数据结构，它可以用来...
mysql存储过程中使用游标的实例
01-21
代码如下:DELIMITER $$ DROP PROCEDURE IF EXISTS getUserInfo $$ CREATE PROCEDURE getUserInfo(in date_day datetime)— — 实例— MYSQL存储过程名为：getUserInfo— 参数为：date_day日期格式...— 定义游标DECLARE
MySQL使用游标批量处理进行表操作
09-10
下面将详细讲解如何使用游标进行这些操作。 首先，我们需要理解游标的声明、打开、前进和关闭等基本步骤： 1. 声明游标： 使用`DECLARE cursor_name CURSOR FOR select_statement`语句声明一个游标。`cursor_name...
集合方法、赋值、比较 批量绑定
左手倒影的专栏
12-09 1317
集合方法EXISTS该方法用于确定集合元素是否存在，如果集合元素存在，则返回TRUE；如果集合元素不存在，返回FALSE。 DECLARE  TYPE ename_table_type  IS TABLE OF  emp.ename%TYPE;  ename_table  ename_table_type;BEGIN  IF ename_table.EXISTS(1)
转换函数
左手倒影的专栏
12-03 704
转换函数用于将数值从一种数据类型转换为另一种数据类型。Oracle Server会隐含地转换数据类型。为了防止出现编译错误，如果数据类型不同，那么应该使用转换函数进行类型转换。 ASCIISTR(string)用于将任意字符集的字符串转变为数据库字符集的ASCII字符串。 BIN_TO_NUM(expr[,expr][,expr])用于将未向量值转变为实际的数字值。 CAS
日期时间函数
左手倒影的专栏
12-03 702
时期时间函数用于处理DATE和TIMESTAMP类型的数据。除了函数MONTHS_BETWEEN返回数字值以外，其他日期函数均返回DATE类型的数据。 ADD_MONTHS(d,n)用于返回特定日期时间d之后(或)之前的n个月所对应的日期时间(n为正整数表示之后，n为负整数表示之前)。 CURRENT_DATE用于返回当前会话时区所对应的日期时间。 CURRENT_TIME
单行函数
左手倒影的专栏
12-01 674
BFILENAME(directory,filename)初始化BFILE定位符，其中directory是与OS路径相关的DIRECTORY对象，filename是OS文件的名称。 COALESCE(expr1[,expr2][,expr3],...)返回表达式列表中第一个NOT NULL表达式结果。 DECODE(expr,search1,result1[,search2
elasticsearch使用游标
最新发布
08-23
Elasticsearch 使用游标（Cursor）机制是为了在大量数据分页查询时提供一种高效的方式来逐条获取结果，而不需要一次性加载所有结果到内存中，特别适合处理大数据集。当从 Elasticsearch 中检索大型文档集合时，你...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值