2017.03.18【NOIP 普及组】模拟赛C组 T4:剪草

**【普及模拟】剪草 **
题目描述

有N棵小草，编号0至N-1。奶牛Bessie不喜欢小草，所以Bessie要用剪刀剪草，目标是使得这N棵小草的高度总和不超过H。在第0时刻，第i棵小草的高度是h[i]，接下来的每个整数时刻，会依次发生如下三个步骤：

（1）每棵小草都长高了，第i棵小草长高的高度是grow[i]。

（2）Bessie选择其中一棵小草并把它剪平，这棵小草高度变为0。注意：这棵小草并没有死掉，它下一秒还会生长的。

（3）Bessie计算一下这N棵小草的高度总和，如果不超过H，则完成任务，一切结束， 否则轮到下一时刻。

你的任务是计算：最早是第几时刻，奶牛Bessie能完成它的任务？如果第0时刻就可以完成就输出0，如果永远不可能完成，输出-1，否则输出一个最早的完成时刻。

输入

第一行，两个整数N和H。 1 ≤ N ≤ 50，0 ≤ H ≤ 1000000。

第二行，N个整数，表示h[i]。0 ≤ h[i] ≤ 100000。

第三行，N个整数，表示grow[i]。1 ≤ grow[i] ≤ 100000。

对于20%的数据， 1 ≤ N ≤ 7。

输出

一个整数，最早完成时刻或-1。

输入样例1

3 16

5 8 58

2 1 1

输入样例2

2 58

5 8

2 1

输入样例3

2 0

5 8

2 1

输入样例4

7 33

5 1 6 5 8 4 7

2 1 1 1 4 3 2

输出样例1

1

输出样例2

0

输出样例3

-1

输出样例4

5

样例解释1

到了第1时刻，三棵小草的高度依次是7,9,59。如果奶牛Bessie把高度是59的小草剪掉，那么三棵小草高度是7+9+0=16,任务完成。

样例解释4

第1秒剪第2棵小草，第2秒剪第0棵小草，第3秒剪6棵小草，第4秒剪第5棵小草，第5秒剪第4棵小草。

题解：
通过分析，每棵小草最多只被割一次，因为如果被割了多次，只有最后一次是有效的，之前割的是无效的。因此，如果有答案，那么一定不超过小草的数量N。 由于N 不超过50，那么我们可以从小到大枚举答案，注意，不能二分答案，没有单调性。枚举一个时间T，表示总共割了T次，那么应该按照什么顺序来割小草呢？应该是先割生长速度慢的小草，如果先割生长速度快的小草，再割生长速度慢一点的小草，那么把它们的顺序调整一下会更好，读者自己写一下它们的表达式，再作差，就可以看出来了。既然割草的先后循序确定了，剩下的问题就是经典的DP了，即有N棵小草，每棵小草可以是被割或者不被割，按照一定的顺序，要使得总高度最小。
设fi,j表示当前时间j剪第i棵草。
得此方程：
f[i,k+1]:=min(f[i,k+1],f[j,k]+sumb-(k+1)*grow[i]-grass[i]);

标程：

uses math;
var
        f:array[0..5000,0..5000] of longint;
        grass,grow:array[0..5000] of longint;
        i,j,k,n,m,suma,sumb,ans:longint;
procedure qsort(l,r:longint);
var
        i,j,m1,m2:longint;
        t:longint;
begin
        i:=l;
        j:=r;
        m1:=grow[(i+j) div 2];
        m2:=grass[(i+j) div 2];
        repeat
                while (grow[i]<m1)or(grow[i]=m1)and(grass[i]>m2) do inc(i);
                while (grow[j]>m1)or(grow[j]=m1)and(grass[j]<m2) do dec(j);
                if i<=j then
                begin
                        t:=grass[i];
                        grass[i]:=grass[j];
                        grass[j]:=t;
                        t:=grow[i];
                        grow[i]:=grow[j];
                        grow[j]:=t;
                        inc(i);
                        dec(j);
                end;
        until i>j;
        if l<j then qsort(l,j);
        if i<r then qsort(i,r);
end;
begin
        assign(input,'grass.in');reset(input);
        assign(output,'grass.out');rewrite(output);
        readln(n,m);
        for i:=1 to n do
        begin
                read(grass[i]);
                suma:=suma+grass[i];
        end;
        for i:=1 to n do
        begin
                read(grow[i]);
                sumb:=sumb+grow[i];
        end;
        qsort(1,n);
        for i:=0 to n do
        begin
                for j:=0 to n do
                begin
                        f[i,j]:=maxlongint div 3 ;
                end;
        end;
        f[0,0]:=suma;
        ans:=maxlongint;
        for i:=1 to n do
        begin
                for j:=0 to i-1 do
                begin
                        for k:=0 to j do
                        begin
                                f[i,k+1]:=min(f[i,k+1],f[j,k]+sumb-(k+1)*grow[i]-grass[i]);
                                if f[i,k+1]<=m then ans:=min(ans,k+1);
                        end;
                end;
        end;
        if ans=maxlongint then writeln(-1)
        else
        writeln(ans);
end.