Hive之表优化

一、小表、大表 Join 

将 key 相对分散，并且数据量小的表放在 join 的左边，这样可以有效减少内存溢出错误发生的几率；再进一步，可以使用 map join 让小的维度表（1000 条以下的记录条数）先进内存。在 map 端完成 reduce。 

新版的 hive 已经对小表 JOIN 大表和大表 JOIN 小表进行了优化。小表放在左边和右边已经没有明显区别。 

例：

1、创建大表

create table bigtable(
id bigint, 
time bigint, 
uid string, 
keyword string, 
url_rank int, 
click_num int, 
click_url string
) row format delimited fields terminated by '\t';

导入大表数据

load data local inpath '/opt/temp/hive/bigtable' into table bigtable;

2、创建小表

create table smalltable(
id bigint, 
time bigint, 
uid string, 
keyword string, 
url_rank int, 
click_num int, 
click_url string
) row format delimited fields terminated by '\t';

导入小表数据

load data local inpath '/opt/temp/hive/smalltable' into table smalltable;

3、创建join后的表

create table jointable(
id bigint,
time bigint,
uid string,
keyword string,
url_rank int,
click_num int,
click_url string
) row format delimited fields terminated by '\t';

4、关闭 mapjoin 功能（默认是打开的） 

set hive.auto.convert.join=false;

5、小表join大表

insert overwrite table jointable
select b.id, b.time, b.uid, b.keyword,
b.url_rank, b.click_num, b.click_url
from smalltable s
left join bigtable b
on b.id = s.id;

耗时：

Total MapReduce CPU Time Spent: 40 seconds 990 msec

6、执行大表 JOIN 小表语句 

insert overwrite table jointable
select b.id, b.time, b.uid, b.keyword, b.url_rank,
b.click_num,b.click_url
from bigtable  b
left join smalltable s
on s.id = b.id;

耗时：

Total MapReduce CPU Time Spent: 43 seconds 940 msec

二、大表 Join 大表 

1、空 KEY 过滤 

有时 join 超时是因为某些 key 对应的数据太多，而相同 key 对应的数据都会发送到相同的 reducer 上，从而导致内存不够。此时我们应该仔细分析这些异常的 key，很多情况下，这些 key 对应的数据是异常数据，我们需要在 SQL 语句中进行过滤。例如 key 对应的字段为空。

例：

（1）创建原始表

create table ori(
id bigint,
time bigint,
uid string,
keyword string,
url_rank int,
click_num int,
click_url string
) row format delimited fields terminated by '\t';

导入数据：

load data local inpath '/opt/temp/hive/SogouQ1.txt' into table ori;

（2）创建空 id 表 

create table nullidtable(
id bigint,
time bigint,
uid string,
keyword string,
url_rank int,
click_num int,
click_url string
) row format delimited fields terminated by '\t';

导入数据：

load data local inpath '/opt/temp/hive/nullid' into table nullidtable;

（3）创建 join 后表

create table nullidjointable(
id bigint,
time bigint,
uid string,
keyword string,
url_rank int,
click_num int,
click_url string
) row format delimited fields terminated by '\t';

（4）不过滤空id进行两张表join

insert overwrite table nullidjointable
select n.*
from nullidtable n
left join ori o
on n.id = o.id;

耗时：

Total MapReduce CPU Time Spent: 49 seconds 200 msec

（5）过滤空key

insert overwrite table nullidjointable select n.* from (select * from nullidtable where id is not null ) n left join ori o on n.id = o.id;

耗时：

Total MapReduce CPU Time Spent: 22 seconds 160 msec

2、空 key 转换 

有时虽然某个 key 为空对应的数据很多，但是相应的数据不是异常数据，必须要包含在join 的结果中，此时我们可以表 a 中 key 为空的字段赋一个随机的值，使得数据随机均匀地分不到不同的 reducer 上。

（1）不随机分布空 null 值

set mapreduce.job.reduces = 5; 

insert overwrite table nullidjointable
select n.*
from nullidtable n
left join ori o
on n.id = o.id;

出现了数据倾斜，某些 reducer 的资源消耗远大于其他 reducer

（2）随机分布空 null值

insert overwrite table jointable select n.* from nullidtable n full join ori o on case when n.id is null then concat('hive', rand()) else n.id end=o.id;

可以看出来，消除了数据倾斜，负载均衡 reducer 的资源消耗 

三、 MapJoin 

如果不指定 MapJoin 或者不符合 MapJoin 的条件，那么 Hive 解析器会将 Join 操作转换成 Common Join，即：在 Reduce 阶段完成 join。容易发生数据倾斜。可以用 MapJoin 把小表全部加载到内存在 map 端进行 join，避免 reducer 处理。 

1、开启 MapJoin 参数设置 

（1）设置自动选择 MapJoin 

set hive.auto.convert.join = true; 默认为 true 

（2）大表小表的阈值设置（默认 25M 一下认为是小表）

set hive.mapjoin.smalltable.filesize=25000000;

2、MapJoin 工作机制 

 

四、Group By

默认情况下，Map 阶段同一 Key 数据分发给一个 reduce，当一个 key 数据过大时就倾斜了。 并不是所有的聚合操作都需要在 Reduce 端完成，很多聚合操作都可以先在 Map 端进行部分聚合，最后在 Reduce 端得出最终结果。

 1、开启 Map 端聚合参数设置 

（1）是否在 Map 端进行聚合，默认为 True 

hive.map.aggr = true 

（2）在 Map 端进行聚合操作的条目数目 

hive.groupby.mapaggr.checkinterval = 100000 

（3）有数据倾斜的时候进行负载均衡（默认是 false） 

hive.groupby.skewindata = true 

当选项设定为 true，生成的查询计划会有两个 MR Job。第一个 MR Job 中，Map 的输出结果会随机分布到 Reduce 中，每个 Reduce 做部分聚合操作，并输出结果，这样处理的结果是相同的 Group By Key 有可能被分发到不同的 Reduce 中，从而达到负载均衡的目的；第二个 MR Job 再根据预处理的数据结果按照 Group By Key 分布到 Reduce 中（这个过程可以保证相同的 Group By Key 被分布到同一个 Reduce 中），最后完成最终的聚合操作。 

五、 Count(Distinct) 去重统计 

数据量小的时候无所谓，数据量大的情况下，由于 COUNT DISTINCT 操作需要用一个Reduce Task 来完成，这一个 Reduce 需要处理的数据量太大，就会导致整个 Job 很难完成，一般 COUNT DISTINCT 使用先 GROUP BY 再 COUNT 的方式替换。

六、笛卡尔积 

尽量避免笛卡尔积，join 的时候不加 on 条件，或者无效的 on 条件，Hive 只能使用 1个 reducer 来完成笛卡尔积。 

七、行列过滤 

1、列处理

在 SELECT 中，只拿需要的列，如果有，尽量使用分区过滤，少用 SELECT *。
2、行处理

在分区剪裁中，当使用外关联时，过滤条件最好用在子查询里

（1）先关联两张表，再用 where 条件过滤 （不推荐）

 select o.id from bigtable b join ori o on o.id = b.id where o.id <= 10; 

（2）优化后，通过子查询后，再关联表 （推荐）

 select b.id from bigtable b join (select id from ori where id <= 10 ) o on b.id = o.id;