做一个像植物大战僵尸的Flash游戏2

 http://bbs.9ria.com/thread-81300-1-5.html

查看该系列的其它文章:
做一个像植物大战僵尸的Flash游戏1
做一个像植物大战僵尸的Flash游戏2
做一个像植物大战僵尸的Flash游戏3
做一个像植物大战僵尸的Flash游戏4
做一个像植物大战僵尸的Flash游戏5

第二个教程了,是时候去筹钱买一个植物了。

我们必需修改一个在教程一中的代码,就是让阳光只是简简单单地出现在某一区块中,并且在一段时间内,若没有被捡起,它就消失了。我们得让阳光平滑的落下。

修改newSun函数

细心的读者可能会发现,教程一里的newSun函数有一个错误使得新生的阳光无法出现在游戏区域内的任意一个区块。这个错误可以通过修改x属性的值来修复:

sun.x=52+sunCol*65;(教程一里写成了sun.x=52+sunRow*65)

既然我们将要加入使得阳光平滑落下的代码,整个newSun函数可以改成这样:
private function newSun(e:TimerEvent):void {
        var sunRow:uint=Math.floor(Math.random()*5);
        var sunCol:uint=Math.floor(Math.random()*9);
        sun = new sunMc();
        sun.buttonMode=true;
        sunContainer.addChild(sun);
        sun.x=52+sunCol*65;
        sun.destinationY=130+sunRow*75;
        sun.y=-20;
        sun.addEventListener(MouseEvent.CLICK,sunClicked);
}
现在,阳光的y属性被初始化为-20使得阳光出现在我们看不见的地方,并且它有一个destinationY属性用来存储它的最终的y坐标。呆会让我们来看看如何使用这一属性。注意一下buttonMode属性,它能使得鼠标指针改变外形当鼠标滑过阳光时。

收集阳光来筹钱吧

首先,我们需要一个变量来存储玩家金钱的数量,然后我们需要一个文本框来显示它。
这些是我们需要导入的类:
import flash.display.Sprite;
import flash.utils.Timer;
import flash.events.TimerEvent;
import flash.events.MouseEvent;
import flash.events.Event;
import flash.text.TextField;

下面这些,是所用到的变量
private var gameField:Array;
private var flowersTimer:Timer=new Timer(5000);
private var sun:sunMc;
private var sunContainer:Sprite=new Sprite();
private var money:uint=0;
private var moneyText:TextField=new TextField;

