Oracle 游标

转载 2012年03月21日 14:22:11
 

游标用来处理从数据库中检索的多行记录(使用SELECT语句)。利用游标,程序可以逐个地处理和遍历一次检索返回的整个记录集。

为了处理SQL语句,Oracle将在内存中分配一个区域,这就是上下文区。这个区包含了已经处理完的行数、指向被分析语句的指针,整个区是查询语句返回的数据行集。游标就是指向上下文区句柄或指针。

两种游标:
一、显示游标(需要明确定义!)
    显示游标被用于处理返回多行数据的SELECT语句,游标名通过CURSOR….IS语句显示地赋给SELECT 语句。
       PL/SQL中处理显示游标所必需的四个步骤:
       1)声明游标;CURSOR cursor_name IS select_statement
       2)为查询打开游标;OPEN cursor_name
       3)取得结果放入PL/SQL变量中;
             FETCH cursor_name INTO list_of_variables;
              FETCH cursor_name INTO PL/SQL_record;
       4)关闭游标。CLOSE cursor_name
       注意:在声明游标时,select_statement不能包含INTO子句。当使用显示游标时,INTO子句是FETCH语句的一部分。
二、隐式游标
      所有的隐式游标都被假设为只返回一条记录。
      使用隐式游标时,用户无需进行声明、打开及关闭。PL/SQL隐含地打开、处理,然后关掉游标。



实际操作和例子:

   (1)FOR循环游标 (常用的一种游标)

--<1>定义游标
--<2>定义游标变量
--<3>使用for循环来使用这个游标

--前向游标 只能往一个方向走
--效率很高
      declare
        --类型定义
        cursor cc is select empno,ename,job,sal
         from emp where job = 'MANAGER';
        --定义一个游标变量
        ccrec cc%rowtype;
      begin
         --for循环
         for ccrec in cc loop
            dbms_output.put_line(ccrec.empno||'-'||ccrec.ename||'-'||ccrec.job||'-'||ccrec.sal);
         end loop;       
      end;
   (2) fetch游标
     --使用的时候 必须要明确的打开和关闭
      declare
        --类型定义
        cursor cc is select empno,ename,job,sal
         from emp where job = 'MANAGER';
        --定义一个游标变量
        ccrec cc%rowtype;
      begin
        --打开游标
         open cc;
       --loop循环
         loop
            --提取一行数据到ccrec中
            fetch cc into ccrec;        
            --判断是否提取到值,没取到值就退出
            --取到值cc%notfound 是false
            --取不到值cc%notfound 是true
            exit when cc%notfound;
            dbms_output.put_line(ccrec.empno||'-'||ccrec.ename||'-'||ccrec.job||'-'||ccrec.sal);            
         end loop;
        --关闭游标
         close cc;  
      end;
游标的属性4种
       %notfound fetch是否提到数据 没有true 提到false
       %found      fetch是否提到数据 有true 没提到false
       %rowcount 已经取出的记录的条数
       %isopen    布尔值 游标是否打开

   (3)参数游标
按部门编号的顺序输出部门经理的名字
     declare
       --部门
       cursor c1 is select deptno from dept;
       --参数游标c2,定义参数的时候
       --只能指定类型,不能指定长度
       --参数只能出现在select语句=号的右侧
       cursor c2(no number,pjob varchar2) is select emp.* from emp
         where deptno = no and job=pjob;
       c1rec c1%rowtype;
       c2rec c2%rowtype;
       --定义变量的时候要指定长度
       v_job varchar2(20);
     begin
       --部门
        for c1rec in c1 loop
          --参数在游标中使用
          for c2rec in c2(c1rec.deptno,'MANAGER') loop
            dbms_output.put_line(c1rec.deptno||'-'||c2rec.ename);
          end loop;
        end loop;
     end;
(4)引用游标/动态游标
        -- select语句是动态的
     declare
       --定义一个类型(ref cursor)弱类型   
       type cur is ref cursor;
         --强类型(返回的结果集有要求)
       type cur1 is ref cursor return emp%rowtype;
       --定义一个ref cursor类型的变量  
       cura cur;
       c1rec emp%rowtype;
       c2rec dept%rowtype;
     begin
DBMS_output.put_line('输出员工')   ;      
       open cura for select * from emp;
       loop
         fetch cura into c1rec;  
         exit when cura%notfound;
         DBMS_output.put_line(c1rec.ename)   ;
       end loop ;
DBMS_output.put_line('输出部门')   ;
       open cura for select * from dept;
       loop
         fetch cura into c2rec;  
         exit when cura%notfound;
         DBMS_output.put_line(c2rec.dname)   ;
       end loop;
       close cura;
    end;

PS:尽量不要用游标,可用临时表、关联、计算函数等组合实现相关功能

Oracle游标使用详解

  • 2011年07月06日 10:21
  • 4KB
  • 下载

Oracle中PLSQL游标

  • 2012年07月25日 15:17
  • 524KB
  • 下载

Oracle学习笔记整理之游标篇

游标分为隐式、显式、REF三种游标。 而隐式游标和显式游标又都属于静态游标,REF游标属于动态游标。 静态游标和动态游标的最大区别在于静态游标是在运行前将游标变量和SQL关联,而动态游标恰恰相反是...
  • kkkennn
  • kkkennn
  • 2013年12月13日 10:58
  • 322

Oracle 游标使用大全.txt

  • 2012年05月27日 05:35
  • 15KB
  • 下载

oracle游标的使用

  • 2013年04月10日 09:18
  • 12KB
  • 下载

ORACLE动态游标实战举例

游标是数据库编程中必须要熟练掌握的技术,主要实现针对数据集合,进行循环处理,因为SQL本身只能一次性处理,所以当有稍微复杂的因为时,都在存储过程中使用游标进行实现。静态游标在执行前就能确定对应查询语句...

oracle游标的使用

  • 2013年03月23日 14:51
  • 58KB
  • 下载

oracle 管道函数+动态游标

  • 2013年12月17日 13:36
  • 1KB
  • 下载

【Oracle】PL/SQL——游标CURSOR

在 PL/SQL 程序中,对于 处理多行记录的事务经常使用游标来实现。 其中,游标又分为显式游标和隐式游标,这里重点说明显式游标的用法。 显示游标 显示游标的处理 四个PL/SQL步骤: 1)定义游标...

oracle游标越界

  • 2015年07月08日 18:35
  • 14KB
  • 下载
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:Oracle 游标
举报原因:
原因补充:

(最多只允许输入30个字)