Qt Quick入门

最新推荐文章于 2024-08-24 13:55:01 发布
最新推荐文章于 2024-08-24 13:55:01 发布
阅读量7.6k 收藏 11
点赞数 1
分类专栏： Qt Qt
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/zzti_erlie/article/details/53008987
版权
Qt 同时被 2 个专栏收录
18 篇文章 4 订阅
订阅专栏
Qt
17 篇文章 1 订阅
订阅专栏

前言

QML是一种语言，而Qt Qucik是QML写出来的类库，就和C++是一种语言，STL是用C++开发的库是一个道理，以Qt5.7为例，进入首页，点击C++就进入类似QPushButton的类，而进入API，再进入ALL QML Types,就能看到QML的类，把Qt Qucik链接里面的东西看的差不多就能知道Qt Quick的作用了，QML是一种语言
这里写图片描述
这里写图片描述

例程

推荐一篇好的博客：Qt Qucik专栏写的挺好的,看看这2篇博客有助于理解源程序，作者是CSDN Qt专栏的版主
Qt Quick 布局介绍：http://blog.csdn.net/foruok/article/details/33738227
Qt Quick 事件处理之信号与槽：http://blog.csdn.net/foruok/article/details/30028711
新建一个Qt Quick Application，先看一下提前定义好的东西
main.qml

import QtQuick 2.5
import QtQuick.Window 2.2

Window {
    //设置window对象为可见，如果不写这一句是不可见的,所以要想看见必须得写
    visible: true
    //设置窗体的宽度
    width: 640
    //设置窗体的宽度
    height: 480
    //设置窗体的名字
    title: qsTr("Hello World")

    //主窗口
    MainForm {

        //从Item类继承下来的属性
        //官方解释为anchors.fill provides a convenient way for one item to have
        //the same geometry as another item, and is equivalent to connecting all
        //four directional anchors.
        //大致意思就是锚(mao)布局，充满父窗口,parent指的就是上一级，即MainForm
        anchors.fill: parent

        //这个是附加属性和附加处理器，看上面的博客，鼠标一点击控件就会退出
        mouseArea.onClicked: {
            Qt.quit();
        }
    }
}

作品

connections的使用

点击按钮，字体发生变化
这里写图片描述
建立的是Qt Quick Controls 2 Application项目，所以按钮显示有点特别
main.qml

import QtQuick 2.7
import QtQuick.Controls 2.0
import QtQuick.Layouts 1.0

ApplicationWindow {
    visible: true
    width: 640
    height: 480
    title: qsTr("Hello World")

    Text {
        id: text1
        text: qsTr("text");
        anchors.horizontalCenter: parent.horizontalCenter;
        anchors.top: parent.top;
        //QML的基础类型font,设置字体的大小
        font.pixelSize: 20
    }

    Button {
        id: btn;
        text:"changeText";
        anchors.bottom: parent.bottom;
        anchors.horizontalCenter: parent.horizontalCenter;
    }

    Connections {
        target: btn;
        onClicked: {
            //定义红绿蓝三原色和透明度
            text1.color = Qt.rgba(Math.random(),Math.random(),Math.random(),1);
        }
    }
}

Connections和Loader的使用

点击左下角的控件，大小是由colorPicker定义的，点击哪个控件文本上的颜色就变为哪个控件
main.qml
这里写图片描述

import QtQuick 2.7
import QtQuick.Controls 2.0
import QtQuick.Layouts 1.0

ApplicationWindow {
    visible: true
    width: 640
    height: 480
    title: qsTr("Hello World")

    Text {
        id : colorText;
        anchors.horizontalCenter : parent.horizontalCenter;
        anchors.top : parent.top;
        text : "hello world";
        font.pixelSize: 32;
    }

    Component {
        id : colorComponent;
        Rectangle {
            id : colorPicker;
            width : 50;
            height: 30;
            signal colorPicked(color col);
            MouseArea {
                anchors.fill: parent;
                onPressed: colorPicker.colorPicked(colorPicker.color);
            }
        }
    }

    Loader {
        id : redLoader;
        anchors.left : parent.left;
        anchors.bottom: parent.bottom;
        sourceComponent: colorComponent;
        onLoaded: {
            item.color = "red";
        }
    }

    Loader {
        id : blueLoader;
        anchors.left : redLoader.right;
        anchors.bottom: parent.bottom;
        sourceComponent: colorComponent;
        onLoaded: {
            item.color = "blue";
        }
    }

    Connections {
        target: redLoader.item
        onColorPicked : {
            colorText.color = col;
        }
    }

    Connections {
        target: blueLoader.item
        onColorPicked : {
            colorText.color = col;
        }
    }

}

