不借用MS Excel导出XLSX文件

已于 2022-11-24 09:05:00 修改
阅读量159 收藏
点赞数
分类专栏： ABAP 文章标签： excel
于 2022-11-22 16:45:26 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/z858622025/article/details/127985447
版权

上午分享了如何上传excel，下午修改了下代码，实现下载功能！

 

基本原理：大部分项目都是预设模板，然后填格子。所以我在上午代码的基础上只做了少量的修改。单元格的充填方式仍然是一个格子一个格子的充填，速度其实不行，但直接生成xml，摆脱了office的依赖。

测试5*50000的数据，花费2分钟11秒，还行（错误的实例：只有50000个单元格有数据）。3分41秒，25万单元格。

有没有大佬知道还能怎么优化进一步提速？

 

*&---------------------------------------------------------------------*
*& Report ZZXLSX
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT zzxlsx2.
TYPES: BEGIN OF typ_alv,
         col001(50),
         col002(50),
         col003(50),
         col004(50),
         col005(50),
       END OF typ_alv,
       typ_t_alv TYPE TABLE OF typ_alv WITH DEFAULT KEY..

CLASS zxlsx DEFINITION.

  PUBLIC SECTION.

    DATA: error_text    TYPE string,
          xstring_excel TYPE xstring.

    METHODS import_document_from_frontend
      IMPORTING
        pi_filename TYPE /iwbep/sb_odata_ty_char_400sm
      EXCEPTIONS
        file_open_error.

    METHODS export_document_from_server
      IMPORTING
        pi_filename TYPE /iwbep/sb_odata_ty_char_400sm
      EXCEPTIONS
        file_open_error.

    METHODS deserialize_document
      IMPORTING
        pi_sheetid      TYPE i OPTIONAL
        pi_sheetname    TYPE /iwbep/sb_odata_ty_char_400sm OPTIONAL
        check_structure TYPE char1
        start_row       TYPE i
        pt_tab          TYPE typ_t_alv
      EXCEPTIONS
        file_open_error.
ENDCLASS.
CLASS zxlsx IMPLEMENTATION.
  METHOD import_document_from_frontend.
    CLEAR xstring_excel.
*open xlsx into xstring
    TRY.
        DATA im_file_name TYPE string.
        im_file_name = pi_filename.
        xstring_excel = cl_openxml_helper=>load_local_file( im_file_name ). "获取excel路径 为 xstring格式
      CATCH cx_openxml_not_found INTO DATA(openxml_not_found).
        error_text = openxml_not_found->get_text( ).
    ENDTRY.
    IF error_text IS NOT INITIAL.
      MESSAGE e001(00) RAISING file_open_error WITH error_text.
    ENDIF.

  ENDMETHOD.
  METHOD export_document_from_server.
*save xlsx by xstring
    TRY.
        DATA im_file_name TYPE string.
        im_file_name = pi_filename.
        cl_openxml_helper=>store_local_file( im_file_name = im_file_name
                                             im_data      = xstring_excel ). "获取excel路径 为 xstring格式
      CATCH cx_openxml_not_found INTO DATA(openxml_not_found).
        error_text = openxml_not_found->get_text( ).
      CATCH cx_openxml_not_allowed INTO DATA(openxml_not_allowed).
        error_text = openxml_not_allowed->get_text( ).
    ENDTRY.
    IF error_text IS NOT INITIAL.
      MESSAGE e001(00) RAISING file_open_error WITH error_text.
    ENDIF.
    CLEAR xstring_excel.
  ENDMETHOD.
  "下列代码实现了Excel 单个sheet页的导出 代码可以直接使用
  "注意，这个程序基于模板下载数据
  METHOD deserialize_document.
*create a xlsx handler
    DATA(xlsxhandler) = cl_ehfnd_xlsx=>get_instance( )."创建了句柄

*load the xlsx
    TRY.
        DATA(xlsxdocument) = xlsxhandler->load_doc( iv_file_data = xstring_excel ). "加载excel
      CATCH cx_openxml_format INTO DATA(openxml_format).
        error_text = openxml_format->get_text( ).
      CATCH cx_openxml_not_allowed INTO DATA(openxml_not_allowed).
        error_text = openxml_not_allowed->get_text( ).
      CATCH cx_dynamic_check INTO DATA(dynamic_check).
        error_text = dynamic_check->get_text( ).
    ENDTRY.
    IF error_text IS NOT INITIAL.
      MESSAGE e001(00) RAISING file_open_error WITH error_text.
    ENDIF.