money变量用来存储玩家的金钱,moneyText是一个动态文本。
现在,让我们来看一下整个代码并且讨论一下新特性。

  1. package {
  2.         import flash.display.Sprite;
  3.         import flash.utils.Timer;
  4.         import flash.events.TimerEvent;
  5.         import flash.events.MouseEvent;
  6.         import flash.events.Event;
  7.         import flash.text.TextField;
  8.         public class Main extends Sprite {
  9.                 private var gameField:Array;
  10.                 private var flowersTimer:Timer=new Timer(5000);
  11.                 private var sun:sunMc;
  12.                 private var sunContainer:Sprite=new Sprite();
  13.                 private var money:uint=0;
  14.                 private var moneyText:TextField=new TextField;
  15.                 public function Main():void {
  16.                         setupField();
  17.                         drawField();
  18.                         fallingSuns();
  19.                         addText();
  20.                         addEventListener(Event.ENTER_FRAME,onEnterFrm);
  21.                 }
  22.                 private function addText():void {
  23.                         addChild(moneyText);
  24.                         updateMoney();
  25.                         moneyText.textColor=0xFFFFFF;
  26.                         moneyText.height=20;
  27.                 }
  28.                 private function updateMoney():void {
  29.                         moneyText.text="Money: "+money.toString();
  30.                 }
  31.                 private function onEnterFrm(e:Event):void {
  32.                         for (var i:uint=0; i<sunContainer.numChildren; i++) {
  33.                                 var fallingSun:sunMc=sunContainer.getChildAt(i) as sunMc;
  34.                                 if (fallingSun.y<fallingSun.destinationY) {
  35.                                         fallingSun.y++;
  36.                                 } else {
  37.                                         fallingSun.alpha-=0.01;
  38.                                         if (fallingSun.alpha<0) {
  39.                                                 fallingSun.removeEventListener(MouseEvent.CLICK,sunClicked);
  40.                                                 sunContainer.removeChild(fallingSun);
  41.                                         }
  42.                                 }
  43.                         }
  44.                 }
  45.                 private function fallingSuns():void {
  46.                         addChild(sunContainer);
  47.                         flowersTimer.start();
  48.                         flowersTimer.addEventListener(TimerEvent.TIMER, newSun);
  49.                 }
  50.                 private function newSun(e:TimerEvent):void {
  51.                         var sunRow:uint=Math.floor(Math.random()*5);
  52.                         var sunCol:uint=Math.floor(Math.random()*9);
  53.                         sun = new sunMc();
  54.                         sun.buttonMode=true;
  55.                         sunContainer.addChild(sun);
  56.                         sun.x=52+sunCol*65;
  57.                         sun.destinationY=130+sunRow*75;
  58.                         sun.y=-20;
  59.                         sun.addEventListener(MouseEvent.CLICK,sunClicked);
  60.                 }
  61.                 private function sunClicked(e:MouseEvent):void {
  62.                         e.currentTarget.removeEventListener(MouseEvent.CLICK,sunClicked);
  63.                         money+=5;
  64.                         updateMoney();
  65.                         var sunToRemove:sunMc=e.currentTarget as sunMc;
  66.                         sunContainer.removeChild(sunToRemove);
  67.                 }
  68.                 private function setupField():void {
  69.                         gameField=new Array();
  70.                         for (var i:uint=0; i<5; i++) {
  71.                                 gameField[i]=new Array();
  72.                                 for (var j:uint=0; j<9; j++) {
  73.                                         gameField[i][j]=0;
  74.                                 }
  75.                         }
  76.                 }
  77.                 private function drawField():void {
  78.                         var fieldSprite:Sprite=new Sprite();
  79.                         var randomGreen:Number;
  80.                         addChild(fieldSprite);
  81.                         fieldSprite.graphics.lineStyle(1,0xFFFFFF);
  82.                         for (var i:uint=0; i<5; i++) {
  83.                                 for (var j:uint=0; j<9; j++) {
  84.                                         randomGreen=(125+Math.floor(Math.random()*50))*256;
  85.                                         fieldSprite.graphics.beginFill(randomGreen);
  86.                                         fieldSprite.graphics.drawRect(25+65*j,80+75*i,65,75);
  87.                                 }
  88.                         }
  89.                 }
  90.         }
  91. }
复制代码

让我们来看一下这个代码中的一些新东西。

第19行:调用addText函数(第22到第27行),这个函数很简单,只是创建了一个动态文本框并且在第24行调用了updateMoney函数(第28到第30行)来显示当前玩家的金钱数量。

第20行:注册Event.ENTER_FRAME事件侦听器,使得每帧调用onEnterFrm函数(第31到第44行)。

第32行:for循环遍历sunContainer,得到sunContainer的子对象。每一束阳光要么是正在下落中,要么是已经落地。

正在下落的阳光它的y属性的值小于它的destinationY属性的值(第34行),这种情况下,阳光会继续下落通过增加y属性的值。

已落地的阳光不会再继续下落,在这种情况下,它开始渐渐消失(第37行,通过改变alpha属性)。一旦它完全透明了(第38行),它的鼠标事件侦听器就会被移除(第39行),并且它也会被移出显示列表(第40行)。

最后一个有改动的函数是sunClicked。现在,你每收集一束阳光就会赚到5个金币(第63行),并且更新动态文本框(第64行)。

下面是游戏效果:



收集阳光赚钱或者让它们落到地面后,看着它们消失吧。

购买你的第一株植物

