洛谷 P2024 食物链

题目

动物王国中有三类动物 A,B,C，这三类动物的食物链构成了有趣的环形。A 吃 B，B 吃 C，C 吃 A。

现有 N 个动物，以 1 － N 编号。每个动物都是 A,B,C 中的一种，但是我们并不知道它到底是哪一种。

有人用两种说法对这 N 个动物所构成的食物链关系进行描述：

第一种说法是“1 X Y”，表示 X 和 Y 是同类。

第二种说法是“2 X Y”，表示 X 吃 Y 。

此人对 N 个动物，用上述两种说法，一句接一句地说出 K 句话，这 K 句话有的是真的，有的是假的。当一句话满足下列三条之一时，这句话就是假话，否则就是真话。

• 当前的话与前面的某些真的话冲突，就是假话

• 当前的话中 X 或 Y 比 N 大，就是假话

• 当前的话表示 X 吃 X，就是假话

你的任务是根据给定的 N 和 K 句话，输出假话的总数。

题解

因为要处理动物之间的关系，所以用并查集
需要注意的：

1.初始化

用r[i]表示动物i与它的祖先的关系：

      r[i]=0   与祖先是同类 
      r[i]=1   吃祖先
      r[i]=2   被祖先吃

用f[i]来处理动物间的关系，注意划分集合的依据是动物间有无关系

2.判断方法

首先要特判这两种假话：当前的话中 X 或 Y 比 N 大 and 当前的话表示 X 吃 X
然后判断当前话与前面的真话是否冲突
（1）如果searchfather(x)<>searchfather(y),那么这句话就一定没有与前面冲突，因为x和y根本就没有关系，这时要合并x和y所在集合；
（2）如果(r[x]-r[y]+s+2)mod 3<>0就是假话

3.合并和searchfather

合并：先把x的祖先的祖先赋值为y的祖先，
然后把x的祖先和y的祖先的关系赋值为
(r[x]-r[y]+s+2)mod 3

searchfather：正常的找祖先和路径压缩，但
要在把k的祖先更新为整个集合的祖先后，把r[k]更新为(r[k]+r[l])mod 3,l是k更新前的祖先

代码

var
  n,m,k,i,j,x,y,s,r1,r2:longint;
  f,r:array[1..50000]of longint;

function searchfather(k:longint):longint;
var
  l:longint;
begin
  if f[k]<>k then searchfather:=searchfather(f[k])
             else searchfather:=k;
  l:=f[k];
  f[k]:=searchfather;
  r[k]:=(r[k]+r[l])mod 3;
end;

procedure union(x,y,s,r1,r2:longint);
var
  l:longint;
begin
  f[r2]:=r1;
  r[r2]:=(r[x]-r[y]+s+2)mod 3;
end;

begin
  readln(n,m);
  for i:=1 to n do f[i]:=i;
  for i:=1 to m do
    begin
      readln(s,x,y);
      if ((s=2)and(x=y))or(x>n)or(y>n) then
        begin inc(k);continue;end;
      r1:=searchfather(x);
      r2:=searchfather(y);
      if r1<>r2 then union(x,y,s,r1,r2) else
      if (r[x]-r[y]+s+2)mod 3<>0 then inc(k);
    end;
  writeln(k);
end.