王爽《汇编语言》实验15 安装新的int 9中断例程

批注：
    在装载新的int 9中断程序后，键盘按下某键会按照以下流程触发相应事件。
    1、CPU取中断类型码9；
    2、标志寄存器入栈；
    3、设置IF=0，TF=0；
    4、CS、IP入栈；
    5、读取0:24h的内容，IP=204H，CS=0H，进入新的int 9例程；
    6、标志寄存器入栈(47行)；
    7、因在步骤2中，已经设置IF=0，TF=0了，所以此处不需再设置；
    8、call dword ptr cs:[200h]，实现了CS、IP入栈，IP=200H,CS=0H，跳转至原int 9例程；
    9、iret(66行)，CS、IP出栈(对应的是步骤8中的CS、IP入栈)，标志寄存器出栈(对应的是步骤6的标志寄存器入栈操作)；
    10、CS、IP出栈(对应的是步骤4中的入栈操作)；
    11、标志寄存器出栈(对应的是步骤2中的标志寄存器入栈)；

    12、继续执行其他程序，直到键盘发生操作继续从步骤1开始新的中断程序。

assume cs:code
stack segment
	db 128 dup(0)
stack ends

code segment
start:
	mov ax,stack
	mov ss,ax
	mov sp,128

	push cs
	pop ds
	
	mov ax,0
	mov es,ax
	
	mov si,offset int9					;将ds:si指向源地址
	mov di,204h							;将es:di指向目的地址
	mov cx,offset int9end-offset int9	;设置cx为传输长度
	cld									;设置为正传送
	rep movsb							;将新的中断例程放置于0:204H开始的内存中
	
	
	push es:[9*4]
	pop es:[200h]
	push es:[9*4+2]
	pop es:[202h]						;将原来的int 9中断例程入口地址保存在0:200H(IP)、0:202H(CS)单元中
	
	cli
	mov word ptr es:[9*4],204h			;在中断向量表中设置新的int 9中断例程的入口地址为0:204H
	mov word ptr es:[9*4+2],0
	sti
	
	mov ax,4c00h
	int 21h
	
;--------------以下为新的int 9中断例程--------------------
int9:
	push ax
	push bx
	push cx
	push es
	
	in al,60h						;读入键盘输入
	
	pushf							;标志寄存器入栈
	call dword ptr cs:[200h]		;调用原int 9的中断程序
	
	cmp al,9Eh						;判断是否为松开'a'键
	jne int9ret
	
	mov ax,0b800h					;全屏显示'A'字符
	mov es,ax
	mov bx,0
	mov cx,2000
s:
	mov byte ptr es:[bx],'A'
	add bx,2
	loop s
int9ret:
	pop es
	pop cx
	pop bx
	pop ax
	iret
int9end:nop
code ends
end start