要创造你的第一株植物,首先我们需要两个新的类:一个是plantMc,它代表了植物,另一个是selectorMc,它使得玩家看清楚植物将要被种到哪一个区块。
我们得增加5个新的变量:
private var plantContainer:Sprite=new Sprite();
private var plant:plantMc;
private var movingPlant:plantMc;
private var playerMoving:Boolean=false;
private var selector:selectorMc;
让我们来看下它们的意思:
plantContainer:一个可视对象,用来当植物的容器
plant:代表植物它本身
movingPlant:也是植物,当玩家买了植物之后,它会跟随鼠标移动
playerMoving:一个布尔型变量,用来记录玩家是否正在移动一株植物
selector:选择器
下面是最终源代码:

  1. package {
  2.         import flash.display.Sprite;
  3.         import flash.utils.Timer;
  4.         import flash.events.TimerEvent;
  5.         import flash.events.MouseEvent;
  6.         import flash.events.Event;
  7.         import flash.text.TextField;
  8.         public class Main extends Sprite {
  9.                 private var gameField:Array;
  10.                 private var flowersTimer:Timer=new Timer(5000);
  11.                 private var sun:sunMc;
  12.                 private var sunContainer:Sprite=new Sprite();
  13.                 private var money:uint=0;
  14.                 private var moneyText:TextField=new TextField  ;
  15.                 private var plantContainer:Sprite=new Sprite();
  16.                 private var plant:plantMc;
  17.                 private var movingPlant:plantMc;
  18.                 private var playerMoving:Boolean=false;
  19.                 private var selector:selectorMc;
  20.                 public function Main():void {
  21.                         setupField();
  22.                         drawField();
  23.                         fallingSuns();
  24.                         addText();
  25.                         addPlants();
  26.                         addEventListener(Event.ENTER_FRAME,onEnterFrm);
  27.                 }
  28.                 private function onPlantClicked(e:MouseEvent):void {
  29.                         if (money>=10&&! playerMoving) {
  30.                                 money-=10;
  31.                                 updateMoney();
  32.                                 selector=new selectorMc();
  33.                                 selector.visible=false;
  34.                                 plantContainer.addChild(selector);
  35.                                 movingPlant=new plantMc() ;
  36.                                 plantContainer.addChild(movingPlant);
  37.                                 playerMoving=true;
  38.                         }
  39.                 }
  40.                 private function addPlants():void {
  41.                         addChild(plantContainer);
  42.                         plant=new plantMc();
  43.                         plantContainer.addChild(plant);
  44.                         plant.buttonMode=true;
  45.                         plant.x=90;
  46.                         plant.y=40;
  47.                         plant.addEventListener(MouseEvent.CLICK,onPlantClicked);
  48.                 }
  49.                 private function addText():void {
  50.                         addChild(moneyText);
  51.                         updateMoney();
  52.                         moneyText.textColor=0xFFFFFF;
  53.                         moneyText.height=20;
  54.                 }
  55.                 private function updateMoney():void {
  56.                         moneyText.text="Money: "+money.toString();
  57.                 }
  58.                 private function onEnterFrm(e:Event):void {
  59.                         for (var i:uint=0; i<sunContainer.numChildren; i++) {
  60.                                 var fallingSun:sunMc=sunContainer.getChildAt(i) as sunMc;
  61.                                 if (fallingSun.y<fallingSun.destinationY) {
  62.                                         fallingSun.y++;
  63.                                 } else {
  64.                                         fallingSun.alpha-=0.01;
  65.                                         if (fallingSun.alpha<0) {
  66.                                                 fallingSun.removeEventListener(MouseEvent.CLICK,sunClicked);
  67.                                                 sunContainer.removeChild(fallingSun);
  68.                                         }
  69.                                 }
  70.                         }
  71.                         if (playerMoving) {
  72.                                 movingPlant.x=mouseX;
  73.                                 movingPlant.y=mouseY;
  74.                                 var plantRow:int=Math.floor((mouseY-80)/75);
  75.                                 var plantCol:int=Math.floor((mouseX-25)/65);
  76.                                 if (plantRow>=0&&plantCol>=0&&plantRow<5&&plantCol<9) {
  77.                                         selector.visible=true;
  78.                                         selector.x=25+plantCol*65;
  79.                                         selector.y=80+plantRow*75;
  80.                                 } else {
  81.                                         selector.visible=false;
  82.                                 }
  83.                         }
  84.                 }
  85.                 private function fallingSuns():void {
  86.                         addChild(sunContainer);
  87.                         flowersTimer.start();
  88.                         flowersTimer.addEventListener(TimerEvent.TIMER, newSun);
  89.                 }
  90.                 private function newSun(e:TimerEvent):void {
  91.                         var sunRow:uint=Math.floor(Math.random()*5);
  92.                         var sunCol:uint=Math.floor(Math.random()*9);
  93.                         sun = new sunMc();
  94.                         sun.buttonMode=true;
  95.                         sunContainer.addChild(sun);
  96.                         sun.x=52+sunCol*65;
  97.                         sun.destinationY=130+sunRow*75;
  98.                         sun.y=-20;
  99.                         sun.addEventListener(MouseEvent.CLICK,sunClicked);
  100.                 }
  101.                 private function sunClicked(e:MouseEvent):void {
  102.                         e.currentTarget.removeEventListener(MouseEvent.CLICK,sunClicked);
  103.                         money+=5;
  104.                         updateMoney();
  105.                         var sunToRemove:sunMc=e.currentTarget as sunMc;
  106.                         sunContainer.removeChild(sunToRemove);
  107.                 }
  108.                 private function setupField():void {
  109.                         gameField=new Array();
  110.                         for (var i:uint=0; i<5; i++) {
  111.                                 gameField[i]=new Array();
  112.                                 for (var j:uint=0; j<9; j++) {
  113.                                         gameField[i][j]=0;
  114.                                 }
  115.                         }
  116.                 }
  117.                 private function drawField():void {
  118.                         var fieldSprite:Sprite=new Sprite();
  119.                         var randomGreen:Number;
  120.                         addChild(fieldSprite);
  121.                         fieldSprite.graphics.lineStyle(1,0xFFFFFF);
  122.                         for (var i:uint=0; i<5; i++) {
  123.                                 for (var j:uint=0; j<9; j++) {
  124.                                         randomGreen=(125+Math.floor(Math.random()*50))*256;
  125.                                         fieldSprite.graphics.beginFill(randomGreen);
  126.                                         fieldSprite.graphics.drawRect(25+65*j,80+75*i,65,75);
  127.                                 }
  128.                         }
  129.                 }
  130.         }
  131. }
