v3_03 从自定义组件中派发一个值对象

v3_03 Dispatching a value object from the custom component 从自定义组件中派发一个值对象

 

ex3_03

这部分主要讲了如何提交一个form到主应用程序中,其实主要内容前面已经讲过了

这里主要是对之前内部的串联

 

这部分的起点是MVC那个例子

1.首先建一个请求提交参数的对象

package valueObjects
{
public class VehicleRequest
{
public var id:String;
public var mobilePhone:String;
public var phone:String;
public var pickupDate:String;
public var returnDate:String;
public function VehicleRequest()
{
}
}
} 

  

2.在提交按钮上处理事件,new一个提交对象

<!--WizRtf2Html Charset=0 -->

protected function submitButton_clickHandler(event:MouseEvent):void
{
var vehicleRequestData:VehicleRequest = new VehicleRequest();
vehicleRequestData.id = dropDownList.selectedItem.id;
vehicleRequestData.phone = phone.text;
vehicleRequestData.mobilePhone = mobilePhone.text;
vehicleRequestData.pickupDate = pickupDate.selectedDate.toDateString();
vehicleRequestData.returnDate = returnDate.selectedDate.toDateString(); 


} 
 

 

3.然后扩展一个Event类来将数据传递回主应用程序

步骤同之前例子

扩展Event类

<!--WizRtf2Html Charset=0 -->

package events
{
import flash.events.Event;

import valueObjects.VehicleRequest;

public class VehicleRequestEvent extends Event
{
public var vehicleRequestData:VehicleRequest

public function VehicleRequestEvent(type:String, vehicleRequestData:VehicleRequest)
{
super(type);
this.vehicleRequestData = vehicleRequestData;
}

override public function clone():Event
{
return new VehicleRequestEvent(type, vehicleRequestData);
}
}
} 
 

 

metadata标签中加入Event

<!-- Metadata ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ -->
<fx:Metadata>
[Event(name="vehicleRequestEvent", type="events.VehicleRequestEvent")]
</fx:Metadata> 

  

提交事件中new一个事件对象,并赋值

protected function submitButton_clickHandler(event:MouseEvent):void
{
var vehicleRequestData:VehicleRequest = new VehicleRequest();
vehicleRequestData.id = dropDownList.selectedItem.id;
vehicleRequestData.phone = phone.text;
vehicleRequestData.mobilePhone = mobilePhone.text;
vehicleRequestData.pickupDate = pickupDate.selectedDate.toDateString();
vehicleRequestData.returnDate = returnDate.selectedDate.toDateString(); 

var eventObject:VehicleRequestEvent = new VehicleRequestEvent("vehicleRequestEvent",vehicleRequestData);
dispatchEvent(eventObject);

} 

 

 

主应用程序中处理事件

<components:VehicleRequestForm employees="{employees}" 
vehicleRequestEvent="vehiclerequestform1_vehicleRequestEventHandler(event)"/>

  

 

protected function vehiclerequestform1_vehicleRequestEventHandler(event:VehicleRequestEvent):void
{
Alert.show("Your vehicle request has been submitted");
}