利用oracle系统包UTL_SMTP发送邮件

最新推荐文章于 2023-11-10 14:33:11 发布

@大海@

最新推荐文章于 2023-11-10 14:33:11 发布

阅读量1.8k

点赞数

分类专栏： FORM 开发 REPORT 开发

FORM 开发同时被 2 个专栏收录

62 篇文章 3 订阅

订阅专栏

REPORT 开发

23 篇文章 0 订阅

订阅专栏

http://blog.chinaunix.net/uid-23072872-id-3576270.html

要利用oracle的系统包实现发送邮件的功能，必须先以sys用户登录执行以下两个脚本：
$ORACLE_HOME/rdbms/admin/utlsmtp.sql
$ORACLE_HOME/rdbms/admin/utltcp.sql
如遇下面的错误：
ORA-29278: SMTP transient error: 421 Service not available
ORA-06512: at "SYS.UTL_SMTP", line 29
ORA-06512: at "SYS.UTL_SMTP", line 108
ORA-06512: at "SYS.UTL_SMTP", line 463
ORA-06512: at line 53
ORA-24248: XML DB extensible security not installed
select comp_name from dba_registry;
select global_name,utl_inaddr.get_host_address from global_name;
执行脚本：
@$ORACLE_HOME/rdbms/admin/catnoqm.sql;
@$ORACLE_HOME/rdbms/admin/catqm.sql xdb sysaux temp YES;

脚本示例：

CREATE OR REPLACE PROCEDURE PRC_sendmail
(
    p_receiver  VARCHAR2,     -- 邮件接收人
    p_subject   VARCHAR2,     -- 邮件标题
    p_message   VARCHAR2      -- 邮件正文
)
IS
    --下面四个变量请根据实际邮件服务器进行赋值
    v_smtphost           VARCHAR2(30)       := 'smtp.qq.com';                  --SMTP服务器地址(hotmail为smtp.live.com,测试未通过)
    v_smtpport           number(5)          :=25;                                       --smtp服务端口
    v_user               VARCHAR2(30)       := '751365252@qq.com';          --登录SMTP服务器的用户名
    v_pass               VARCHAR2(20)       := 'XXXXXX';                             --登录SMTP服务器的密码
    v_sender             VARCHAR2(50)       := '751365252@qq.com';         --发送者邮箱，一般与 ps_user 对应
    v_conn               UTL_SMTP.connection;                                           --到邮件服务器的连接
    v_msg                varchar2(4000);                                                    --邮件内容

BEGIN

    v_conn := UTL_SMTP.open_connection(v_smtphost, v_smtpport);
    --是用 ehlo() 而不是 helo() 函数
    --否则会报：ORA-29279: SMTP 永久性错误: 503 5.5.2 Send hello first.
    UTL_SMTP.ehlo(v_conn, v_smtphost);

    -- smtp服务器登录校验
    UTL_SMTP.command(v_conn, 'AUTH LOGIN');
    UTL_SMTP.command(v_conn,UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(UTL_RAW.cast_to_raw(v_user))));
    UTL_SMTP.command(v_conn,UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(UTL_RAW.cast_to_raw(v_pass))));

    --设置发件人及收件人
    UTL_SMTP.mail(v_conn, '<'||v_sender||'>');
    UTL_SMTP.rcpt(v_conn, '<'||p_receiver||'>');

    -- 创建要发送的邮件内容注意报头信息和邮件正文之间要空一行
    v_msg :='Date:'|| TO_CHAR(SYSDATE, 'yyyy mm dd hh24:mi:ss')
            || UTL_TCP.CRLF || 'From: '|| v_sender || ''
            || UTL_TCP.CRLF || 'To: ' || p_receiver || ''
            || UTL_TCP.CRLF || 'Subject: ' || p_subject
            || UTL_TCP.CRLF || UTL_TCP.CRLF          -- 这前面是报头信息
            || p_message;                                        -- 这个是邮件正文

    --打开流
    UTL_SMTP.open_data(v_conn);
    --标题和内容都都可用中文
    UTL_SMTP.write_raw_data(v_conn, UTL_RAW.cast_to_raw(v_msg));
    --关闭流
    UTL_SMTP.close_data(v_conn);
    --关闭连接
    UTL_SMTP.quit(v_conn);

EXCEPTION
WHEN OTHERS THEN
     DBMS_OUTPUT.put_line(DBMS_UTILITY.format_error_stack);
     DBMS_OUTPUT.put_line(DBMS_UTILITY.format_call_stack);
     UTL_SMTP.quit(v_conn);

END PRC_sendmail;
/

执行脚本：

SQL> exec PRC_sendmail(p_receiver => '751365252@qq.com',p_subject => 't张ttt',p_message => 'yy在yy');

-- The End --