cmake:arm-xm-linux交叉编译工具链文件及交叉支持HTTPS的curl静态库

curl是一个成熟的HTTP client库，可以使用cmake在命令行完成交叉编译。

TOOLCHAIN

首先要准备工具链文件
arm-xm-linux-uclibcgnueabi.toolchain.cmake

# This one is important
SET(CMAKE_SYSTEM_NAME Linux)
SET(CMAKE_SYSTEM_PROCESSOR arm)
# _compiler_prefix  定义编译器安装位置 
set(_compiler_prefix /opt/xm_toolchain/arm-xm-linux/usr)
if(NOT EXISTS ${_compiler_prefix})
	if(NOT $ENV{CROSS_COMPILER_PREFIX} STREQUAL "")
	    set(_compiler_prefix $ENV{CROSS_COMPILER_PREFIX})
	elseif(CROSS_COMPILER_PREFIX)
	    set(_compiler_prefix ${CROSS_COMPILER_PREFIX})
	else()
		find_program(_gcc_path arm-xm-linux-uclibcgnueabi-gcc)
		if(NOT _gcc_path)
			message(FATAL_ERROR "NOT FOUND compiler arm-xm-linux-uclibcgnueabi-gcc in system path")
		endif()
		get_filename_component(_bin ${_gcc_path} DIRECTORY )
		get_filename_component(_compiler_prefix ${_bin} DIRECTORY )
	endif()	
endif()

# Specify the cross compiler
SET(CMAKE_C_COMPILER "${_compiler_prefix}/bin/arm-xm-linux-uclibcgnueabi-gcc")
SET(CMAKE_CXX_COMPILER "${_compiler_prefix}/bin/arm-xm-linux-uclibcgnueabi-g++")
#UNSET(CMAKE_C_FLAGS_INIT CACHE)
#SET(CMAKE_C_FLAGS_INIT "-std=c99" CACHE STRING "c flags init" FORCE)

# Where is the target environment
SET(CMAKE_FIND_ROOT_PATH "${_compiler_prefix}/arm-xm-linux-uclibcgnueabi/sysroot")

# Search for programs in the build host directories
SET(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)

# For libraries and headers in the target directories
SET(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY BOTH)
SET(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE BOTH)

unset(_compiler_prefix)

build curl

以下脚本实现arm-xm-linx(雄迈650)下使用cmake及交叉编译curl

cd curl
mkdir build
cd build
#############################################
# 生成gcc工程文件
CFLAGS=-fPIC \
cmake .. \
	-DCMAKE_BUILD_TYPE=RELEASE \
	-DCMAKE_INSTALL_PREFIX=/your/path/curl-arm-xm-linux-uclibcgnueabi \
	-DBUILD_SHARED_LIBS=OFF -DCURL_USE_OPENSSL=ON \
	-DCMAKE_PREFIX_PATH=/your/path/Downloads/dist/openssl-1.1.0d_arm-xm-linux-uclibcgnueabi \
	-DCMAKE_TOOLCHAIN_FILE=/your/path/cmake/arm-xm-linux-uclibcgnueabi.toolchain.cmake

# CFLAGS=-fPIC 视需要指定此选项，如果不指定，如果后续在自己的项目中使用curl生成动态库时，连接会报错
# CMAKE_INSTALL_PREFIX 指定安装位置
# BUILD_SHARED_LIBS=OFF 生成curl静态库,如果生成动态库,可以不加此选项
# CURL_USE_OPENSSL=ON 指定使用OPENSSL,如果不需要支持HTTPS,可以不加此选项
# CMAKE_PREFIX_PATH 指定OpenSSL库的安装位置不需要支持HTTPS,可以不加此选项
#############################################
# 编译CURL并安装到CMAKE_INSTALL_PREFIX指定的位置
cmake --build . --target install --config Release -j 8
# - j 8 指定8线程并行编译，以提高编译速度