鼠标事件

点击鼠标左键一次背景发生变化，连点鼠标2次背景变为灰色，点击鼠标右键退出程序
这里写图片描述

main.qml

import QtQuick 2.7
import QtQuick.Controls 2.0
import QtQuick.Layouts 1.0

ApplicationWindow {
    visible: true
    width: 640
    height: 480
    title: qsTr("Hello World")

    MouseArea {
        anchors.fill: parent;
        acceptedButtons: Qt.LeftButton | Qt.RightButton;
        onClicked: {
            if(mouse.button == Qt.RightButton) {
                Qt.quit();
            } else if( mouse.button == Qt.LeftButton) {
                //通过QML基础类型color进行设置
                color = Qt.rgba(Math.random(),Math.random(),Math.random());
            }
        }
        onDoubleClicked: {
            color = "gray";
        }
    }
}

键盘事件

按上下左右移动字体，按空格或者鼠标点击选中复选框
这里写图片描述
main.qml

import QtQuick 2.7
import QtQuick.Controls 2.0
import QtQuick.Layouts 1.0

ApplicationWindow {
    visible: true
    width: 640
    height: 480
    title: qsTr("Hello World")

    Rectangle {
        anchors.fill: parent;
        focus: true;
        Keys.enabled: true;
        Keys.onEscapePressed: {
            Qt.quit();
        }
        Keys.forwardTo: [moveText,likeQt];

        Text {
            id: moveText;
            //设置相对于窗口的坐标
            x: 20;
            y: 20;
            width: 200;
            height: 30;
            text: "Moving Text";
            //设置粗体，字体大小为20
            font {bold : true;pixelSize: 20}
            Keys.enabled: true;
            Keys.onPressed: {
                switch(event.key) {
                case Qt.Key_Left:
                    x -= 10;
                    break;
                case Qt.Key_Right:
                    x += 10;
                    break;
                case Qt.Key_Up:
                    y -= 10;
                    break;
                case Qt.Key_Down:
                    y += 10;
                    break;
                default:
                    return;
                }
                event.accepted = true;
            }
        }

        CheckBox {
            id: likeQt;
            text: "like qt quick";
            anchors.left: parent.left;
            anchors.bottom: parent.bottom;
        }
    }

}

Timer的使用

点击按钮，从10开始倒计时
这里写图片描述
main.qml

import QtQuick 2.7
import QtQuick.Controls 2.0
import QtQuick.Layouts 1.0

ApplicationWindow {
    visible: true
    width: 640
    height: 480
    title: qsTr("Hello World")

    QtObject {
        id: attrs;
        property int counter;
        //不能直接赋值，只能用组件赋值
        Component.onCompleted: {
            attrs.counter = 10;
        }
    }

    Text {
        id: countShow;
        anchors.centerIn: parent;
        color: "blue";
        font.pixelSize: 40;
    }

    Timer {
        id: countDown;
        interval: 1000;
        repeat: true;
        triggeredOnStart: true;
        onTriggered: {
            countShow.text = attrs.counter;
            attrs.counter -= 1;
            if(attrs.counter < 0) {
                countDown.stop();
                countShow.text = "Clap now";
            }
        }
    }

    Button {
        id: startBtn;
        anchors.top: countShow.bottom;
        anchors.horizontalCenter: countShow.horizontalCenter;
        text : "Start";
        onClicked: {
            attrs.counter = 10;
            countDown.start();
        }
    }


}

行布局和列布局

这里写图片描述
main.qml

import QtQuick 2.7
import QtQuick.Controls 2.0
import QtQuick.Layouts 1.0

