30、Keil-STM32启动文件详解

一、C语言基础知识

1. 关于C语言
   C语言相对于汇编是属于高级语言，写好的C语言在编译之后首先被翻译成汇编指令，而汇编指令是和指令吗对应的，经过汇编生成指令码。
   
   2.关于C语言环境
   由于C语言相对于汇编的各种新属性，所以需要用汇编先构建一个C语言的环境。(比如不同类型的变量在内存中位置要设置好)。
   C语言常见元素类型:（全局变量、静态变量）（局部变量、函数形参）（常量）（代码）等。
   3.关于内存
   一般内存主要分为：堆区、栈区、静态区（全局区）、代码区、常量区这几个区域。(堆栈也可称为动态区)

二、关于STM32的启动过程

1. 启动文件主要完成如下工作，即程序执行过程：

• 设置堆栈指针 SP = __initial_sp。
• 设置 PC 指针 = Reset_Handler。
• 设置中断向量表。
• 配置系统时钟。
• 配置外部 SRAM/SDRAM 用于程序变量等数据存储（这是可选的） 。
• 跳转到 C 库中的 __main ，最终会调用用户程序的 main()函数。
  Cortex-M 内核处理器复位后，处于线程模式，指令权限是特权级别（最高级别），堆栈设置为使用主堆栈 MSP

2.硬件复位之后，CPU 内的时序逻辑电路首先完成如下两个工作（ 程序代码下载到内部 flash 为例，flash首地址 0x0800 0000）
 将 0x08000000 位置存放的堆栈栈顶地址存放到 SP 中(MSP)。
 将 0x08000004 位置存放的向量地址装入 PC 程序计数器。
CPU 从 PC 寄存器指向的物理地址取出第 1 条指令开始执行程序，也就是开始执行复位中断服务程
序 Reset_Handler。
复位中断服务程序会调用SystemInit()函数来配置系统时钟、配置FMC总线上的外部SRAM/SDRAM，
然后跳转到 C 库中__main 函数。由 C 库中的__main 函数完成用户程序的初始化工作（比如：变量赋初
值等），最后由__main 函数调用用户写的 main()函数开始执行 C 程序。

三、启动文件分析

1.第 1 部分代码分析
下面的代码实现开辟栈(stack)空间，用于局部变量、 函数调用、 函数的参数等。

 2. ; Amount of memory (in bytes) allocated for Stack
 3. ; Tailor this value to your application needs
 4. ; <h> Stack Configuration
 5. ; <o> Stack Size (in Bytes) <0x0-0xFFFFFFFF:8>
 6. ; </h>
 7.  8. Stack_Size EQU 0x00000800
 9.  
 10. AREA STACK, NOINIT, READWRITE, ALIGN=3
 11. Stack_Mem SPACE Stack_Size
 12. __initial_sp
第 7 行： EQU 是表示宏定义的伪指令，类似于 C 语言中的#define。伪指令的意思是指这个“指令”并不会生成二进制程序代码，也不会引起变量空间
分配。0x00000800 表示栈大小，注意这里是以字节为单位。
第 9 行： 开辟一段数据空间可读可写，段名 STACK，按照 8 字节对齐。 ARER 伪指令表示下面将开始定义一个代码段或者数据段。此处是定义数据段。
 ARER 后面的关键字表示这个段的属性。
STACK ：表示这个段的名字，可以任意命名。
NOINIT：表示此数据段不需要填入初始数据。
READWRITE：表示此段可读可写。
ALIGN=3 ：表示首地址按照 2 的 3 次方对齐，也就是按照 8 字节对齐(地址对 8 求余数等于 0)。
第 10 行： SPACE 这行指令告诉汇编器给 STACK 段分配 0x00000800 字节的连续内存空间。
第 11 行： __initial_sp 紧接着 SPACE 语句放置，表示了栈顶地址。 __initial_sp 只是一个标号，标号主要用于表示一片内存空间的某个位置，
等价于 C 语言中的“地址”概念。地址仅仅表示存储空间的一个位置，从 C 语言的角度来看，变量的地址，数组的地址或是函数的入口地址在本质上并
无区别。

