OLEDB Excel INSERT UPDATE SELECT用法

最新推荐文章于 2022-06-07 16:38:49 发布
最新推荐文章于 2022-06-07 16:38:49 发布
阅读量8.4k 收藏 6
点赞数
文章标签： excel insert radiobutton dataset microsoft 工作

如何在 Visual Basic .NET 中使用 ADO.NET 检索和修改 Excel 工作簿中的记录

察看本文应用于的产品
文章编号:316934
最后修改:2004年6月29日
修订:7.0

概要

本文讨论如何使用 ADO.NET 检索 Microsoft Excel 工作簿中的数据、修改现有工作簿中的数据或将数据添加至新的工作簿中。要通过 ADO.NET 访问 Excel 工作簿，您可以使用 Jet OLE DB 提供程序；本文提供了您所需要的信息，以便您可以在 Excel 充当目标数据源时使用 Jet OLE DB 提供程序。

回到顶端

如何将 Jet OLE DB 提供程序与 Microsoft Excel 工作簿配合使用

Microsoft Jet 数据库引擎可以通过可安装的索引顺序访问方法 (ISAM) 驱动程序，访问格式为其他数据库文件（例如 Excel 工作簿）的数据。要打开 Microsoft Jet 4.0 OLE DB 提供程序所支持的外部格式，请在连接的扩展属性中指定数据库类型。Jet OLE DB 提供程序对于 Microsoft Excel 工作簿支持下列数据库类型：
Excel 3.0
Excel 4.0
Excel 5.0
Excel 8.0
注意：对于 Microsoft Excel 5.0 和 7.0 (95) 工作簿，请使用 Excel 5.0 源数据库类型；对于 Microsoft Excel 8.0 (97)、9.0 (2000) 和 10.0 (2002) 工作簿，请使用 Excel 8.0 源数据库类型。本文中的示例使用的是格式为 Excel 2000 和 Excel 2002 的 Excel 工作簿。

连接字符串
要使用 Jet OLE DB 提供程序访问 Excel 工作簿，请使用具有下列语法的连接字符串：
Provider=Microsoft.Jet.OLEDB.4.0;Data Source=C:/Book1.xls;Extended Properties="Excel 8.0;HDR=YES;"
在连接字符串中，用 Data Source 参数指定工作簿的完整路径和文件名。Extended Properties 参数可包含两种属性：一个属性用于 ISAM 版本，一个属性用于指示表是否包括标题。

使用 Excel 工作簿时，默认情况下，区域中的第一行是标题行（或字段名称）。如果第一个区域不包含标题，您可以在连接字符串的扩展属性中指定 HDR=NO。如果您在连接字符串中指定 HDR=NO，Jet OLE DB 提供程序将自动为您命名字段（F1 表示第一个字段，F2 表示第二个字段，依此类推）。
数据类型
与传统的数据库不同，在 Excel 表中没有指定列的数据类型的直接方式。而是，OLE DB 提供程序通过对一列中的八行进行扫描来猜测 该字段的数据类型。您可以通过为连接字符串的扩展属性中的 MAXSCANROWS 设置指定一个一 (1) 至十六 (16) 之间的值，来更改要扫描的行数。

 表命名规则 您可以通过若干种方式引用 Excel 工作簿中的表（或区域）：
•使用工作表名称后面跟一个美元符号（例如 [Sheet1$] 或 [My Worksheet$]）。以此方式引用的工作簿包括工作表的整个使用区域。
Select * from [Sheet1$]
•使用带有定义名称的区域（例如 [MyNamedRange]）：
Select * from [MyNamedRange]
•使用带有特定地址的区域（例如 [Sheet1$A1:B10]）：
Select * from [Sheet1$A1:B10]
注意：工作表名称后面带美元符号表示该表存在。如果您要创建一个新表，如本文 创建新工作簿和表 一节中所讨论的那样，请不要使用美元符号。

回到顶端

如何将 Excel 工作簿用作 ADO.NET 数据源

检索记录
您可以使用 ADO.NET 中的两种方法之一检索数据库中的记录：使用 Dataset 或使用 DataReader。

Dataset 是一个从数据源检索到的记录的缓存。Dataset 中的数据通常要比数据库中的数据精简得多。但是，您可以像使用实际数据一样使用它，并且无须与实际数据库连接。除了数据检索之外，还可以使用 Dataset 在基础数据库上执行更新操作。