ApplicationWindow {
    visible: true
    width: 300
    height: 300
    title: qsTr("Hello World")

    Row {
        id: row;
        anchors.top: parent.top;
        anchors.left: parent.left;
        anchors.topMargin: 20
        spacing: 20;//间距

        Rectangle {
            width: 20;
            height: 20
            color: "red";
        }

        Rectangle {
            width: 20;
            height: 20
            color: "red";
        }

        Rectangle {
            width: 20;
            height: 20
            color: "red";
        }
    }

    Column {
        anchors.top: row.bottom;
        anchors.left: parent.left;
        Rectangle {
            width: 20;
            height: 20
            color: "blue";
        }

        Rectangle {
            width: 20;
            height: 20
            color: "blue";
        }

        Rectangle {
            width: 20;
            height: 20
            color: "blue";
        }
    }
}

表格布局

这里写图片描述
main.qml

import QtQuick 2.7
import QtQuick.Controls 2.0
import QtQuick.Layouts 1.0

ApplicationWindow {
    visible: true
    width: 300
    height: 300
    title: qsTr("Hello World")

    Grid {
        anchors.left: parent.left
        anchors.bottom: parent.bottom
        flow: Grid.TopToBottom
        //默认是 flow: Grid.LeftToRight
        rows: 3
        columns: 3
        rowSpacing: 20
        columnSpacing: 20

        Rectangle {
            width: 20
            height: 20
            color: "red"
        }
        Rectangle {
            width: 20
            height: 20
            color: "red"
        }
        Rectangle {
            width: 20
            height: 20
            color: "red"
        }
        Rectangle {
            width: 20
            height: 20
            color: "red"
        }
        Rectangle {
            width: 20
            height: 20
            color: "red"
        }
        Rectangle {
            width: 20
            height: 20
            color: "red"
        }
        Rectangle {
            width: 20
            height: 20
            color: "red"
        }
    }

}

QML和C++混合编程
推荐博客：http://blog.csdn.net/foruok/article/details/32698603
上手敲一下，很快就能理解
这里写图片描述
点击开始，中间的图形开始变化，上面显示时间，点击停止，不再变化，点击RGB，应用这个算法，按钮显示为下一个算法，退出按钮退出程序

QML中使用C++对象

(1)实现可以导出的C++类
colormaker.h

#ifndef COLORMAKER_H
#define COLORMAKER_H

#include <QObject>
#include <QColor>
#include <QTimerEvent>

class ColorMaker : public QObject
{
    Q_OBJECT
    Q_ENUMS(generate);
    Q_PROPERTY(QColor color READ color WRITE setColor NOTIFY colorChanged);
    Q_PROPERTY(QColor timeColor READ timeColor);

public:
    explicit ColorMaker(QObject *parent = 0);
    ~ColorMaker();

    //枚举参数
    enum generate{
        randomRGB,
        randomRed,
        randomGreen,
        randomBlue,
        increase,
    };

    QColor color() const;
    void setColor(const QColor &color);
    QColor timeColor() const;

    Q_INVOKABLE generate algorithm() const;
    Q_INVOKABLE void setAlgorithm(generate algorithm);

signals:
    void colorChanged(const QColor &color);
    void currentTimer(const QString &strTime);
public slots:
    void start();
    void stop();
protected:
    //从QObject上继承下来的虚函数
    void timerEvent(QTimerEvent *event);
private:
    generate myGenerate;
    QColor myColor;
    int colorTimer;//定时器的标识符
};

#endif // COLORMAKER_H

colormaker.cpp

#include "colormaker.h"
#include <QDateTime>
#include <QColor>