*获取指定sheet名称或者id或者第一个sheet页数据
    TRY.
        IF pi_sheetid IS NOT INITIAL.
          DATA(firstsheet) = xlsxdocument->get_sheet_by_id( pi_sheetid ).
        ELSEIF pi_sheetname IS NOT INITIAL.
          DATA iv_sheet_name TYPE string.
          iv_sheet_name = pi_sheetname.
          firstsheet = xlsxdocument->get_sheet_by_name( iv_sheet_name ).
        ELSE.
          firstsheet = xlsxdocument->get_sheet_by_id( 1 ).
        ENDIF.
      CATCH cx_openxml_format  INTO openxml_format.
        error_text = openxml_format->get_text( ).
        error_text = |Error occurs when extract data from specific sheet: | && error_text.
      CATCH cx_openxml_not_found  INTO DATA(openxml_not_found).
        error_text = openxml_not_found->get_text( ).
        error_text = |Error occurs when extract data from specific sheet: | && error_text .
      CATCH cx_dynamic_check  INTO dynamic_check.
        error_text = |Error occurs when extract data from specific sheet: | && dynamic_check->get_text( )  .
    ENDTRY.
    IF error_text IS NOT INITIAL.
      MESSAGE e001(00) RAISING file_open_error WITH error_text.
    ENDIF.

    "return if no sheet in xlsx file
    CHECK NOT firstsheet IS INITIAL.
    "check file structure, first line of excel file
    DATA(columncount) = firstsheet->get_last_column_number_in_row( 1 ). "获取第1行列数 （一共几列）
    DATA column TYPE i VALUE 1.
    "data tablecomponents type cl_abap_structdescr=>component_table.
*get the components of structure
    DATA lw_tab_ref    TYPE REF TO data.
    CREATE DATA lw_tab_ref LIKE LINE OF pt_tab.

    DATA tablestructure TYPE REF TO cl_abap_structdescr.
    tablestructure ?= cl_abap_typedescr=>describe_by_data_ref( lw_tab_ref ). "获取内表的 components
    DATA(tablecomponents) = tablestructure->get_components( ).

    "get the content of excel.
    TYPES: BEGIN OF columninfo,
             column     TYPE i,
             columnname TYPE string,
           END OF columninfo.
    TYPES columnsinfo TYPE STANDARD TABLE OF columninfo WITH EMPTY KEY.
    DATA columnfromfile TYPE columnsinfo.

    IF check_structure = abap_on.
*    get the title row  compare with tab structure if need
      DO columncount TIMES.
        column = sy-index.
        DATA(cellvalue) = firstsheet->get_cell_content(
                                  EXPORTING
                                    iv_row     = 1
                                    iv_column  = column ).
        APPEND INITIAL LINE TO columnfromfile ASSIGNING FIELD-SYMBOL(<columnfromfile>).
        <columnfromfile>-column = column.
        <columnfromfile>-columnname = cellvalue.
        IF line_exists( tablecomponents[ name = cellvalue ] ).
          DELETE tablecomponents WHERE name = cellvalue.
        ELSE.
          error_text = error_text && |,{ cellvalue }|.
        ENDIF.

      ENDDO.
      IF error_text IS NOT INITIAL.
        MESSAGE e001(00) RAISING file_open_error WITH error_text.
      ENDIF.
    ENDIF.
*    get the title row  compare with tab structure if need

    "last row
    DATA(rowcount) = lines( pt_tab[] ).
    DATA(currentrow) = start_row.
*get data of excel

    CASE check_structure.
      WHEN abap_on.
        "按照字段对应获取数据

        LOOP AT pt_tab ASSIGNING FIELD-SYMBOL(<currentrow>).
          LOOP AT columnfromfile REFERENCE INTO DATA(currentcolumn).
            ASSIGN COMPONENT currentcolumn->*-columnname OF STRUCTURE <currentrow> TO FIELD-SYMBOL(<cellvalue>).
            firstsheet->set_cell_content( EXPORTING iv_row    = currentrow
                                                    iv_column = currentcolumn->column
                                                    iv_value  = <cellvalue> ).
            UNASSIGN <cellvalue>.
          ENDLOOP.
          currentrow = currentrow + 1.
        ENDLOOP.

      WHEN OTHERS.
        "按照顺序获取数据
        CLEAR column.
        LOOP AT pt_tab ASSIGNING <currentrow>.
          DO columncount TIMES.
            column = column + 1.
            ASSIGN COMPONENT column OF STRUCTURE <currentrow> TO <cellvalue>.
            firstsheet->set_cell_content( EXPORTING iv_row    = currentrow
                                                    iv_column = column
                                                    iv_value  = <cellvalue> ).
            UNASSIGN <cellvalue>.
          ENDDO.
          CLEAR column.
          currentrow = currentrow + 1.
        ENDLOOP.

    ENDCASE.

    TRY.
        xstring_excel = xlsxdocument->save( ).
      CATCH cx_openxml_format  INTO openxml_format.
        error_text = openxml_format->get_text( ).
        error_text = |Error occurs when save data from specific sheet: | && error_text.
      CATCH cx_openxml_not_found  INTO openxml_not_found.
        error_text = openxml_not_found->get_text( ).
        error_text = |Error occurs when save data from specific sheet: | && error_text .
      CATCH cx_openxml_not_allowed INTO openxml_not_allowed.
        error_text = openxml_not_allowed->get_text( ).
        error_text = |Error occurs when save data from specific sheet: | && error_text .
    ENDTRY.
    IF error_text IS NOT INITIAL.
      MESSAGE e001(00) RAISING file_open_error WITH error_text.
    ENDIF.

  ENDMETHOD.

