用bat设置ip

用来将所内静态ip和动态dns以及宿舍动态ip和动态dns之间的自动切换。基本原理：采用netsh命令完成。保存下面代码为bat文件，双击运行即可。
==========================================================================
@echo off
title=自动切换ip地址
color 0A
rem *************** 自动切换ip地址程序 ***************
rem 主要用于在计算所内部ip和宿舍ip自动切换
rem **************************************************
set find=%SystemRoot%\System32\find.exe
set config=%SystemRoot%\System32\ipconfig.exe
goto :start

:start
cls
echo ╭─────────────╮
echo ╭──────┤ IP地址自动设置程序 ├──────╮
echo │ ╰─────────────╯ │
echo │本程序能为您自动或手动设置合适的IP,网关及DNS │
echo │ Design By: 齐宝财 │
echo ╰───────────────────────────╯
echo.
echo 1. 设置成计算所静态IP
echo 2. 设置成宿舍动态ip
echo Q. 退出
echo ==========================================================
set type=
set /P type= 请选择: [1],[2]或[3]?
if /I "%type%"=="1" goto :goictstatic
if /I "%type%"=="2" goto :godormdyn
if /I "%type%"=="Q" goto :end
goto :start

:goictstatic
echo.
echo 将IP地址设置成 10.62.0.160
echo 子网掩码设置成 255.255.255.0
echo 网关地址设置成 10.62.0.254
echo DNS:159.226.39.1
echo.
echo 正在设置IP地址及子网掩码
netsh interface ip set address name="本地连接" source=static addr=10.62.0.160 mask=255.255.255.0 >nul
echo 正在设置默认网关地址
netsh interface ip set address name="本地连接" gateway=10.62.0.254 gwmetric=0 >nul
echo 正在设置DNS
netsh interface ip set dns name="本地连接" source=static addr=10.62.0.8 register=PRIMARY >nul
netsh interface ip add dns name="本地连接" addr=159.226.39.1 index=2 >nul
goto :showip
:godormdyn
echo.
echo 正在设置动态IP地址，请稍候!
netsh interface ip set address name="本地连接" source=dhcp >nul
echo 正在设置动态DNS地址，请稍候!
netsh interface ip set dns name="本地连接" source=dhcp>nul
goto :showip
:showip
cls
ipconfig/all
::netsh int ip show address
echo.
echo 按任一键退出程序!
pause >nul
:end
echo