ColorMaker::ColorMaker(QObject *parent) : QObject(parent)
  ,myGenerate(randomRGB)
  ,myColor(Qt::black)
  ,colorTimer(0)
{
//    qsrand在QtGlobal中定义，具体作用如下
//    qsrand(QTime::currentTime().msec());
//    是取时间作为产生随机数的种子.
//    qrand()%5000+1000是产生一个在 1000-6000间的数,
//    timer->start是根据上述产生的数值来启动定时器.
    //以当前时间距1970-01-01T00:00:00的秒数来作为种子
    qsrand(QDateTime::currentDateTime().toTime_t());
}
ColorMaker::~ColorMaker()
{

}
QColor ColorMaker::color() const
{
    return myColor;
}
void ColorMaker::setColor(const QColor &color)
{
    myColor = color;
    emit colorChanged(myColor);
}
QColor ColorMaker::timeColor() const
{
    QTime time = QTime::currentTime();
    int r = time.hour();
    int g = time.minute();
    int b = time.second();
    return QColor::fromRgb(r,g,b);
}
ColorMaker::generate ColorMaker::algorithm() const
{
    return myGenerate;
}
void ColorMaker::setAlgorithm(generate algorithm)
{
    myGenerate = algorithm;
}
void ColorMaker::start()
{
    if(colorTimer == 0)
    {
        //从QObject继承下来的方法，返回的是定时器的标示
        colorTimer = startTimer(1000);
    }
}
void ColorMaker::stop()
{
    if(colorTimer > 0)
    {
        //关闭定时器
        killTimer(colorTimer);
        //记得把定时器的标示重新定义为0
        colorTimer = 0;
    }
}
void ColorMaker::timerEvent(QTimerEvent *event)
{
    //qrand()在QtGlobal中定义
    if(event->timerId() == colorTimer)
    {
        switch (myGenerate)
        {
        case randomRGB:
            myColor.setRgb(qrand()%255,qrand()%255,qrand()%255);
            break;
        case randomRed:
            myColor.setRed(qrand()%255);
            break;
        case randomGreen:
            myColor.setGreen(qrand()%255);
            break;
        case randomBlue:
            myColor.setBlue(qrand()%255);
            break;
        default:
            int r = myColor.red() + 10;
            int g = myColor.green() + 10;
            int b = myColor.blue() + 10;
            myColor.setRgb(r % 255, g % 255, b % 255);
            break;
        }
        emit colorChanged(myColor);
        emit currentTimer(QDateTime::currentDateTime().toString("yyyy-MM-dd hh:mm:ss"));
    }
    else
    {
       timerEvent(event);
    }
}

main.cpp

#include <QGuiApplication>
#include <QQmlApplicationEngine>
#include <colormaker.h>

int main(int argc, char *argv[])
{
    QGuiApplication app(argc, argv);
    qmlRegisterType<ColorMaker>("my.qt.ColorMaker",1,0,"ColorMaker");
    QQmlApplicationEngine engine;
    engine.load(QUrl(QStringLiteral("qrc:/main.qml")));

    return app.exec();
}

main.qml

import QtQuick 2.5
import QtQuick.Window 2.2
import my.qt.ColorMaker 1.0
import QtQuick.Controls 1.4

Window {
    visible: true
    width: 360
    height: 360
    title: qsTr("Hello World")

    //显示时间
    Text {
        id: timerLabel
        anchors.left: parent.left
        anchors.top: parent.top
    }
    ColorMaker {
        id : colorMaker
        color: Qt.green
    }

    Rectangle{
        id: colorRect;
        anchors.centerIn: parent
        width:200
        height:200
        color:"blue"
    }
    Button{
        id:start;
        anchors.left: parent.left
        anchors.bottom: parent.bottom
        text:"开始"
        onClicked: {
            colorMaker.start();
        }
    }

    Button{
        id:stop;
        anchors.left: start.right
        anchors.bottom: parent.bottom
        text:"停止"
        onClicked: {
            colorMaker.stop();
        }
    }

    Button{
        id:colorAlgorithm;
        anchors.left: stop.right
        anchors.bottom: parent.bottom
        text:"RGB"
        onClicked: {
           var algorithm = (colorMaker.algorithm() + 1) % 5;
            changetAlgorithm(colorAlgorithm,algorithm);
            colorMaker.setAlgorithm(algorithm);
        }
    }

    //javascript函数
    function changetAlgorithm(button,algorithm){
        switch(algorithm) {
        case 0:
            button.text="RGB";
            break;
        case 1:
            button.text="red";
            break;
        case 2:
            button.text="green";
            break;
        case 3:
            button.text="blue";
        default:
            button.text="increase";
            break;
        }
    }

    Button{
        id:quit;
        anchors.left: colorAlgorithm.right
        anchors.bottom: parent.bottom
        text:"退出"
        onClicked: {
            Qt.quit();
        }
    }

    Connections {
        //接收事件的对象
        target: colorMaker
        //收到事件时的处理函数
        onCurrentTimer:{
            //strTime从currentTimer里发送过来的
            timerLabel.text = strTime
            timerLabel.color = colorMaker.timeColor;
        }
    }

    Connections {
        target: colorMaker
        onColorChanged:{
            colorRect.color = color;
        }
    }

}

(2)导出一个C++对象为QML的属性
在上一个的基础上改动的地方不多
main.cpp