ENDCLASS.

PARAMETERS: file  TYPE /iwbep/sb_odata_ty_char_400sm,
            sheet TYPE /iwbep/sb_odata_ty_char_400sm NO-DISPLAY,
            id    TYPE i NO-DISPLAY,
            check TYPE char1 AS CHECKBOX,
            row   TYPE i.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR file.
  DATA: file_table TYPE filetable,
        rc         TYPE i.

  CALL METHOD cl_gui_frontend_services=>file_open_dialog
    EXPORTING
      file_filter             = 'Excel(*.xlsx)'
    CHANGING
      file_table              = file_table
      rc                      = rc
    EXCEPTIONS
      file_open_dialog_failed = 1
      cntl_error              = 2
      error_no_gui            = 3
      not_supported_by_gui    = 4
      OTHERS                  = 5.
  READ TABLE file_table ASSIGNING FIELD-SYMBOL(<fs_file>) INDEX 1.
  IF sy-subrc = 0.
    file = <fs_file>.
  ENDIF.

START-OF-SELECTION.
*  sheet = 'Sheet1'.
  DATA lr TYPE REF TO zxlsx.
  DATA itab TYPE typ_t_alv.
  itab = VALUE #( ( col001 = 1 )
                  ( col002 = 2 )
                  ( col003 = 3 )
                  ( col004 = 4 )
                  ( col005 = 5 ) ).
  CREATE OBJECT lr.
  lr->import_document_from_frontend( file ).

  lr->deserialize_document(
        EXPORTING
          pi_sheetname    = sheet
          pi_sheetid      = id
          check_structure = check
          start_row       = row
          pt_tab          = itab ).

  lr->export_document_from_server( file ).

  cl_demo_output=>display( itab ).