复制代码

跟往常一样,让我们来看下新的代码:

第25行:调用addPlants函数(第40-48行),这将会增加植物选项条。现在,只有一种植物,它就是绿色的圆形(别忘了,我们玩的是“圆形大战方块”)。

第40-48行:addPlants函数把我们唯一能买到的植物加入到显示列表,并且给它注册一个鼠标事件侦听器onPlantClicked。这个侦听函数是代码的核心部分。

让我们来看看onPlantClicked函数是如何工作的:

第29行:当你有足够的钱时你才能买植物,并且不能是你已经买了一株植物,正找个地方放置它。现在,植物的价格是10个金币。

第30-31行:扣掉你买植物所花费的钱,并且更新文本框。

第32-34行:把选择器加入到显示列表,但此刻要使得它不可见。

第34-36行:把植物放到游戏区块中。

第37行:设置playerMoving的值为true,告诉程序我们正在移动一株植物,给它选择一个家。当playerMoving为真时会发生什么呢?在onEnterFrm函数里,一些事因此改变了。

第71-83行:这里是playerMoving为真时所发生的:当我们考虑在要哪个区块放置我们刚刚买到的植物时,我们所买的植物跟随鼠标移动(第74-75行)。如果我们的鼠标滑过一个区块(第76行),我们就使选择器可见,使得该区块高亮显示(第77-79行),否则,我们继续保持选择器不可见(第81行)。

下面是结果:


收集10个金币,然后购买一株植物,把它移向游戏区域。
下载源代码。下一次,安置植物,并且第一个僵尸到来!

评论
添加红包

请填写红包祝福语或标题

红包个数最小为10个

红包金额最低5元

当前余额3.43前往充值 >
需支付:10.00
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明:

1.余额是钱包充值的虚拟货币,按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载,可以购买VIP、付费专栏及课程。

余额充值