#include <QGuiApplication>
#include <QQmlApplicationEngine>
#include <colormaker.h>
#include <QQmlContext>

int main(int argc, char *argv[])
{
    QGuiApplication app(argc, argv);
    //qmlRegisterType<ColorMaker>("my.qt.ColorMaker",1,0,"ColorMaker");
    QQmlApplicationEngine engine;
    //这一句是新加的，从QQmlEngine上继承下来的方法,返回QQmlContext
    engine.rootContext()->setContextProperty("colorMaker",new ColorMaker);
    engine.load(QUrl(QStringLiteral("qrc:/main.qml")));

    return app.exec();
}

main.qml

import QtQuick 2.5
import QtQuick.Window 2.2
//不用导入了
//import my.qt.ColorMaker 1.0
import QtQuick.Controls 1.4

Window {
    visible: true
    width: 360
    height: 360
    title: qsTr("Hello World")

    //显示时间
    Text {
        id: timerLabel
        anchors.left: parent.left
        anchors.top: parent.top
    }
//    不用定义
//    ColorMaker {
//        id : colorMaker
//        color: Qt.green
//    }

    Rectangle{
        id: colorRect;
        anchors.centerIn: parent
        width:200
        height:200
        color:"blue"
    }
    Button{
        id:start;
        anchors.left: parent.left
        anchors.bottom: parent.bottom
        text:"开始"
        onClicked: {
            colorMaker.start();
        }
    }

    Button{
        id:stop
        anchors.left: start.right
        anchors.bottom: parent.bottom
        text:"停止"
        onClicked: {
            colorMaker.stop();
        }
    }

    Button{
        id:colorAlgorithm;
        anchors.left: stop.right
        anchors.bottom: parent.bottom
        text:"RGB"
        onClicked: {
           var algorithm = (colorMaker.algorithm() + 1) % 5;
            changetAlgorithm(colorAlgorithm,algorithm);
            colorMaker.setAlgorithm(algorithm);
        }
    }

    //javascript函数
    function changetAlgorithm(button,algorithm){
        switch(algorithm) {
        case 0:
            button.text="RGB";
            break;
        case 1:
            button.text="red";
            break;
        case 2:
            button.text="green";
            break;
        case 3:
            button.text="blue";
        default:
            button.text="increase";
            break;
        }
    }

    Button{
        id:quit;
        anchors.left: colorAlgorithm.right
        anchors.bottom: parent.bottom
        text:"退出"
        onClicked: {
            Qt.quit();
        }
    }

    //这个是在上一个的基础上增加的，感觉component的作用有点初始化的意思
    Component.onCompleted: {
        //设置红绿蓝三原色和透明度
        colorMaker.color = Qt.rgba(0,0,0,1);
        colorMaker.setAlgorithm(2);
        changetAlgorithm(colorAlgorithm,colorMaker.algorithm());
    }

    Connections {
        //接收事件的对象
        target: colorMaker
        //收到事件时的处理函数
        onCurrentTimer:{
            //strTime从currentTimer里发送过来的
            timerLabel.text = strTime
            timerLabel.color = colorMaker.timeColor;
        }
    }

    Connections {
        target: colorMaker
        onColorChanged:{
            colorRect.color = color;
        }
    }

}

C++中使用QML对象

每隔一秒改变一下背景颜色，点击退出程序关闭
这里写图片描述
main.cpp

#include <QGuiApplication>
#include <QQmlApplicationEngine>
#include <QQuickItem>
#include <QList>
#include <QDebug>
#include <changeqmlcolor.h>

int main(int argc, char *argv[])
{
    QGuiApplication app(argc, argv);

    QQmlApplicationEngine engine;
    engine.load(QUrl(QStringLiteral("qrc:/main.qml")));
    //找到文档的父节点，为什么有好几个父节点不太理解
    QList<QObject*> rootObjects = engine.rootObjects();
    QObject *root = NULL;
    for(int i=0;i <rootObjects.size(); i++)
    {
        if(rootObjects[i]->objectName() == "rootObject")
        {
            root = rootObjects[i];
            break;
        }
    }
    QObject *quitBtn = root->findChild<QObject*>("quitBtn");
    //quitBtn找到了
    //改变背景颜色
    new ChangeQmlColor(root);
    if(quitBtn)
    {
        QObject::connect(quitBtn,SIGNAL(clicked()),&app,SLOT(quit()));
    }
    QObject *textLabel = root->findChild<QObject*>("textLabel");
    if(textLabel)
    {
        bool flag = QMetaObject::invokeMethod(textLabel,"doLayout");
        //显示true说明调用成功
        qDebug()<<flag;
    }
    return app.exec();
}