z858622025
关注
专栏目录
2020.02.28 【ABAP随笔】- EXCEL批导程式3 - CL_EHFND_XLSX类 比较好用快速准确
m0_37461511的博客
02-27 724
怎么找到这个类的呢，是因为Wang Jerry 的一篇文章。感谢sap研究院大佬让我更透彻的了解了一下XLSX其实就是多个XML文件组合成的。 文章链接如下，请大家自行关注查看： https://mp.weixin.qq.com/s/29v98Z4mgFboZjBTLsiWbw 关键 DATA error_text TYPE string. lv_filenam...
ABAP xlsx格式EXCEL文件导出（非OLE或DOI方式）
Nathan的博客
07-22 1793
*&---------------------------------------------------------------------**&ReportYN_XLSX_TEST*&---------------------------------------------------------------------**&*&----------...
2022.05.14 【ABAP随笔】-SAP后台server读取Excel方案的想法
m0_37461511的博客
05-14 1097
读取Excel方案的研究 我之前在文章(Excel批量导入)中提到过使用CL_XLSX_DOCUMENT来处理excel，此时EXCEL文件被当作多个xml文件来出了，速度和效率上有了很大的提升。 但是需要使用cl_ehfnd_xlsx这个类来得到EXCEL的单元格的值，发现很多客户还在使用ERP ECC6.0 ON HANA 的架构，所以系统里面没有这个类。 我们可以看到这个类是属于该S4的...
2020.03.04 【ABAP随笔】- Excel批量导出7-CL_XLSX_DOCUMENT 导出
m0_37461511的博客
03-04 1348
今天写一下CL_XLSX_DOCUMENT个人觉得这个比较好用。 导出代码如下： SELECT * INTO CORRESPONDING FIELDS OF TABLE @lt_zmmt001 FROM zmmt001. IF sy-subrc EQ 0 AND p_file IS NOT INITIAL . lv_filename = p_f...
ABAP读取Excel方法大全
u012232542的博客
11-20 3213
前言 ABAP读取Excel文件可以使用多种方式实现，OLE是最常用的技术，但速度及兼容性较差；也可以使用DOI接口读取，最新的技术则通过XML技术进行解析，采用最新的面向对象编程，容易理解，且兼容性较好。 方法 标准函数 函数名 说明 TEXT_CONVERT_XLS_TO_SAP 基于OLE，需要内表结构与Exce列顺序一致 ALSM_EXCEL_TO_INTERNAL_TABL 基于OLE,按单元读取出来，最长只支持50个字符 UPLOAD_XLS_FILE_2_ITAB （尚
springboot使用freemarker进行复杂Excel导出（多sheet页）
qq_45801211的博客
07-23 1194
springboot使用freemarker模板进行复杂Excel导出
excaljs导入导出xlxs文件的方法
qq_47657875的博客
03-16 295
excaljs导入导出xlxs文件的方法
Excel文件(xlsx)导出json文件
02-05
Excel文件(xlsx)导出json文件 Excel文件(xlsx)导出json文件 Excel文件(xlsx)导出json文件 Excel文件(xlsx)导出json文件 Excel文件(xlsx)导出json文件 Excel文件(xlsx)导出json文件 Excel文件(xlsx)导出json文件 ...
js导出excel为xlsx格式
05-27
Javascript导出excel为xlsx格式，兼容IE6+和主流浏览器，下载下来直接可以使用。 其他javascript导出excel插件可看作者文章：https://blog.csdn.net/qq_21693027/article/details/80459677
QT5 Xlsx库,不需安装ms Excel操作Xlsx文件
06-05
QtXlsx是一个读写Excel文件的库。它不需要安装MicrosoftExcel，且可以用于任何Qt5支持的平台.此库可用于1>创建一个新的.xlsx文件2>从.xlsx文件读取数据3>编辑已存在的.xlsx文件。注意：可能不支持.xls文件。
ASP.NET Core 导入导出Excel xlsx 文件实例
01-02
ASP.NET Core 使用EPPlus.Core导入导出Excel xlsx 文件，EPPlus.Core支持Excel 2007/2010 xlsx文件导入导出，可以运行在Windows, Linux和Mac。 EPPlus.Core 是基于EPPlus 更改而来，在Linux 下需要安装libgdiplus 。...
C# 导出excel表格（xls、xlsx两种格式）
09-12
本文将详细讲解如何使用C#来实现Excel表格的导出，包括xls和xlsx两种常见格式。 首先，我们需要理解这两种格式的区别。Xls是Excel早期版本（2003及更早）使用的文件格式，它基于二进制文件结构，支持的最大行数和列...
Python办公自动化案例（二）：对比两个Excel数据内容并标出不同
衍生星球的博客
09-14 396
在数据处理和分析的日常工作中，我们经常需要比较两个Excel文件的差异。这可能是为了验证数据的一致性、检查数据的准确性，或者在版本控制中追踪更改。手动比较这些文件不仅耗时，而且容易出错。幸运的是，Python的openpyxl库提供了一种自动化这一过程的方法。
springBoot整合easyexcel实现导入、导出功能
weixin_71454352的博客
09-14 328
springBoot整合easyexcel实现导入、导出功能
Excel 基础知识-操作手册2
m0_53191230的博客
09-13 1139
Excel中的查找与引用函数非常丰富，以下是一些主要的函数及其使用示例：- 语法：`VLOOKUP(lookup_value, table_array, col_index_num, [range_lookup])`- 示例：假设A列是员工编号，B列是员工姓名，你想根据员工编号查找员工姓名。公式：这将在A2:B100的范围内查找编号123，并返回同一行的B列中的员工姓名。
探索Python的Excel世界：openpyxl的魔法之旅
最新发布
AIGC搞起
09-15 722
openpyxl是一个Python库，它允许你操作Excel文件，就像你在Excel中所做的那样，但完全自动化。你可以创建新的工作簿，读取现有文件，修改单元格，添加图表，甚至设置样式。openpyxl是一个强大的工具，它将Excel的自动化提升到了一个新的水平。通过这个库，你可以轻松地创建、读取、修改和保存Excel文件，而无需打开Excel应用程序。无论你是数据分析师、财务专家还是普通的Excel用户，openpyxl都能为你的工作带来便利和效率。
POI生成Excel文件增加数据验证（下拉序列）
qq_32076957的博客
09-13 324
由于excel数据验证 序列的长度最多255字符， 如果代码中数据的长度超过这个，则生成的excel会提示先修复才能打开，修复完成打开之后发现需要设置数据验证的列没有设置成功。如果想要输入更多数据，则先可以先把数据保存到一个隐藏的sheet中，然后通过公式引用存储的数据再设置数据验证。POI版本为5.2.2。
一个关于Excel的段子
withcsharp2的博客
09-11 546
一个关于Excel的段子
ExcelJS 支持dom table导出xlsx文件吗？
06-01
是的，ExcelJS 支持将 DOM table 导出为 xlsx 文件。可以使用 `ExcelJS.Table.fromDomTable()` 方法将 DOM table 转换为 ExcelJS 的 worksheet 对象，然后再将 worksheet 添加到 workbook 中，最后导出 xlsx 文件。 ...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值