[USACO 1.5.3] Superprime Rib

[题目描述]

Superprime Rib

特殊的质数肋骨

农民约翰母牛总是产生最好的肋骨。
你能通过农民约翰和美国农业部标记在每根肋骨上的数字认出它们。
农民约翰确定他卖给买方的是真正的质数肋骨,是因为从右边开始切下肋骨,每次还剩下的肋骨上的数字都组成一个质数,举例来说:
7 3 3 1
全部肋骨上的数字 7331是质数;三根肋骨 733是质数;二根肋骨 73 是质数;当然,最后一根肋骨 7 也是质数。
7331 被叫做长度 4 的特殊质数。
写一个程序对给定的肋骨的数目 N (1<=N<=8),求出所有的特殊质数。
数字1不被看作一个质数。

PROGRAM NAME: sprime

INPUT FORMAT
单独的一行包含N。

SAMPLE INPUT (file sprime.in) 
4

OUTPUT FORMAT
按顺序输出长度为 N 的特殊质数,每行一个。

SAMPLE OUTPUT (file sprime.out)
2333
2339
2393
2399
2939
3119
3137
3733
3739
3793
3797
5939
7193
7331
7333
7393

[解题思路]

沿袭上题思路，果断1A！

反正只可能是1,2,3,5,7,9这几个数字组成，搜索树深度也最多为8，就直接DFS枚举，加上Miller-Rabin检验，0.00s AC！

[Code]

{
ID: zane2951
PROG: sprime
LANG: PASCAL
}

program sprime;
const
   a:array[1..6] of longint=(1,2,3,5,7,9);
   p:array[1..7] of longint=(2,3,5,7,11,13,17);

var
   q:array[0..111111] of longint;
   n,top,i:longint;

//------------mul----------
function mul(a,b,mo:int64):int64;
begin
   mul:=1;
   while b>0 do
      begin
         if b and 1>0 then mul:=(mul*(a mod mo)) mod mo;
         a:=((a mod mo)*(a mod mo)) mod mo;
         b:=b>>1;
      end;
end;

//----------check----------
function check(x:int64):boolean;
var
   i:longint;

begin
   if x=1 then exit(false);
   for i:=1 to 7 do
      if p[i]<>x then
         if mul(p[i],x-1,x)<>1 then exit(false);
   exit(true);
end;

//-----------run-----------
procedure run(dp:longint; x:int64);
var
   i:longint;
   ce:int64;

begin
   if dp=n then begin inc(top); q[top]:=x; exit; end;
   for i:=1 to 6 do
      begin
         ce:=10*x+a[i];
         if check(ce) then run(dp+1,ce);
      end;
end;

//-----------qs------------
procedure qs(s,t:longint);
var
   i,j,ce,tmp:longint;

begin
   i:=s; j:=t; ce:=q[(i+j)>>1];
   repeat
      while q[i]<ce do inc(i);
      while q[j]>ce do dec(j);
      if i<=j then
         begin
            tmp:=q[i]; q[i]:=q[j]; q[j]:=tmp;
            inc(i); dec(j);
         end;
   until i>j;
   if s<j then qs(s,j); if i<t then qs(i,t);
end;

//----------main-----------
begin
   assign(input,'sprime.in'); reset(input);
   assign(output,'sprime.out'); rewrite(output);
   readln(n);
   top:=0;
   run(0,0);
   qs(1,top);
   for i:=1 to top do writeln(q[i]);
   close(input); close(output);
end.