main.qml

import QtQuick 2.7
import QtQuick.Window 2.2
import QtQuick.Controls 1.4

Window {
    objectName: "rootObject"
    visible: true
    width: 640
    height: 480
    title: qsTr("Hello World")

    Text {
        objectName: "textLabel"
        anchors.centerIn: parent
        text:"Hello World"
    }

    Button {
        objectName: "quitBtn"
        anchors.right: parent.right
        anchors.bottom: parent.bottom
        anchors.bottomMargin: 4
        anchors.rightMargin: 4
        text:"退出"
    }
}

changeqmlcolor.h

#ifndef CHANGEQMLCOLOR_H
#define CHANGEQMLCOLOR_H

#include <QObject>
#include <QTimer>

class ChangeQmlColor : public QObject
{
    Q_OBJECT
public:
    ChangeQmlColor(QObject *target,QObject *parent = 0);

protected slots:
    void onTimeOut();
private:
    QTimer *timer;
    QObject *target;
};

#endif // CHANGEQMLCOLOR_H

changeqmlcolor.cpp

#include "changeqmlcolor.h"
#include <QDebug>
#include <QDateTime>
#include <QColor>

ChangeQmlColor::ChangeQmlColor(QObject *target,QObject *parent)
    : QObject(parent)
    ,target(target)
{
    timer = new QTimer(this);
    qsrand(QDateTime::currentDateTime().toTime_t());
    connect(timer,SIGNAL(timeout()),this,SLOT(onTimeOut()));
    timer->start(1000);
}
void ChangeQmlColor::onTimeOut()
{
    QColor color = QColor::fromRgb(qrand()%256,qrand()%256,qrand()%256);
    target->setProperty("color",color);
}

欢迎关注

喜欢本文的朋友们，欢迎关注公众号Kruskal，收看更多精彩内容
avatar