2.第 2部分代码分析
下面的代码实现开辟堆(heap)空间，主要用于动态内存分配，也就是说用 malloc， calloc, realloc 等函数分配的变量空间是在堆上。

 14. ; <h> Heap Configuration
 15. ; <o> Heap Size (in Bytes) <0x0-0xFFFFFFFF:8>
 16. ; </h>
 17.  18. Heap_Size EQU 0x00000400
 19.  20. AREA HEAP, NOINIT, READWRITE, ALIGN=3
 21. __heap_base
 22. Heap_Mem SPACE Heap_Size
 23. __heap_limit
这几行语句和上面第 1 部分代码类似。分配一片连续的内存空间给名字叫 HEAP 的段，也就是分配堆空
间。堆的大小为 0x00000400。
__heap_base 表示堆的开始地址。
__heap_limit 表示堆的结束地址。

3.第 3 部分代码分析

1. PRESERVE8
2. THUMB
3.
4.
3. ; Vector Table Mapped to Address 0 at Reset
4. AREA RESET, DATA, READONLY
5. EXPORT __Vectors
6. EXPORT __Vectors_End
7. EXPORT __Vectors_Size
第 1 行： PRESERVE8 指定当前文件保持堆栈八字节对齐。
第 2 行： THUMB 表示后面的指令是 THUMB 指令集 ， CM4 采用的是 THUMB - 2 指令集。
第 6 行： AREA 定义一块代码段，只读，段名字是 RESET。 READONLY 表示只读，缺省就表示代码段了。
第 7-9 行： 3 行 EXPORT 语句将 3 个标号申明为可被外部引用， 主要提供给链接器用于连接库文件或
其他文件。

4.第 4 部分代码分析

1. __Vectors DCD __initial_sp ; Top of Stack
2. DCD Reset_Handler ; Reset Handler
3. DCD NMI_Handler ; NMI Handler
4. DCD HardFault_Handler ; Hard Fault Handler
5.
6. 中间部分省略未写
7.
8. DCD HASH_RNG_IRQHandler ; Hash and Rng
9. DCD FPU_IRQHandler ; FPU
10.
11.
12. __Vectors_End
13.
14. __Vectors_Size EQU __Vectors_End - __Vectors
上面的这段代码是建立中断向量表，中断向量表定位在代码段的最前面。具体的物理地址由链接器的
配置参数（ IROM1 的地址）决定。如果程序在 Flash 运行，则中断向量表的起始地址是 0x08000000。
以 MDK 为例，就是如下配置选项：

DCD 表示分配 1 个 4 字节的空间。每行 DCD 都会生成一个 4 字节的二进制代码。中断向量表存放的实际上是中断服务程序的入口地址。当异常（也即是中断事件）发生时， CPU 的中断系统会将相应的入口地址赋值给 PC 程序计数器，之后就开始执行中断服务程序。
5.第 5 部分代码分析

1. AREA |.text|, CODE, READONLY
2.
3. ; Reset handler
4. Reset_Handler PROC
5. 				EXPORT Reset_Handler [WEAK]
6. 				IMPORT SystemInit
7. 				IMPORT __main
8.
9. 				LDR R0, =SystemInit
10. 			BLX R0
11. 			LDR R0, =__main
12.				BX R0
13. 			ENDP
第 1 行： AREA 定义一块代码段，只读，段名字是 .text 。 READONLY 表示只读。
第 4 行： 利用 PROC、 ENDP 这一对伪指令把程序段分为若干个过程，使程序的结构加清晰。
第 5 行： WEAK 声明其他的同名标号优先于该标号被引用,就是说如果外面声明了的话会调用外面的。 这
个声明很重要，它让我们可以在 C 文件中任意地方放置中断服务程序，只要保证 C 函数的名字和向量表中
的名字一致即可。
第 6 行： IMPORT：伪指令用于通知编译器要使用的标号在其他的源文件中定义。但要在当前源文件中引
用，而且无论当前源文件是否引用该标号，该标号均会被加入到当前源文件的符号表中。
第 9 行： SystemInit 函数在文件 system_stm32f4xx.c 里面，主要实现 RCC 相关寄存器复位和中断向量
表位置设置。
第 11 行： __main 标号表示 C/C++标准实时库函数里的一个初始化子程序__main 的入口地址。该程序
的一个主要作用是初始化堆栈(跳转__user_initial_stackheap 标号进行初始化堆栈的，下面会讲到这个标
号)，并初始化映像文件，最后跳转到 C 程序中的 main 函数。这就解释了为何所有的 C 程序必须有一
个 main 函数作为程序的起点。因为这是由 C/C++标准实时库所规，并且不能更改。

