ansys模拟钢筋混凝土结构（mac文件）

最新推荐文章于 2023-11-07 20:47:12 发布

yueliang2100

最新推荐文章于 2023-11-07 20:47:12 发布

阅读量2.7k

点赞数 4

本文链接：https://blog.csdn.net/yueliang2100/article/details/82190048

版权

define.mac
!-------------------------------------------------------------------
!注参数命名：h（高度），w（宽度），t（厚度），sec（代表截面信息）
!单位：mm

!柱截面尺寸 HW300(截面高度)*300(翼缘宽度)*10(腹板厚度)*15(翼缘厚度)
hw_sec_h = 300
hw_sec_w = 300
hw_sec_t1 = 10
hw_sec_t2 = 15

!梁截面尺寸 HN250*125*6*9
hn_sec_h = 250
hn_sec_w = 125
hn_sec_t1 = 6
hn_sec_t2 = 9

!T型肋加强板尺寸 HT75*125*6*9
ht_sec_h = 75
ht_sec_w = 125
ht_sec_t1 = 6
ht_sec_t2 = 9
ht_l = 1000 !长度

!混凝土板厚度尺寸
con_sec_t = 120 !(修改）

!模型整体尺寸
mod_h = 3000     !模型的高
mod_w1 = 640    !模型横向宽度原3000
mod_w2 = 5100    !模型纵向宽度

!其他参数
rebar_vr = 0.014 !体积率（配筋率）为1.4％（修改）
!横向钢筋？？？6@200??
nail_dis = 100 !栓钉间距为 100mm （修改）
gridding = 100 !网格
steelbar = 200 !钢筋间隔
********************************************************************
concrete.mac
!-------------------------------------------------------------------
!model1,钢筋全部由实常数定义的配筋率
!先运行参数定义命令
define.mac
/FILNAME,model,0
/prep7
!定义属性
et,1,solid65,,,,,,3 !定义混凝土板单元 KEYOPT(6) 混凝土非线性解输出控制:3 -- 同时还给出积分点的解
et,2,SHELL181 !定义钢梁单元
et,3,combin39,,,0 !定义弹簧单元combin39
et,4,solid45 !定义垫板单元 (增加垫块以消除混凝土单元的应力集中)
et,5,link8 !定义link8单元

mp,ex,1,3E4 !定义混凝土板的弹性模量N/mm2
mp,prxy,1,0.2 !定义混凝土板的泊松比
mp,dens,1,2.6e-9 !定义混凝土板的密度

mp,ex,2,2.06E5 !定义钢梁的弹性模量
mp,prxy,2,0.3 !定义钢梁的泊松比
mp,dens,2,7.8e-9

mp,ex,3,2.0E5 !定义钢筋的弹性模量
mp,prxy,3,0.3 !定义钢筋的泊松比
mp,dens,3,7.85e-9

mp,ex,4,2.02E5 !定义垫板材料特性
mp,prxy,4,0.3

tb,miso,1 !混凝土屈服准则
*do,i,1,17,1
*if,i,LE,7,THEN
x=0.0001*2*i
y=(2.07*(x/1.58e-3)+(3-2*2.07)*(x/1.58e-3)*(x/1.58e-3)+0.07*(x/1.58e-3)*(x/1.58e-3)*(x/1.58e-3))*26.1
*ELSE
xtemp=0.0001*2*i/1.58e-3
x=0.0001*2*i
y=xtemp*26.1/(1.13*(xtemp-1)*(xtemp-1)+xtemp)
*ENDIF
tbpt,,x,y
*enddo
tbpt,,0.0002,6
!该处将0.0033改为了0.0035
tbpl,miso,1

tb,concr,1 !混凝土破坏准则
tbdata,,0.6,1.0,2.61,-1
!混凝土材料的前四个实常数的含义
!1 裂缝张开剪力传递系数.
!2 裂缝闭合剪力传递系数
!3 单轴抗拉强度
!4 单轴抗压强度
! 当变量3（4）被设为-1时表示混凝土无开裂（无压碎）

tb,bkin,2,1,2 !激活钢梁的温度特性？？？mkin
tbdata,,235,2000
tbpl,bkin,2

tb,bkin,3,1,2 !激活钢筋的温度特性
tbdata,,335,2000 !320屈服应力，10代表屈服后的切线模量
tbpl,bkin,3

r,1,3,rebar_vr,0,0,0,0 !体积率，方向角 3是什么意思？
!r,1,3,0.0089,90,90,3,0.007819
rmore,0,0 !定义混凝土板实常数（三个方向的钢筋）

!定义钢梁腹板厚度
r,2,hw_sec_t1,hw_sec_t1,hw_sec_t1,hw_sec_t1 !定义钢梁腹板厚度(柱子)
r,3,hn_sec_t1,hn_sec_t1,hn_sec_t1,hn_sec_t1 !定义钢梁腹板厚度(水平梁)
!定义钢梁上下翼缘的厚度
r,4,hw_sec_t2,hw_sec_t2,hw_sec_t2,hw_sec_t2 !定义钢梁上下翼缘的厚度(柱子)
r,5,hn_sec_t2,hn_sec_t2,hn_sec_t2,hn_sec_t2 !定义钢梁上下翼缘的厚度(水平梁)

r,6,0,0,0.02,4607.0,0.04,6765.5 !定义弹簧的荷载变形曲线
rmore,0.05,7651.1,0.06,8457.1,0.07,9201.7
rmore,0.08,9896.9,0.09,10551.2,0.1,11170.8
rmore,0.2,16154.6,0.3,19890.4,0.4,22932.2
rmore,0.5,25506.4,0.6,27734.7,0.7,29692.3
rmore,0.8,31430.3,0.9,32985.4,1,34385.1
rmore,2,43095.0,4,100000,
!3,46937.7,4,50000,
r,7,12 !定义link8单元的面积
!*
KEYOPT,3,1,0
KEYOPT,3,2,0
KEYOPT,3,3,2
KEYOPT,3,4,0
KEYOPT,3,6,0
!*

!**********************************************************************
!开始建立几何模型
!**********************************************************************
!先建柱子
!**********************************************************************
wpcsys,-1,0
csys,4   !在局部坐标系中建立柱子模型
wpoffs,-(mod_w1+hw_sec_w*0.5),-mod_w2*0.5,0
wprota,,90      !(positive Y toward Z)
wpoffs,,,-hw_sec_h*0.5
blc4,0,0,hw_sec_w,mod_h+con_sec_t
wpoffs,,,hw_sec_h
blc4,0,0,hw_sec_w,mod_h+con_sec_t
wprota,,,90      !(positive Z toward X)
wpoffs,,,hw_sec_w*0.5
blc4,0,0,hw_sec_h,mod_h+con_sec_t

aptn,all
asel,all
wpcsys,-1,0
wpoffs,,,mod_h-hn_sec_t2*0.5
asbw,all
wpoffs,,,-hn_sec_h
asbw,all

!!!!!纵梁
wpcsys,-1,0
csys,4 !在局部坐标系中建立纵梁模型
asel,invert !反选
wpoffs,-mod_w1,-mod_w2*0.5,mod_h-hn_sec_t2*0.5
blc4,-hn_sec_w*0.5,-hw_sec_h*0.5,hn_sec_w,(mod_w2+hw_sec_h)*0.5

wpoffs,,,-hn_sec_h
blc4,-hn_sec_w*0.5,-hw_sec_h*0.5,hn_sec_w,(mod_w2+hw_sec_h)*0.5
wprota,,,-90 !(positive Z toward X)
blc4,0,-hw_sec_h*0.5,hn_sec_h,(mod_w2+hw_sec_h)*0.5

cm,hn_temp,area
wpcsys,-1,0
!agen,3,hn_temp,,,mod_w1
aptn,all

asel,all

!!切割梁
wpcsys,-1,0
wpoffs,-mod_w1,-(mod_w2+hn_sec_w)*0.5,mod_h-hn_sec_t2*0.5
wpro,,90
wpro,,,90
wpoffs,,,-hn_sec_w*0.5
asbw,all
wpoffs,,,hn_sec_w
asbw,all

aptn,all

!混凝土板
wpcsys,-1,0
csys,4 !在局部坐标系中建立柱子模型
wpoffs,-mod_w1,-(mod_w2+hw_sec_h)*0.5,mod_h
blc4,-mod_w1*0.5,0,mod_w1,(mod_w2+hw_sec_h)*0.5,con_sec_t

!切体
wpcsys,-1,0
wpoffs,-mod_w1,-mod_w2*0.5,mod_h-hn_sec_t2*0.5
wpro,,90
!vsbw,all
!wpoffs,,,-hw_sec_h*0.5
!vsbw,all
wpro,,,90
vsbw,all
wpoffs,,,-hn_sec_w*0.5
vsbw,all
wpoffs,,,hn_sec_w
vsbw,all

!!!付属性
ALLSEL,BELOW,VOLU
asel,invert
cm,gangjiegou,area

wpcsys,-1,0
wpoffs,-mod_w1,-(mod_w2+hn_sec_h)*0.5,mod_h-hn_sec_t2*0.5
asel,r,loc,z,
wpoffs,,,-hn_sec_h
asel,a,loc,z,
cm,hnsect2,area
AATT, 2, 5, 2, 0, !!!!梁翼缘

cmsel,s,gangjiegou,area
cmsel,u,hnsect2,area
wpcsys,-1,0
wpoffs,-mod_w1,-mod_w2*0.5,mod_h-hn_sec_t2*0.5
asel,r,loc,y,hw_sec_w*0.5+0.001,mod_w2
cm,hnsect1,area
AATT, 2, 3, 2, 0, !!!!!梁腹板

cmsel,s,gangjiegou,area
cmsel,u,hnsect2,area
cmsel,u,hnsect1,area
cm,hwall,area
asel,r,loc,x,
cm,hwsect1,area
AATT, 2, 2, 2, 0, !!!!!柱子腹板

cmsel,s,hwall,area
cmsel,u,hwsect1,area
AATT, 2, 4, 2, 0, !!!!!柱子翼缘

!!!!钢结构网格
cmsel,s,gangjiegou,area
ESIZE,gridding,0,
AMESH,all

nummrg,all

!!!!!!!选钢筋切体
wpcsys,-1,0
allsel,all

KWPAVE, 33
wpoffs,,,-20
vsbw,all

wpcsys,-1,0
KWPAVE, 33
wpoffs,20,
wpro,,,90
vsbw,all
*do,i,1,mod_w1/steelbar,1
wpoffs,,,steelbar !!!!!!改了
vsbw,all
*enddo

!!!!!!!!!!!!!!!!!!!!
!体模型save.amesh
!!!!!!!!!!!!!!!!!!!!
!选钢筋的线\
wpcsys,-1,0
allsel,all
KWPAVE, 33
wpoffs,20,,-20

lsel,r,loc,z
cm,ltemp,line !选出那一层的线
lsel,r,loc,x,0
cm,ltemp1,line

cmsel,s,ltemp,line
*do,i,1,mod_w1/steelbar,1
lsel,r,loc,x,i*steelbar
cmsel,a,ltemp1,line
cm,ltemp1,line
cmsel,s,ltemp,line
*enddo

cmsel,s,ltemp1,line
LATT,3,7,5, , , ,
ESIZE,gridding,0,
LMESH,all

!!!!!!!!!!!!!!!!!体单元

allsel,all
ESIZE,gridding,0,
VATT, 1, 1, 1, 0 !体属性
vmesh,all

!****************************************************
!加弹簧、耦合
!上混泥土板
!***************************
type,3 !设定弹簧单元
real,6

wpcsys,-1,0
wpoffs,-mod_w1,
nsel,s,loc,x
nsel,r,loc,y,0,-(mod_w2-hw_sec_w)*0.5 !!1400
nsel,r,loc,z,mod_h-0.001,mod_h+0.001
cm,enod,node

*get,max0,node,0,count !max1=15
*dim,ojd0,,max0
*dim,jd0,,max0
*get,nod0,node,0,num,min
ojd0(1)=nod0
*do,i,2,max0
ojd0(i)=ndnext(ojd0(i-1))
*enddo
allsel,all
nsel,all
cmsel,u,enod
*do,i,1,max0
nod0=ojd0(i)
j0=nnear(nod0)
jd0(i)=j0
*enddo
nsel,all
*do,i,1,max0
e,ojd0(i),jd0(i)
*enddo
allsel,all

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!node(x,y,z)    !返回最近节点的编号
!nnear(n)       !返回最接近n的节点编号
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!耦合纵梁节点
wpcsys,-1,0
wpoffs,-mod_w1,
!nsel,r,loc,y,0,-2400     !!1400
nsel,r,loc,z,mod_h-0.001,mod_h+0.001
nsel,r,loc,x,-hn_sec_w*0.5,hn_sec_w*0.5
cm,cmljnod,node

*get,max1,node,0,count !max1=15
*dim,ojd,,max1
*dim,jd,,max1
*get,nod1,node,0,num,min
ojd(1)=nod1
*do,i,2,max1
ojd(i)=ndnext(ojd(i-1))
*enddo
allsel,all
nsel,all
cmsel,u,cmljnod
*do,i,1,max1
nod1=ojd(i)
j=nnear(nod1)
jd(i)=j
*enddo
nsel,all
ji = 1
*do,i,1,max1
cp,ji,ux,ojd(i),jd(i)
cp,ji+1,uz,ojd(i),jd(i)
ji=ji+2
*enddo
allsel,all

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!node(x,y,z)    !返回最近节点的编号
!nnear(n)       !返回最接近n的节点编号
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!耦合端部节点
wpcsys,-1,0
wpoffs,-mod_w1,
nsel,s,loc,x,-hn_sec_w*0.5,hn_sec_w*0.5
nsel,r,loc,y,-(mod_w2+hw_sec_w)*0.5 ,-(mod_w2-hw_sec_w)*0.5      !!1400
nsel,r,loc,z,mod_h-0.001,mod_h+0.001
cm,egnod,node

*get,max2,node,0,count !max1=15
*dim,ojd2,,max2
*dim,jd2,,max2
*get,nod2,node,0,num,min
ojd2(1)=nod2
*do,i,2,max2
ojd2(i)=ndnext(ojd2(i-1))
*enddo
allsel,all
nsel,all
cmsel,u,egnod
*do,i,1,max2
nod2=ojd2(i)
j2=nnear(nod2)
jd2(i)=j2
*enddo
nsel,all
ji2 = ji + 1
*do,i,1,max2
cp,ji2,uy,ojd2(i),jd2(i)
ji2=ji2+1
*enddo
allsel,all

!!!!!!!!!!!载荷
wpcsys,-1,0
nsel,s,loc,z,
D,all, , , , , ,ALL, , , , ,
!ACEL,0,0,0,
nsel,s,loc,y,
D,all, , , , , ,UY, , , , ,
allsel,all
wpcsys,-1,0
wpoffs,-mod_w1,-(mod_w2-hw_sec_h)*0.5,mod_h-hn_sec_t2*0.5
nsel,r,loc,z,
nsel,r,loc,x,
nsel,r,loc,y,0,mod_h-hn_sec_t2*0.5
cm,N_load,node
allsel,all

wpcsys,-1,0

!cmsel,s,N_load,node
!*get,Nnod,node,0,count
!*Dim,Nodes,array,Nnod
!*get,Nd,node,0,num,min
!*do,I,1,Nnod,1
! Nodes(I)=Nd
! F,Nd,FZ,-11000                   !!!!!2000-20000
! Nd=NDNEXT(Nd)
!*ENDDO
!!SFTRAN
!allsel,all
!wpcsys,-1,0
!
!/sol
!cnvtol,f,,0.05,2 !定义收敛条件,使用缺省的VALUE
!!nsubst,50 !定义子步数
!outres,all,all !输出每一子步的结果
!autots,1 !打开自动时间步控制
!lnsrch,1 !打开线性搜索
!ncnv,2 !如果不收敛时结束而不退出
!!neqit,50 !每一子步中方程的迭代次数限值
!pred,on !打开预测器
!
!ANTYPE,0
!NLGEOM,1
!NSUBST,100,0,0
!OUTRES,ERASE
!OUTRES,ALL,LAST
!AUTOTS,-1.0
!PSTRES,1
!TIME,20