Java识堂
关注
专栏目录
创建 Qt Quick 项目
青春不老，奋斗不止！
01-09 1万+
来看看如何使用 Qt Creator 创建 Qt Quick 项目！
Qt使用教程之创建Qt Quick项目
需要界面开发、IDE工具研发中文教程资料的小伙伴，记得私信我~
10-20 1264
Qt Enterprise最新版下载> Qt长期以来一直以“linux平台下，最著名的开发平台”身份在全世界开发者中享有盛誉。Qt Enterprise v5.5是目前最先进、最完整的跨平台C++开发工具。它不仅完全实现了一次编写，所有平台无差别运行，更提供了几乎所有开发过程中需要用到的工具。那么在本文中，我们将为大家展示如何创建一个新的Qt Quick项目。 当你从头开始
QT QUICK 学习笔记
最新发布
qq_48786027的博客
08-24 844
在Qt Quick应用程序中，如果你想让QML能够访问和使用C++类，你需要按照一定的步骤来定义和导出C++类，以便QML引擎能够识别和实例化。创建C++类并继承自QObject创建一个C++类，并让它继承自QObject。这是为了让该类能够参与到Qt的Meta-Object System中，使得其属性、信号和槽可以在QML中访问和使用。。
import QtQuick.Controls 1.4 import QtQuick.Controls 2.2
qbw_csdn的博客
12-22 949
问题：一个组件具有两个导入文件中的内容，一山难容二虎。 方法：导入文件的顺序十分重要，先小后大。
【Qt Quick】Window
weixin_44697562的博客
09-04 350
常用去除窗口边框最大化窗口最小化窗口 去除窗口边框 flags: Qt.FramelessWindowHint 最大化窗口 visibility: "Maximized" 最小化窗口 visibility: "Minimized"
qt quick 项目创建
热门推荐
FREEDOM
08-29 1万+
打开 qt creator
qtquick入门
01-20
### Qt Quick 入门知识点详解 #### 一、引言 **Qt Quick** 是一个用于构建用户界面的技术栈，它采用声明式编程风格，并利用QML（Qt Meta Language）来描述用户界面及其行为。Qt Quick 不仅适用于桌面应用，也广泛...
Qt-Quick核心编程之Qt Quick入门，适合Qt初学者
05-12
### Qt Quick核心编程之Qt Quick入门详解 #### 一、Qt Quick编程概述 Qt Quick 是一个用于构建丰富用户界面的框架，它通过一种简洁、易读的语言——QML（Qt Meta Language）来实现。Qt Quick 不仅适用于桌面应用...
《QML和Qt Quick快速入门》示例源码
09-16
《QML和Qt Quick快速入门》示例源码是一份专为初学者设计的资源，旨在帮助理解并掌握QML和Qt Quick这两种强大的GUI开发工具。QML（Qt Meta Language）是Qt框架的一部分，用于创建现代、动态且响应迅速的用户界面。Qt...
基于QtQuick的入门例子，方便大家入门学习
01-02
【QtQuick入门详解】 QtQuick是Qt框架的一部分，它提供了一种高效且声明式的用户界面设计方式，使得开发者可以快速创建美观、响应迅速的应用程序。本教程将通过一个简单的入门例子，帮助初学者理解QtQuick的基本...
qt quick.pdf
04-25
经典的QML学习教程，附带示例源码
QT和QT quick实战（附项目源码）
04-11
本文件中包含QT及QT quick实战高清电子书版书籍，并附有书中项目源码，边看边学。
Qt及Qt Quick开发实战精解 (Qt应用编程系列丛书) - 霍亚飞.mobi
05-18
Qt及Qt Quick开发实战精解 (Qt应用编程系列丛书) - 霍亚飞.mobi
【Qt Quick 项目(第一集Qt Quick UI 项目项目创建)】
m0_45463480的博客
01-21 394
到底什么是Qt Qml、什么是Qt Quick、QtQuick应用程序与Qt Widget程序有何区别，为了让读者在学习QML之前有一个整体认识，这里先介绍几个Quick项目。
Qt Quick常用的控件..
nowhaha的专栏
03-13 1915
Qt Quick Controls模块提供了一组可以在Qt Quick中建立完整接口的控件（用于创建用户界面的QML类型）。这些QML类型与Qt Quick和Qt Quick Layouts配合使用。     该模块是Qt5.1新添加的，需要Qt Quick 2.1。     QML类型可以用下面的导入语句导入到应用程序的.qml文件中。 import QtQuick
QT Quick项目简介
weixin_36323170的博客
01-21 1108
在Qt 4中，Qt Quick只是在QGraphicsView之上做了简单的封装，并通过QtScript和JavaScript来为其提供脚本支持。基于QGraphicsView之上的QML在功能上仅仅限于那些绝对必要且速度可以足够快的绘制美观用户界面的部分。对于那些潜在影响绘制速度的高级功能，比如组合模式、QPainterPaths、QGraphicsEffects和复杂的画笔等都不被支持的。
Hello Qt（五十一）———Qt Quick Controls
天山老妖
03-06 1267
一、Qt Quick Controls基础 QT5.1发布了Qt Quick的一个全新模块：Qt Quick Controls。Qt Quick Controls模块提供了大量类似Qt Widgets模块的可重用组件。 为了开发基于Qt Quick Controls的程序，需要创建一个Qt Quick Application类型的应用程序，选择组件集的时候注意选择Qt Quick Controls。 二、Qt Quick Controls组件 Qt Quick Controls 提供了多种组件。
第53篇 Qt Quick项目详解
林中静月下仙的博客
12-13 2261
在Qt中提供了两个运行QML文件的工具qmlviewer和qmlscene，前者是Qt 4时代的产物，主要用来显示导入了QtQuick 1.1模块的QML文件，而qmlscene用来显示导入了QtQuick 2.0以后版本的QML文件。本节内容让大家可以从根本上掌握Qt Quick程序的构建，并且也提供了一种学习的方法，一种分析大型复杂程序的方法，就是所谓的剖析法，希望大家用心过一遍，为以后的学习打好基础。文件的内容，从最简单的程序开始，逐渐丰富代码，现在大家应该已经对QML程序有了一定的认识。
《Qt5 Cadaques》学习笔记（六）：QT QUICK Controls 2
观月执白
07-04 1384
从头开始使用 Qt Quick 提供了基本的图形和交互元素，从中构建用户界面。
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

Java识堂

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值