或者，您可以使用 DataReader 从数据库中检索只读、只进数据流。当您使用 DataReader 程序时，由于内存中每次仅有一行，因此性能将增强，系统开销将降低。如果您有大量数据需要检索并且不希望更改基础数据库，则 DataReader 是比 Dataset 更好的选择。

 添加和更新记录 使用 ADO.NET，您可以通过三种方式之一在工作簿中插入和更新记录：

•直接运行一个命令，每次插入或更新一个记录。为此，您可以在自己的连接上创建一个 OLEDbCommand 对象，并将其 CommandText 属性设置成一个插入记录的有效命令

INSERT INTO [Sheet1$] (F1, F2) values ('111', 'ABC')
或一个可更新记录的命令，

 
UPDATE [Sheet1$] SET F2 = 'XYZ' WHERE F1 = '111'
然后调用 ExecuteNonQuery 方法。
•对使用 Excel 工作簿中的一个表/查询填充的一个 DataSet 做一些更改，然后调用 DataAdapter 的 Update 方法，以将这些更改从 DataSet 解析回工作簿。不过，要使用 Update 方法执行更新解析，您必须为 DataAdapter 的 InsertCommand 设置参数化命令： 
INSERT INTO [Sheet1$] (F1, F2) values (?, ?)
并为 UpdateCommand 设置参数化命令： 
UPDATE [Sheet1$] SET F2 = ? WHERE F1 = ?
必须要用 INSERT 和 UPDATE 的参数化命令，因为 OleDbDataAdapter 不提供 Excel 工作簿的主键/索引信息；没有主键/索引字段，CommandBuilder 就无法自动为您生成命令。
•如果 Jet OLE DB 提供程序能够使用另外的数据源，请将该数据源中的数据导出到 Excel 工作簿中。可通过 Jet OLE DB 提供程序以这种方式使用的数据源包括：文本文件、Microsoft Access 数据库，当然也包括其他 Excel 工作簿。使用单个 INSERT INTO 命令，您可以将其他表/查询中的数据导出到您的工作簿中： 
INSERT INTO [Sheet1$] IN 'C:/Book1.xls' 'Excel 8.0;' SELECT * FROM MyTable"
INSERT INTO 要求目标表（或工作表）已存在，并且数据已附加到目标表中。

您还可以使用 SELECT..INTO 将您的表/查询导出到工作簿中： 
SELECT * INTO [Excel 8.0;Database=C:/Book1.xls].[Sheet1] FROM [MyTable]
当您使用 SELECT..INTO 时，如果目标表或工作簿不存在，将为您创建。如果在发出 SELECT..INTO 命令之前表已存在，您将收到错误信息。

本文的稍后的示例代码 部分对这些在工作簿中添加和更新记录的方法中的每一种都进行了说明。

删除记录
虽然 Jet OLE DB 提供程序允许您在 Excel 工作簿中插入和更新记录，但是不允许进行 DELETE（删除）操作。如果您尝试对一个或多个记录执行 DELETE 操作，您将收到以下错误信息：
Deleting data in a linked table is not supported by this ISAM.
这是将 Excel 工作簿作为数据库进行处理时所固有的限制。
创建工作簿和表
要在 Excel 工作簿中创建表，请运行 CREATE TABLE 命令： 
CREATE TABLE Sheet1 (F1 char(255), F2 char(255))
 当您运行此命令时，将使用您在命令中指定的表名称创建新的工作表。如果不存在要连接的工作簿，也会创建该工作簿。

本文的 示例代码 部分说明了如何使用 CREATE TABLE 命令创建新的工作簿和表。

回到顶端

分步操作

示例代码
1.启动一个新的 Visual Basic .NET Windows 应用程序项目。