6.第 6 部分代码分析

1. ; Dummy Exception Handlers (infinite loops which can be modified)
2.
3. NMI_Handler PROC
4. 					  EXPORT NMI_Handler [WEAK]
5. 					  B .
6. 					  ENDP
7. HardFault_Handler\
8. 					  PROC
9. 					  EXPORT HardFault_Handler [WEAK]
10. 					  B .
11.					  	  ENDP
12.
13. 中间部分省略未写
14. Default_Handler PROC
15.
16. EXPORT WWDG_IRQHandler [WEAK]
17. EXPORT PVD_AVD_IRQHandler [WEAK]
18. EXPORT TAMP_STAMP_IRQHandler [WEAK]
19. 中间部分省略未写
20. HASH_RNG_IRQHandler
21. FPU_IRQHandler
22. 					B .
23. 					ENDP
24. 					ALIGN
第 5 行： 死循环，用户可以在此实现自己的中断服务程序。 不过很少在这里实现中断服务程序，一般多是
在其它的 C 文件里面重新写一个同样名字的中断服务程序， 因为这里是 WEEK 弱定义的。 如果没有在其
它文件中写中断服务器程序，且使能了此中断，进入到这里后，会让程序卡在这个地方。
第 14 行： 缺省中断服务程序（ 开始）
第 22 行： 死循环， 如果用户使能中断服务程序，而没有在 C 文件里面写中断服务程序的话，都会进入到
这里。 比如在程序里面使能了串口 1 中断，而没有写中断服务程序 USART1_IRQHandle， 那么串口中断
来了，会进入到这个死循环。
第 23 行： 缺省中断服务程序（ 结束） 。

7.第 7 部分代码分析

1. ;*******************************************************************************
2. ; User Stack and Heap initialization
3. ;*******************************************************************************
4. 				IF :DEF:__MICROLIB
5.
6. 				EXPORT __initial_sp
7. 				EXPORT __heap_base
8. 				EXPORT __heap_limit
9.
10.					ELSE
11.
12. 				IMPORT __use_two_region_memory
13. 				EXPORT __user_initial_stackheap
14.
15. __user_initial_stackheap
16.
17. 				LDR R0, = Heap_Mem
18. 				LDR R1, =(Stack_Mem + Stack_Size)
19. 				LDR R2, = (Heap_Mem + Heap_Size)
20. 				LDR R3, = Stack_Mem
21. 				BX LR
22.
23. 				ALIGN
24.
25. 				ENDIF
26.
27. 				END
第 4 行：简单的汇编语言实现 IF…….ELSE…………语句。如果定义了 MICROLIB，那么程序是不会执行 ELSE
分支的代码。 __MICROLIB 可能大家并不陌生，就在 MDK 的 Target Option 里面设置。

第 5 行： __user_initial_stackheap 将由__main 函数进行调用。
 MicroLib
MicroLib 是 MDK 里面带的微库， 针对嵌入式应用， MicroLIB 做了深度优化，比使用 C 标准库所需的 RAM 和 FLASH 空间都大大减小比如调用：
<math.h>， <stdlib.h>， <stdio.h>， <string.h>
更多相关知识可以地址： http://www.keil.com/arm/microlib.asp。另外注意 microlib 只有库，没有源文件。下图是标准库和微库生成代码的比较。