卸载vmware

 

@echo off
color 0a

echo.
echo     是否确定卸载VMware Workstation 精简版？
echo.
echo ---------------------------------------------------------------------------
echo.
SET /P ST=   请输入 Y (确定卸载)或 N (取消卸载)：
echo.
if /I "%ST%"=="Y" goto ST
if /I "%ST%"=="N" goto EX
goto EX

:ST

echo 取消DLL文件注册...
regsvr32 /u /s "%cd%/vmappcfg.dll"
regsvr32 /u /s "%cd%/vmappsdk.dll"
regsvr32 /u /s "%cd%/vmdbCOM.dll"
regsvr32 /u /s "%cd%/vmhwcfg.dll"

echo 正在删除虚拟网卡，请稍后……
:delete VM Network
start /wait vnetlib -- remove adapter vmnet1
start /wait vnetlib -- remove adapter vmnet8
start /wait vnetlib -- remove dhcp vmnet1
start /wait vnetlib -- remove dhcp vmnet8
start /wait vnetlib -- remove nat vmnet8

:delservice
echo 正在删除服务...
call :删除服务 vmnetbridge
call :删除服务 VMAuthdService
call :删除服务 vmx86
call :删除服务 VMnetAdapter
call :删除服务 "VMware NAT Service"
call :删除服务 "VMnetDHCP"
call :删除服务 VMnetuserif
call :删除服务 hcmon
call :删除服务 Vmparport
call :删除服务 vstor2-ws60
call :删除服务 vstor2

"%cd%\VMMount\vmount2.exe"  /Unregserver
netcfg -u vmware_bridge

::以下两句删除用户的配置文件(即虚拟机文件)默认不删除,需要删除请将下面两句前面的::去掉
::rd /s /q %APPDATA%\vmware
::rd /s /q "\Virtual Machines"
echo.
:delreg
echo 删除注册表....
reg delete  "HKEY_LOCAL_MACHINE\SOFTWARE\VMware, Inc." /f

:deluser
echo 删除用户__vmware_user__...
net user __vmware_user__ /delete
net localgroup __vmware__ /delete

pause>nul|echo 卸载完成......
goto :eof
:删除服务
echo 正在删除服务 %*
net stop %* 2>nul
sc delete %*
goto :eof