默认情况下会创建 Form1。
2.向 Form1 添加六个 RadioButton（单选按钮）控件和一个 Button（按钮）控件。
3.选中所有单选按钮控件，并将大小属性设置为 200,24。
4.在视图菜单上，单击代码。
5.在代码模块的开始处添加以下行： 
Imports System.Data.OleDb
6.将以下代码插入到Form 类中： 
Private m_sConn1 As String = "Provider=Microsoft.Jet.OLEDB.4.0;" & _
            "Data Source=C:/ExcelData1.xls;" & _
            "Extended Properties=""Excel 8.0;HDR=YES"""
            Private m_sConn2 As String = "Provider=Microsoft.Jet.OLEDB.4.0;" & _
            "Data Source=C:/ExcelData2.xls;" & _
            "Extended Properties=""Excel 8.0;HDR=YES"""
            Private m_sNorthwind = _
            "C:/Program Files/Microsoft Office/Office10/Samples/Northwind.mdb"
            Private m_sAction As String
            Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
            RadioButton1.Text = "Create_Workbook"
            RadioButton2.Text = "Retrieve_Records"
            RadioButton3.Text = "Add_Records"
            RadioButton4.Text = "Update_Records"
            RadioButton5.Text = "Update_Individual_Cells"
            RadioButton6.Text = "Use_External_Source"
            Button1.Text = "Go!"
            End Sub
            Private Sub RadioButtons_Click(ByVal sender As Object, ByVal e As System.EventArgs) _
            Handles RadioButton1.Click, RadioButton2.Click, RadioButton3.Click, _
            RadioButton4.Click, RadioButton5.Click, RadioButton6.Click
            m_sAction = sender.Text'Store the text for the selected radio button
            End Sub
            Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
            Try
            ' Call the associated routine to add/update/modify the workbook.
            Select Case m_sAction
            Case "Create_Workbook" : Create_Workbook()
            Case "Retrieve_Records" : Retrieve_Records()
            Case "Add_Records" : Add_Records()
            Case "Update_Records" : Update_Records()
            Case "Update_Individual_Cells" : Update_Individual_Cells()
            Case "Use_External_Source" : Use_External_Source()
            End Select
            Catch ex As OleDbException
            Dim er As OleDbError
            For Each er In ex.Errors
            MsgBox(er.Message)
            Next
            Catch ex2 As System.InvalidOperationException
            MsgBox(ex2.Message)
            End Try
            End Sub
            Public Sub Create_Workbook()
            ' If the workbooks already exist, prompt to delete.
            Dim answer As MsgBoxResult
            If Dir("C:/ExcelData1.xls") <> "" Or Dir("C:/ExcelData2.xls") <> "" Then
            answer = MsgBox("Delete existing workbooks (C:/ExcelData1.xls and " & _
            "C:/ExcelData2.xls)?", MsgBoxStyle.YesNo)
            If answer = MsgBoxResult.Yes Then
            If Dir("C:/ExcelData1.xls") <> "" Then Kill("C:/ExcelData1.xls")
            If Dir("C:/ExcelData2.xls") <> "" Then Kill("C:/ExcelData2.xls")
            Else
            Exit Sub
            End If
            End If
            '==========================================================================
            ' Create a workbook with a table named EmployeeData. The table has 3
            ' fields: ID (char 255), Name (char 255) and Birthdate (date).
            '==========================================================================
            Dim conn As New OleDbConnection()
            conn.ConnectionString = m_sConn1
            conn.Open()
            Dim cmd1 As New OleDbCommand()
            cmd1.Connection = conn
            cmd1.CommandText = "CREATE TABLE EmployeeData (Id char(255), Name char(255), BirthDate date)"
            cmd1.ExecuteNonQuery()
            cmd1.CommandText = "INSERT INTO EmployeeData (Id, Name, BirthDate) values ('AAA', 'Andrew', '12/4/1955')"
            cmd1.ExecuteNonQuery()
            conn.Close()
            '==========================================================================
            ' Create a workbook with a table named InventoryData. The table has 3
            ' fields: Product (char 255), Qty (float) and Price (currency).
            '==========================================================================
            conn.ConnectionString = m_sConn2
            conn.Open()
            Dim cmd2 As New OleDbCommand()
            cmd2.Connection = conn
            cmd2.CommandText = "CREATE TABLE InventoryData (Product char(255), Qty float, Price currency)"
            cmd2.ExecuteNonQuery()
            cmd2.CommandText = "INSERT INTO InventoryData (Product, Qty, Price) values ('Cola', 200, 1.35)"
            cmd2.ExecuteNonQuery()
            cmd2.CommandText = "INSERT INTO InventoryData (Product, Qty, Price) values ('Chips', 550, 0.89)"
            cmd2.ExecuteNonQuery()
            conn.Close()
            ' NOTE: You can ALTER and DROP tables in a similar fashion.
            End Sub
            Public Sub Retrieve_Records()
            '==========================================================
            'Use a DataReader to read data from the EmployeeData table.
            '==========================================================
            Dim conn1 As New System.Data.OleDb.OleDbConnection(m_sConn1)
            conn1.Open()
            Dim cmd1 As New System.Data.OleDb.OleDbCommand("Select * From [EmployeeData$]", conn1)
            Dim rdr As OleDbDataReader = cmd1.ExecuteReader
            Debug.WriteLine(vbCrLf & "EmployeeData:" & vbCrLf & "=============")
            Do While rdr.Read()
            Debug.WriteLine(System.String.Format("{0,-10}{1, -15}{2}", _
            rdr.GetString(0), rdr.GetString(1), _
            rdr.GetDateTime(2).ToString("d")))
            Loop
            rdr.Close()
            conn1.Close()
            '========================================================
            'Use a DataSet to read data from the InventoryData table.
            '========================================================
            Dim conn2 As New OleDbConnection(m_sConn2)
            Dim da As New OleDbDataAdapter("Select * From [InventoryData$]", conn2)
            Dim ds As DataSet = New DataSet()
            da.Fill(ds)
            Debug.WriteLine(vbCrLf & "InventoryData:" & vbCrLf & "==============")
            Dim dr As DataRow
            For Each dr In ds.Tables(0).Rows'Show results in output window
            Debug.WriteLine(System.String.Format("{0,-15}{1, -6}{2}", _
            dr("Product"), dr("Qty"), dr("Price")))
            Next
            conn2.Close()
            End Sub
            Public Sub Add_Records()
            '==========================================================================
            ' Run an INSERT INTO command to add new records to the workbook.
            '==========================================================================
            Dim conn1 As New System.Data.OleDb.OleDbConnection(m_sConn1)
            conn1.Open()
            Dim cmd As New System.Data.OleDb.OleDbCommand()
            cmd.Connection = conn1
            cmd.CommandText = "INSERT INTO [EmployeeData$] (ID, Name, BirthDate) values ('CCC', 'Charlie', '10/14/48')"
            cmd.ExecuteNonQuery()
            cmd.CommandText = "INSERT INTO [EmployeeData$] (ID, Name, BirthDate) values ('DDD', 'Deloris', '7/19/98')"
            cmd.ExecuteNonQuery()
            conn1.Close()
            '====================================================================
            'Use the InsertCommand object to add new records to the InventoryData
            'table.
            '====================================================================
            Dim conn2 As New OleDbConnection(m_sConn2)
            Dim da As New OleDbDataAdapter("Select * From [InventoryData$]", conn2)
            Dim ds As DataSet = New DataSet()
            da.Fill(ds, "MyExcelTable")
            ' Generate the InsertCommand and add the parameters for the command.
            da.InsertCommand = New OleDbCommand( _
            "INSERT INTO [InventoryData$] (Product, Qty, Price) VALUES (?, ?, ?)", conn2)
            da.InsertCommand.Parameters.Add("@Product", OleDbType.VarChar, 255, "Product")
            da.InsertCommand.Parameters.Add("@Qty", OleDbType.Double).SourceColumn = "Qty"
            da.InsertCommand.Parameters.Add("@Price", OleDbType.Currency).SourceColumn = "Price"
            ' Add two new records to the dataset.
            Dim dr As DataRow
            dr = ds.Tables(0).NewRow
            dr("Product") = "Bread" : dr("Qty") = 390 : dr("Price") = 1.89 : ds.Tables(0).Rows.Add(dr)
            dr = ds.Tables(0).NewRow
            dr("Product") = "Milk" : dr("Qty") = 99 : dr("Price") = 2.59 : ds.Tables(0).Rows.Add(dr)
            ' Apply the dataset changes to the actual data source (the workbook).
            da.Update(ds, "MyExcelTable")
            conn2.Close()
            End Sub
            Public Sub Update_Records()
            '==========================================================================
            ' Run an UPDATE command to change a record in the EmployeeData
            ' table.
            '==========================================================================
            Dim conn1 As New System.Data.OleDb.OleDbConnection(m_sConn1)
            conn1.Open()
            Dim cmd As New System.Data.OleDb.OleDbCommand()
            cmd.Connection = conn1
            cmd.CommandText = "UPDATE [EmployeeData$] " & _
            "SET NAME = 'Aaron', BirthDate = '5/4/1975' WHERE ID = 'AAA'"
            cmd.ExecuteNonQuery()
            conn1.Close()
            '====================================================================
            ' Use the UpdateCommand object to modify records in the InventoryData
            ' table.
            '====================================================================
            Dim conn2 As New OleDbConnection(m_sConn2)
            Dim da As New OleDbDataAdapter("Select * From [InventoryData$]", conn2)
            Dim ds As DataSet = New DataSet()
            da.Fill(ds, "MyInventoryTable")
            ' Generate the UpdateCommand and add the parameters for the command.
            da.UpdateCommand = New OleDbCommand( _
            "UPDATE [InventoryData$] SET Qty = ?, Price=? WHERE Product = ?", conn2)
            da.UpdateCommand.Parameters.Add("@Qty", OleDbType.Numeric).SourceColumn = "Qty"
            da.UpdateCommand.Parameters.Add("@Price", OleDbType.Currency).SourceColumn = "Price"
            da.UpdateCommand.Parameters.Add("@Product", OleDbType.VarChar, 255, "Product")
            ' Update the first two records.
            ds.Tables(0).Rows(0)("Qty") = 1000
            ds.Tables(0).Rows(0)("Price") = 10.1
            ds.Tables(0).Rows(1)("Qty") = 2000
            ds.Tables(0).Rows(1)("Price") = 20.2
            ' Apply the dataset changes to the actual data source (the workbook).
            da.Update(ds, "MyInventoryTable")
            conn2.Close()
            End Sub
            Public Sub Update_Individual_Cells()
            '==========================================================================
            ' Update individual cells on the EmployeeData worksheet;
            ' specifically, cells F3, G3, and I4 are modified.
            '==========================================================================
            ' NOTE: The connection string indicates that the table does *NOT*
            ' have a header row.
            Dim conn As New System.Data.OleDb.OleDbConnection(m_sConn1.Replace("HDR=YES", "HDR=NO"))
            conn.Open()
            Dim cmd As New System.Data.OleDb.OleDbCommand()
            cmd.Connection = conn
            cmd.CommandText = "UPDATE [EmployeeData$F3:G3] SET F1 = 'Cell F3', F2 = 'Cell G3'"
            cmd.ExecuteNonQuery()
            cmd.CommandText = "UPDATE [EmployeeData$I4:I4] SET F1 = 'Cell I4'"
            cmd.ExecuteNonQuery()
            conn.Close()
            End Sub
            Public Sub Use_External_Source()
            ' Open a connection to the sample Northwind Access database.
            Dim conn As New System.Data.OleDb.OleDbConnection( _
            "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & m_sNorthwind & ";")
            conn.Open()
            Dim cmd As New System.Data.OleDb.OleDbCommand()
            cmd.Connection = conn
            '=======================================================================
            ' Run an INSERT..INTO command on the Northwind database to append
            ' the records from a table/query to an existing table in the Excel
            ' workbook.
            '=======================================================================
            cmd.CommandText = "INSERT INTO [EmployeeData$] IN 'C:/ExcelData1.xls' 'Excel 8.0;'" & _
            "SELECT EmployeeID AS ID, FirstName AS Name, BirthDate FROM Employees"
            cmd.ExecuteNonQuery()
            '==========================================================================
            ' Run a SELECT..INTO command on the Northwind database to insert
            ' all the records from a table/query into a new sheet in the Excel
            ' workbook.
            '==========================================================================
            cmd.CommandText = "SELECT * INTO [Excel 8.0;Database=C:/ExcelData2.xls].[ProductSales]" & _
            "FROM [Product Sales for 1997]"
            cmd.ExecuteNonQuery()
            conn.Close()
            End Sub
7.如果需要，可为代码中的 m_sNorthwind 成员修改指向 Access 示例数据库 Northwind 的路径。
试运行
1.在视图菜单上，指向其他窗口，然后单击输出以显示输出窗口。
2.按 F5 键生成并运行程序。
3.单击 Create_Workbook，然后单击 Go（执行。下同）。Create_Workbook 过程将运行 CREATE TABLE 命令以创建两个新的工作簿：C:/ExcelData1.xls 和 C:/ExcelData2.xls。ExcelData1.xls 包含一个名为 EmployeeData 的工作表（表），ExcelData2.xls 包含一个名为 InventoryData 的工作表（表）。这两个表都填入了记录。

注意：请在此测试的每个其余步骤中，在 Excel 中打开工作簿以检查结果。或者，单击 Retrieve_Records 以在 Visual Studio .NET 的输出窗口中查看表内容。
4.单击 Retrieve_Records，然后单击 Go。Retrieve_Records 过程将从表中提取记录并将它们显示在输出窗口中，输出的记录类似于下面的内容： 
EmployeeData:
            =============
            AAA       Andrew         12/4/1955
            InventoryData:
            ==============
            Cola           200   1.35
            Chips          550   0.89
5.单击 Add_Records，然后单击 Go。Add_Records 例程将向每个表添加两条记录： 
EmployeeData:
            =============
            AAA       Andrew         12/4/1955
            CCC       Charlie        10/14/1948
            DDD       Deloris        7/19/1998
            InventoryData:
            ==============
            Cola           200   1.35
            Chips          550   0.89
            Bread          390   1.89
            Milk           99    2.59
6.单击 Update_Records，然后单击 Go。Update_Records 例程在每一个工作簿中更新两条记录： 
EmployeeData:
            =============
            AAA       Aaron          5/4/1975
            CCC       Charlie        10/14/1948
            DDD       Deloris        7/19/1998
            InventoryData:
            ==============
            Cola           1000  10.1
            Chips          2000  20.2
            Bread          390   1.89
            Milk           99    2.59
7.单击 Update_Individual_Cells，然后单击 Go。Update_Individual_Cells 例程修改 ExcelData1.xls 中 EmployeeData 工作表上的特定单元格；具体就是单元格 F3、G3 和 I4 将被更新。
8.单击 Use_External_Source，然后单击 Go。当您使用 INSERT..INTO 命令时，Use_External_Source 例程将 Northwind 表“Employees”中的记录追加到 ExcelData1.xls 中的 EmployeeData 工作表中。并且，Use_External_Source 使用 SELECT..INTO 命令在 ExcelData2.xls 中创建一个包含 Northwind 表“Products”中的所有记录的新表（或工作表）。

注意：如果您单击 Use_External_Source 多次，Employees 列表将被追加多次，原因是主键未被识别或实施。

回到顶端

单元格格式设置

如果您要使用 ADO.NET 在现有工作簿中添加或更新记录，可以将单元格格式应用到该工作簿，以将该格式应用于新的或已更新的记录。当您更新工作簿中的现有记录（或行）时，将保留单元格格式设置。当您在工作簿中插入新的记录（或行）时，新记录将继承上一行的格式设置。

以下过程说明了如何通过示例代码在工作簿中使用格式设置：

1.按 F5 生成并运行该示例。
2.在 Form1 上，单击 Create_Workbook，然后单击 Go。
3.启动 Microsoft Excel 并打开 C:/ExcelData1.xls。
4.对单元格 A2 应用粗体样式。
5.对单元格 B2 应用斜体和下划线样式，并居中对齐。
6.对单元格 C2 应用长日期格式。
7.保存并关闭 C:/ExcelData1.xls。
8.在 Form1 上，单击 Add_Records，然后单击 Go。
9.在 Excel 中打开 C:/ExcelData1.xls，可以看到两个新行继承了第一行的格式设置。

回到顶端

限制

下面是 Jet OLE DB 提供程序关于 Excel 数据源的一些限制：
•您不能使用 ADO.NET 在单元格中插入公式。
•Jet OLE DB 提供程序无法为 Excel 工作簿中的表提供主键/索引信息。因此，您不能使用 CommandBuilder 在 Excel 工作簿中自动更新和插入记录。
zhrtzc
关注
  • 0
    点赞
  • 踩
  • 6
    收藏
    觉得还不错? 一键收藏
  • 4
    评论
Excel 2010 SQL应用018 把一条新记录添加到数据源中
复行数十步
12-10 426
目录 源数据表 解决方案 INSERTINTO语句的使用 源数据表 地区 销售部门 代码 商品 数量 深圳 一部 A00001 订书机 95 广州 二部 A00002 钢笔 50 广州 三部 A00003 钢笔 36 广州 二部 A00004 笔记本 27 佛山 一部 A00005 订书机 56 如图，为某公司的商品销...
vb.net ADO快速读取excel
taitoubiyan1的专栏
01-15 9883
一:写在之前 其实我还在写erlang, vb什么的才和我没关系,要不是为了妹子,才不会看 二:关于vb的看法 感觉vb的资料非常乱,由于时间太久,而且有vb,vb.net的分别,需要花费更多的时间去筛选资料 就比如查找读取excel,查找出大量..2000年多有的资料,简直惨..接口已经变过了.. 三:vb 基本的读取excel方法 Dim xlapp A
复杂表格一键导出
qq_17162169的博客
06-07 774
复杂表格一键导出
前端复杂表格一键导出看这篇就够了（附源码）
程序员成长指北
06-07 957
大厂技术高级前端Node进阶点击上方程序员成长指北，关注公众号回复1，加入高级Node交流群前端导出 excel 的需求很多，但市面上好用的库并不多，讲明白复杂使用场景的文章更少。本文将以文字 + demo 源码的形式，力求讲清楚满足 99% 使用场景的终极 excel 导出方案。如果项目中用到了 AntD，那就更简单了，因为 Table 本身已经设置好了 co...
vb.net读取写入EXCEl的终极方法-NOPI。
chinaherolts2008的博客
12-11 1182
据我浅薄的知识，之前只知道两种操作excel的方法： 一。ODBC操作excel 看下图： 1.ODBC 由于初期连接不同的数据库通过vb.net教程各种不同的API，ODBC就是将各种不同的API封装成统一的接口。当sql语句进入接口时驱动器管理器会判断将他们送入对应的驱动器（driver），由对应的驱动将sql语句送入对应的数据库。 缺点：不同版本的excel，需要添加不同的ODBC数据源。 2.OLEDB与ODBC OLEDB：一个基于COM（Componet Object Model，DOS可执行
FG_List - Copy (2).rar_browngr1_excel_oledb
09-15
6. **写入数据**：同样，通过`OleDbCommand`对象，可以使用`ExecuteNonQuery()`方法执行INSERT、UPDATE或DELETE语句来修改Excel数据。 7. **关闭连接**：操作完成后，记得关闭连接以释放资源： ```vb.net ...
C#操作Excel(OLEDB)
10-25
本示例探讨了如何使用C#通过OLEDB（Object Linking and Embedding, Database）接口来操作Microsoft Excel文件。OLEDB是微软提供的一种数据访问技术，允许程序与各种类型的数据源进行交互，包括Excel工作簿。 首先，...
OLEDB驱动程序大全 Sybase-OleDB-Provider
02-21
2. **数据查询**：支持SQL命令的执行，包括SELECT、INSERT、UPDATE和DELETE等，同时也支持存储过程调用。 3. **事务处理**：支持事务的开始、提交和回滚，确保数据的一致性和完整性。 4. **游标支持**：允许开发者...
oledb-2-13.zip_atl Ole DB oracle_atl ole
09-21
标题中的"oledb-2-13.zip_atl Ole DB oracle_atl ole"表明这是一个关于使用ATL OLE DB与Oracle数据库交互的压缩包。描述提到"ATL OLE_DB数据库引擎模板保存数据到一个简单的数组(42KB)"，意味着这个示例可能展示了...
使用MDAC和Oledb使用MS Excel（xls / xlsx）
04-09
标题中的“使用MDAC和Oledb使用MS Excel（xls / xlsx）”是指通过Microsoft Data Access Components (MDAC) 和OLE DB接口来操作Microsoft Excel文件。MDAC是微软提供的一套组件，它包含了多种数据访问技术，如ADO...
使用“自动化”功能将数据从ADO记录集传输到Excel
04-17
讲述了ADO记录集输出到Excel的方法。 介绍了CopyFromRecordset,GetRows方法。 讲的比较透彻。
VB.net 导入Excel方法(2010及以下版本适用)
热门推荐
宁静致远
07-16 1万+
需引入命名空间：Imports System.Data.OleDb ''' ''' 读取Excel ''' Public Shared Function LoadDataFromExcel() As System.Data.DataTable Dim GeneralCommon As New GeneralCommon L
ADO.NET 读取EXCEL
aamn98463的博客
09-11 174
（转）经常需要在数据库与Execl之间互导数据。net时代，ADO.NET可以使用使用Microsoft.Jet.OleDb访问访问Excel，网上已经有很多类似的资源，最典型也是最简单的可能如下：（asp.net环境） 1//连接字符串 2stringxlsPath=Server.MapPath("~/app_data/somef...
VB中使用ADO的方法创建及访问Excel文件(原创)
雪松软件开发的专栏
06-22 2041
本文主要介绍使用ADO的方法操作EXCEL文件,其它相对于使用EXCEL对象更通用简单.   数据库连接    Dim adoConn As New ADODB.Connection     Dim adoReco As New ADODB.Recordset     Set adoConn = New ADODB.Connection    OLE DB + ODBC Driver
ado.net 如何读取 excel
去日留痕
12-01 1700
原文地址：http://tieba.baidu.com/f?kz=331569890 经常需要在数据库与Execl之间互导数据。net时代，ADO.NET可以使用使用Microsoft.Jet.OleDb访问访问Excel，网上已经有很多类似的资源，最典型也是最简单的可能如下：（asp.net环境）   // 连接字符串                      string xlsPath
Excel vba 如何使用sql语句
最新发布
09-09
### 回答1： Excel VBA 可以通过 ADODB 对象库来使用 SQL 语句。 首先，需要在 VBA 编辑器中打开“工具”菜单，选择“引用”并勾选“Microsoft ActiveX Data Objects x.x Library”（x.x 为版本号，通常为最新版本）。 接下来，可以使用 ADODB 对象来连接数据库、执行 SQL 查询、更新数据库等操作。下面是一个示例代码，演示如何使用 SQL 查询获取数据库中的数据： ``` Sub QueryDatabase() Dim conn As ADODB.Connection Dim rs As ADODB.Recordset Dim sql As String ' 连接数据库 Set conn = New ADODB.Connection conn.ConnectionString = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=C:\Users\username\Documents\example.accdb" conn.Open ' 执行 SQL 查询 sql = "SELECT * FROM table1" Set rs = New ADODB.Recordset rs.Open sql, conn ' 输出查询结果 Do While Not rs.EOF Debug.Print rs("column1") rs.MoveNext Loop ' 关闭连接 rs.Close conn.Close End Sub ``` 在这个示例中，首先创建了一个 ADODB.Connection 对象，并使用 ConnectionString 属性设置连接字符串，指定了要连接的数据库文件路径。然后，执行 SQL 查询并将结果保存到 ADODB.Recordset 对象中，最后遍历结果集并输出查询结果。 这只是一个简单的示例，实际使用中可能需要根据具体情况调整代码。 ### 回答2： 在Excel VBA中，可以使用SQL语句与数据库进行交互。为了使用SQL语句，首先需要确保计算机上已经安装了适当的数据库引擎，并且已经将其添加到VBA项目的引用中。 使用SQL语句的第一步是创建数据库连接对象。可以使用ADODB（ActiveX 数据对象）库中的`Connection`对象来实现。使用以下代码创建数据库连接对象： ```vba Dim conn As New ADODB.Connection Dim connectionString As String connectionString = "Provider=Microsoft.ACE.OLEDB.12.0; Data Source=C:\path\to\database.accdb" conn.Open connectionString ``` 上述代码创建了一个名为`conn`的`Connection`对象，并打开了代表数据库文件路径的连接字符串。可以根据不同的数据库引擎和文件路径进行相应的更改。 接下来，可以使用`Connection`对象的`Execute`方法来执行SQL语句。以下是执行SELECT语句的示例代码： ```vba Dim rs As New ADODB.Recordset Dim sql As String sql = "SELECT * FROM TableName" rs.Open sql, conn While Not rs.EOF ' 对于每一行数据执行操作 ' 可以使用rs.Fields(index)访问每一列的值 rs.MoveNext Wend rs.Close ``` 上述代码创建了一个名为`rs`的`Recordset`对象，并执行了一个SELECT语句来检索数据。通过循环遍历记录集对象，可以逐行处理返回的数据。 除了SELECT语句外，还可以执行INSERT、UPDATE和DELETE等SQL语句。只需将相应的SQL语句赋值给`sql`变量，然后使用`Execute`方法执行即可。 最后，记得在完成操作后关闭连接和记录集对象： ```vba rs.Close conn.Close ``` 通过以上步骤，你可以在Excel VBA中使用SQL语句与数据库进行交互。特别是对于需要大量数据处理和复杂查询的任务，使用SQL语句可以更高效地操作数据。 ### 回答3： 使用Excel VBA 可以利用SQL 语句来操作数据库。下面是使用Excel VBA 中 SQL 语句的一些基本步骤： 1. 首先需要设置 VBA 中对于数据库的引用。在 VBA 编辑器中，选择 "工具" -> "引用"，勾选 "Microsoft ActiveX Data Objects x.x Library" ，点击确定。 2. 在 VBA 代码中，使用「ADODB.Connection」对象来建立到数据库的连接。可以使用以下语句创建连接对象： ```vba Dim conn As New ADODB.Connection ``` 3. 使用连接字符串指定数据库的类型和文件路径，例如使用 Microsoft Access 数据库可以使用如下连接字符串： ```vba conn.ConnectionString = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=<路径\文件名.accdb>;" ``` 4. 使用「conn.Open」方法打开数据库连接： ```vba conn.Open ``` 5. 在连接成功后，可以使用「conn.Execute」方法执行 SQL 语句。以下是一个示例： ```vba conn.Execute "UPDATE 表名 SET 字段名1='值1' WHERE 字段名2='值2';" ``` 6. 如果想要从数据库中检索数据，可以使用「ADODB.Recordset」对象。首先建立一个 Recordset 对象，然后使用「conn.Execute」方法执行 SQL 查询语句，并将结果存储在 Recordset 对象中。以下是一个示例： ```vba Dim rs As New ADODB.Recordset rs.Open "SELECT * FROM 表名;", conn ``` 7. 在使用完毕后，使用「conn.Close」方法关闭数据库连接： ```vba conn.Close ``` 以上就是使用 Excel VBA 中 SQL 语句的基本步骤。可以根据具体的需求，使用不同的 SQL 语句对数据库进行增删改查的操作。
评论 4
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值