windows系统ntp服务器一键开启

ntp服务器一键开启脚本

@echo off
REM 自动判断权限问题，主动获取管理员权限
@echo off  
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system" 
 
if '%errorlevel%' NEQ '0' (  
    goto UACPrompt  
) else ( goto gotAdmin )  
   
:UACPrompt  
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs" 
    echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs" 
    "%temp%\getadmin.vbs" 
    exit /B  
   
:gotAdmin  
    if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )  
    pushd "%CD%" 
    CD /D "%~dp0" 
 
:begin

@REM ntp 服务配置
reg add  "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\W32Time\Config" /v "AnnounceFlags" /t REG_DWORD /d 5 /f
reg add  "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\W32Time\TimeProviders\NtpServer" /v "Enabled" /t REG_DWORD /d 1 /f
reg add  "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\W32Time\Parameters" /v "Type" /t REG_SZ /d "NTP" /f
@REM 添加防火墙
netsh advfirewall firewall add rule name="_123 NTP" protocol=UDP dir=in localport=123 action=allow
@REM 设置服务开机自启 todo

@REM 启动服务
net start w32time
netstat -an | find "123"

w32tm /stripchart /computer:127.0.0.1

pause

w32time对应的服务

停止服务

启动服务

服务启动之后的状态

手动配置ntp服务器

配置ntp server

1、 使用组合键WIN + R 启动运行窗口，在打开的窗口中输入regedit，点击确定按钮。

在打开的注册表中输入HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\W32Time\Config，找到并打开Config目录，双击Config目录下的AnnounceFlags。

把注册表项的值设定为5，点击确定按钮。

输入注册表路径HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\W32Time\TimeProviders\NtpServer，双击NtpServer下的Enabled

把Enabled的值设定为1，点击确定按钮 

重启w32time服务

 输入net stop w32time停止服务，再输入net start w32time启动服务。

查看是否配置成功

输入命令  

w32tm /stripchart /computer:127.0.0.1

 查看到下图中的效果说明配置成功

用另一台电脑ntp客户端进行测试

 点击开始，找到windows系统下的控制面板，点击打开“控制面板”。

选择日期和时间

 输入ntp服务器，点击立即更新 

提示下面的错误

需要确保两台服务器时间相差不是太大，比如手动改成一天之内再同步试一下，就可以看到同步成功了