因项目需要准备对LISTVIEW的滚动条进行自绘。于是在网上搜了一下,问题没解决,却搜出一篇令人不愉快的帖子 。确实,那时候实力是不够的,但现在应该是没问题了,为这个目的才不断磨练自己的。
LISTVIEW控件的滚动条是系统自带的,它不创建窗口。对LISTVIEW窗口本身进行子类化后,要处理一些跟滚动条有关的消息。
首先是要骗过WM_NCPAINT消息。这个十分容易。WM_NCPAINT消息的wParam是一个区域的句柄。当它不为1时,从它里面CLIP掉滚动条的区域,再传给原窗口过程即可。当它为1时,创建一个包含控件全客户区域的Region,再从中CLIP掉滚动条的区域,传给原窗口过程。
然后是WM_HSCROLL和WM_VSCROLL消息。在调用原窗口过程之前需要去掉窗口的WS_HSCROLL和WS_VSCROLL样式,否则窗口过程就会在消息中绘制滚动条。调用后需要恢复。同时为避免窗口在WM_STYLECHANGING和WM_STYLECHANGED消息中重绘,也需要截获这两个消息。
WM_NCCALCSIZE消息也是必须截获的。如果是在处理WM_HSCROLL和WM_VSCROLL消息的过程中响应WM_NCCALCSIZE,则必须去掉WS_HSCROLL和WS_VSCROLL样式。
然后是WM_ERASEBACKGROUND,WM_MOUSEWHELL消息。在这消息后需要重绘滚动条。
最重要的莫过于WM_NCHITTEST消息了。因为是自绘,所以滚动条的按下和拖动都必须在这里处理。
在自己写的滚动条Track函数中,最头疼的莫过于ThumbTrack了。当你计算好滚动到的绝对位置后,用SendMessage(hWnd, WM_XSCROLL, MAKEWPARAM(SB_THUMBTRACK, Pos), 0)发给窗口时,它居然没有反应。这是因为窗口过程不会从消息中取得TrackPos,而是会调用GetScrollInfo的API取得TrackPos(因为前者只有16位)。但是使用SetScrollInfo是没办法设置TrackPos的。虽然你可以用SIF_POS标志让它同时设置Pos和TrackPos,但当Pos等于TrackPos时,窗口过程不会做任何响应。从windows源代码中我们可以了解到,TrackPos并不会为每个窗口保存一份,实际上,在任一时刻最多只有一个滚动条在做ThumbTrack的操作,因此系统只需要用一个全局变量来保存就可以了。
解决这个问题的办法是HookAPI。在GetScrollInfo中返回我们自己的TrackPos。要注意的是要Hook的不是本模块的API,而是ComCtl32.dll中的GetScrollInfo。因此简单的如往@GetScrollInfo地址写几句跳转的方法是行不通的。必须遍历ComCtl32.dll的pe头。这种技术在很多文章中都有描述。
不多说了,以下是Delphi代码,要点在前面已有描述,源码中没有做特殊说明。
使用说明:
资源中是一张横条的192*16的位图,从左到右依次是:左箭头、右箭头、上箭头、下箭头、左箭头按下、右箭头按下、上箭头按下、下箭头按下、横Thumb条、纵Thumb条、横背景条、纵背景条。
初始化时,调用GetSkinSB.InitSkinSB(ListView1.Handle);即可。窗口销毁前调用GetSkinSB.UninitSkinSB(ListView1.Handle)。
虽然也可针对EDIT(TMemo)和其它使用系统滚动条的控件使用此模块,但效果各有差异,需要分别做特殊处理。
unit SkinSB;
interface
uses
SysUtils, Classes, Windows, Messages, Graphics;
const
SKINSB_PROP = '{8BC6661E-5880-4353-878D-C3B3784CFC5F}';
type
TBarPosCode = ( bpcNone,
bpcHArrowL, bpcHArrowR, bpcHPageL, bpcHPageR, bpcHThumb,
bpcVArrowU, bpcVArrowD, bpcVPageU, bpcVPageD, bpcVThumb,
bpcCross );
TWindowProc = function (hWnd: HWND; uMsg: UINT; wParam: WPARAM; lParam: LPARAM): LRESULT; stdcall;
PSkinSBInfo = ^TSkinSBInfo;
TSkinSBInfo = packed record
OldWndProc: TWindowProc;
Prevent: Boolean; // prevent style change message
Scrolling: Boolean;
Style: Cardinal; // real style
ThumbTrack: Boolean;
ThumbPos: Integer;
Tracking: Boolean; // tracking: click arrow or track thumb
end;
TSkinSB = class
protected
FBitmap: TBitmap;
constructor CreateInstance;
public
constructor Create;
destructor Destroy; override;
procedure InitSkinSB(H: HWND);
procedure UnInitSkinSB(H: HWND);
procedure DrawElem(H: HWND; Code: TBarPosCode; R: TRect; Down: Boolean);
end;
function GetSkinSB: TSkinSB;
function SkinSBWndProc(hWnd: HWND; uMsg: UINT; wParam: WPARAM; lParam: LPARAM): LRESULT; stdcall;
function GetSkinSBInfo(hWnd: HWND): PSkinSBInfo;
implementation
uses
CommCtrl;
{$R *.res}
var
l_SkinSB: TSkinSB;
l_SkinSB_Prop: TATOM;
type
PImageImportDescriptor = ^TImageImportDescriptor;
TImageImportDescriptor = packed record
OriginalFirstThunk: DWORD; // or Characteristics: DWORD
TimeDateStamp: DWORD;
ForwarderChain: DWORD;
Name: DWORD;
FirstThunk: DWORD;
end;
PImageChunkData = ^TImageChunkData;
TImageChunkData = packed record
case Integer of
0: ( ForwarderString: DWORD );
1: ( Func: DWORD );
2: ( Ordinal: DWORD );
3: ( AddressOfData: DWORD );
end;
PImageImportByName = ^TImageImportByName;
TImageImportByName = packed record
Hint: Word;
Name: array[0..0] of Byte;
end;
type
PHookRec = ^THookRec;
THookRec = packed record
OldFunc: Pointer;
NewFunc: Pointer;
end;
var
_HookGetScrollInfo: THookRec;
procedure HookApiInMod(ImageBase: Cardinal; ApiName: PChar; PHook: PHookRec);
var
pidh: PImageDosHeader;
pinh: PImageNtHeaders;
pSymbolTable: PIMAGEDATADIRECTORY;
piid: PIMAGEIMPORTDESCRIPTOR;
pitd_org, pitd_1st: PImageChunkData;
piibn: PImageImportByName;
pAPIFunction: Pointer;
written, oldAccess: DWORD;
begin
if ImageBase = 0 then Exit;
pidh := PImageDosHeader(ImageBase);
pinh := PImageNtHeaders(DWORD(ImageBase) + Cardinal(pidh^._lfanew));
pSymbolTable := @pinh^.OptionalHeader.DataDirectory[1];
piid := PImageImportDescriptor(DWORD(ImageBase) + pSymbolTable^.VirtualAddress);
repeat
pitd_org := PImageChunkData(DWORD(ImageBase) + piid^.OriginalFirstThunk);
pitd_1st := PImageChunkData(DWORD(ImageBase) + piid^.FirstThunk);
repeat
piibn := PImageImportByName(DWORD(ImageBase) + LPDWORD(pitd_org)^);
pAPIFunction := Pointer(pitd_1st^.Func);
if StrComp(ApiName, @piibn^.Name) = 0 then
begin
PHook^.OldFunc := pAPIFunction;
VirtualProtect(@(pitd_1st^.Func), SizeOf(DWORD), PAGE_WRITECOPY, oldAccess);
WriteProcessMemory(GetCurrentProcess(), @(pitd_1st^.Func), @PHook^.NewFunc, SizeOf(DWORD), written);
VirtualProtect(@(pitd_1st^.Func), SizeOf(DWORD), oldAccess, oldAccess);
end;
Inc(pitd_org);
Inc(pitd_1st);
until pitd_1st^.Func = 0;
Inc(piid);
until piid^.FirstThunk + piid^.OriginalFirstThunk + piid^.ForwarderChain + piid^.Name = 0;
end;
function GetSkinSBInfo(hWnd: HWND): PSkinSBInfo;
begin
Result := PSkinSBInfo( GetProp(hWnd, MAKEINTATOM(l_SkinSB_Prop)) );
end;
function GetSkinSB: TSkinSB;
begin
if l_SkinSB = nil then l_SkinSB := TSkinSB.CreateInstance;
Result := l_SkinSB;
end;
function CalcScrollBarRect(H: HWND; nBarCode: Cardinal): TRect;
var
Style, ExStyle: Cardinal;
begin
SetRect(Result, 0, 0, 0, 0);
Style := GetWindowLong(H, GWL_STYLE);
ExStyle := GetWindowLong(H, GWL_EXSTYLE);
if (nBarCode = SB_HORZ) and ((Style and WS_HSCROLL) = 0) then Exit;
if (nBarCode = SB_VERT) and ((Style and WS_VSCROLL) = 0) then Exit;
GetWindowRect(H, Result);
OffsetRect(Result, -Result.Left, -Result.Top);
if ((ExStyle and WS_EX_DLGMODALFRAME) <> 0)
or ((ExStyle and WS_EX_CLIENTEDGE) <> 0) then
begin
InflateRect(Result, -GetSystemMetrics(SM_CXEDGE), -GetSystemMetrics(SM_CYEDGE));
end;
// special: returns the cross
if nBarCode = SB_BOTH then
begin
if ((Style and WS_HSCROLL) = 0) or ((Style and WS_VSCROLL) = 0) then
begin
SetRect(Result, 0, 0, 0, 0);
Exit;
end;
Result.Top := Result.Bottom - GetSystemMetrics(SM_CYVSCROLL);
if (ExStyle and WS_EX_LEFTSCROLLBAR) <> 0 then Result.Right := Result.Left + GetSystemMetrics(SM_CXHSCROLL)
else Result.Left := Result.Right - GetSystemMetrics(SM_CXHSCROLL);
Exit;
end;
if nBarCode = SB_HORZ then
begin
// if (ExStyle and WS_EX_TOPSCROLLBAR) <> 0 then Result.Bottom := Result.Top + GetSystemMetrics(SM_CYVSCROLL)
Result.Top := Result.Bottom - GetSystemMetrics(SM_CYVSCROLL);
if ((Style and WS_VSCROLL) <> 0) then Dec(Result.Right, GetSystemMetrics(SM_CYVSCROLL));
end;
if nBarCode = SB_VERT then
begin
if (ExStyle and WS_EX_LEFTSCROLLBAR) <> 0 then Result.Right := Result.Left + GetSystemMetrics(SM_CXHSCROLL)
else Result.Left := Result.Right - GetSystemMetrics(SM_CXHSCROLL);
if ((Style and WS_HSCROLL) <> 0) then Dec(Result.Bottom, GetSystemMetrics(SM_CXHSCROLL));
end;
end;
type
TBarElem = (beArrow1, beBG, be