升级oracle19c重建wm_concat函数

背景：

应用之前使用的oracle11数据库，使用了大量的wmsys.wm_concat行转列。升级oracle19c后，没有该方法，查询报错。

解决方案：

第一步：

激活wmsys用户

​
# 首先使用dba账号登录oracle数据库（使用oracle / root用户执行）
sqlplus / as sysdba

# 解锁wmsys用户
alter user wmsys account unlock;

# 并为wmsys用户授权，可根据需要授权，不建议授权所有权限
grant all privileges to wmsys;

# 如果不知道wmsys用户的密码，可以修改其密码
alter user wmsys identified by 123456;

# 使用wmsys用户登录数据库
conn wmsys/123456

第二步：

重建wm_concat函数。

CREATE OR REPLACE TYPE wmsys.WM_CONCAT_IMPL AS OBJECT
(
    CURR_STR VARCHAR2(32767),
    STATIC FUNCTION ODCIAGGREGATEINITIALIZE(SCTX IN OUT WM_CONCAT_IMPL) RETURN NUMBER,
    MEMBER FUNCTION ODCIAGGREGATEITERATE(SELF IN OUT WM_CONCAT_IMPL,
                                         P1 IN VARCHAR2) RETURN NUMBER,
    MEMBER FUNCTION ODCIAGGREGATETERMINATE(SELF IN WM_CONCAT_IMPL,
                                           RETURNVALUE OUT VARCHAR2,
                                           FLAGS IN NUMBER)
        RETURN NUMBER,
    MEMBER FUNCTION ODCIAGGREGATEMERGE(SELF IN OUT WM_CONCAT_IMPL,
                                       SCTX2 IN WM_CONCAT_IMPL) RETURN NUMBER
);
/

-- 定义类型body:
CREATE OR REPLACE TYPE BODY wmsys.WM_CONCAT_IMPL
IS
    STATIC FUNCTION ODCIAGGREGATEINITIALIZE(SCTX IN OUT WM_CONCAT_IMPL)
        RETURN NUMBER
        IS
    BEGIN
        SCTX := WM_CONCAT_IMPL(NULL) ;
        RETURN ODCICONST.SUCCESS;
    END;
    MEMBER FUNCTION ODCIAGGREGATEITERATE(SELF IN OUT WM_CONCAT_IMPL,
                                         P1 IN VARCHAR2)
        RETURN NUMBER
        IS
    BEGIN
        IF(CURR_STR IS NOT NULL) THEN
            CURR_STR := CURR_STR || ',' || P1;
        ELSE
            CURR_STR := P1;
        END IF;
        RETURN ODCICONST.SUCCESS;
    END;
    MEMBER FUNCTION ODCIAGGREGATETERMINATE(SELF IN WM_CONCAT_IMPL,
                                           RETURNVALUE OUT VARCHAR2,
                                           FLAGS IN NUMBER)
        RETURN NUMBER
        IS
    BEGIN
        RETURNVALUE := CURR_STR ;
        RETURN ODCICONST.SUCCESS;
    END;
    MEMBER FUNCTION ODCIAGGREGATEMERGE(SELF IN OUT WM_CONCAT_IMPL,
                                       SCTX2 IN WM_CONCAT_IMPL)
        RETURN NUMBER
        IS
    BEGIN
        IF(SCTX2.CURR_STR IS NOT NULL) THEN
            SELF.CURR_STR := SELF.CURR_STR || ',' || SCTX2.CURR_STR ;
        END IF;
        RETURN ODCICONST.SUCCESS;
    END;
END;
/

CREATE OR REPLACE FUNCTION wmsys.wm_concat(P1 VARCHAR2)
    RETURN VARCHAR2 AGGREGATE USING WM_CONCAT_IMPL ;
/

效果：