一文读懂CMake

已于 2024-01-13 14:13:32 修改
阅读量2.3k 收藏 11
点赞数 1
分类专栏： CMake 文章标签： CMake CMake基本语法 cmake
于 2022-07-27 16:10:40 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/CAir2/article/details/125995922
版权

这篇文章是站在VS角度描述CMake基本语法的。具体语法对应关系，参照下表。

CMake函数对应VS相关设置

VS相关设置CMake函数
指定包含头文件目录target_include_directories
指定链接库目录target_link_directories
指定链接库target_link_libraries
指定C++标准set(CMAKE_CXX_STANDARD 11)
指定编译器版本cmake -G “Visual Studio 12 2013”
指定平台集cmake -G “Visual Studio 12 2013 Win64”
指定编译类型set(CMAKE_BUILD_TYPE “Debug”）等价于g++ -g
指定预编译宏add_definitions(-Dxxx -Dyyy ) 必须-D开头
指定解决方案名称project(xxxx)
文件分类source_group(“folder_name” file_list)

CMake常见内置变量

CMake内置变量说明（路径都是全路径）
PROJECT_NAMECMakeList.txt里设置的project_name
CMAKE_BUILD_TYPE设置当前工程编译类型（Debug,Release），默认debug
BUILD_TYPE当前工程的编译类型（Debug,Release）
PROJECT_SOURCE_DIR根CMakeLists.txt所在的路径
PROJECT_BINARY_DIR工程的构建目录（build目录）
CMAKE_CURRENT_SOURCE_DIR当前’CMakeLists.txt’ 所在的路径
CMAKE_CURRENT_BINARY_DIR当前正在处理的’构建目录’
CMAKE_CURRENT_LIST_DIR当前处理的’cmake文件’所在的目录
CMAKE_CURRENT_LIST_FILE当前处理的’CMakeLists.txt或cmake’文件的全路径
CMAKE_CURRENT_LIST_LINE当前处理的’CMakeLists.txt或cmake’文件的’行号’
CMAKE_PROJECT_NAME整个项目’配置的project_name
LIBRARY_OUTPUT_DIRECTORY库的存放目录（需要用户设置）
CMAKE_RUNTIME_OUTPUT_DIRECTORY可执行文件的存放目录（需要用户设置，必须在设置可执行文件之前设置）

设置C++FLAGS，例如MT

#release模式下为MT
set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /MT")

#debug模式下为MTD
set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /MTd")

Debug和Release模式设置与判断（该模式不支持动态判断，需要设置变量CMAKE_BUILD_TYPE ）

#设置编译模式为Debug，默认为Debug
set(CMAKE_BUILD_TYPE "Debug")

#当前编译模式的判断
if(CMAKE_BUILD_TYPE)
	string(TOLOWER ${CMAKE_BUILD_TYPE} CUR_BUILD_TYPE)
	if(${CUR_BUILD_TYPE} STREQUAL "release")
		set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -Wall -o3")
		message(STATUS "release build,Cxx flags:${CMAKE_CXX_FLAGS_RELEASE}")
	else()
		#default mode debug
		set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -Wall -o0")
		message(STATUS "debug build,Cxx flags:${CMAKE_CXX_FLAGS_DEBUG}")
	endif()
else()
	#default mode debug
	set(CMAKE_BUILD_TYPE "Debug")
	set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -Wall -o0")
	message(STATUS "debug build,Cxx flags:${CMAKE_CXX_FLAGS_DEBUG}")	
endif()

#变量BUILD_TYPE在Debug模式下位Debug，release模式下为Release,未选中模式的时为空。等价于VS的$(Configuration)
message(STATUS "current build type:${BUILD_TYPE}")

设置工程为Win32 windwos 窗口程序

CMake默认生成的vs工程为console程序。如果想生成windows窗口程序需要指定链接属性。

set_target_properties(demo PROPERTIES LINK_FLAGS "/SUBSYSTEM:WINDOWS")

当前运行平台判断

# 在 Linux 平台
CMAKE_HOST_SYSTEM_NAME = "Linux"
CMAKE_HOST_UNIX = 1
CMAKE_HOST_WIN32 = 空
UNIX = 1
WIN32 = 空
 
# 在 Windows 平台
CMAKE_HOST_SYSTEM_NAME = "Windows"
CMAKE_HOST_UNIX = 空
CMAKE_HOST_WIN32 = 1
UNIX = 空
WIN32 = 1

#判断方法一：通过SYSTEM_NAME
if(CMAKE_HOST_SYSTEM_NAME MATCHES "Linux")
	message(STATUS "current platform: Linux ")
elseif(CMAKE_HOST_SYSTEM_NAME MATCHES "Windows")
	message(STATUS "current platform: Windows ")
else()
	message(STATUS "current platform: unkonw ")
endif()

#判断方法二：通过BOOL值
if(CMAKE_HOST_UNIX)
	message(STATUS "current platform: Linux ")
elseif(CMAKE_HOST_WIN32)
	message(STATUS "current platform: Windows ")
else()
	message(STATUS "current platform: unkonw ")
endif()

指定编译模式

#方法一:Cmake文件中设置变量CMAKE_BUILD_TYPE 
set(CMAKE_BUILD_TYPE "Debug")

#方法二：cmake 执行命令的时候设置变量CMAKE_BUILD_TYPE 
cmake ./ -DCMAKE_BUILD_TYPE:STRING=Debug 

#如果在windows平台
#release版本
cmake --build . --config Release
#debug版本
cmake --build . --config Debug

#如果在linux平台
#release版本
cmake ../ -DCMAKE_BUILD_TYPE=Release
cmake --build .
#Debug版本
cmake ../ -DCMAKE_BUILD_TYPE=Debug
cmake --build .

链接第三方库和头文件包含

#eg：hellow 链接libmymath.a，libtest.a等库，每个库之间以空格分开
target_link_libraries(hellow PUBLIC mymath test)
#指定库位置
target_link_directories(hellow PUBLIC 
						"/home/jef/work/mymath "
						"/home/jef/work/test"
						)
#指定lib头文件位置
target_include_directories(hellow PUBLIC 
                        "/home/jef/work/test/include"
                        "${PROJECT_SOURCE_DIR}/mymath"
                        )

增加预定义宏

#增加预定义宏，必须-D开头，通常配合option来使用
add_definitions(-DUSE_OPEN_SLL)

#代码中使用
#ifdef USE_OPEN_SLL
#else
#endif

开关选项控制option

通过option的ON和off来控制编译流程

#variable：定义选项名称
#help_text：说明选项的含义
#value:定义选项默认状态，一般是OFF或者ON，除去ON之外，其他所有值都为认为是OFF。
option(<variable> "<help_text>" [value])

eg:如果定义USE_OPEN_SLL=ON，则定义宏USE_OPEN_SLL否则不定义

option(USE_OPEN_SLL "USE_OPEN_SLL" ON)

if (USE_OPEN_SLL)
	add_definitions(-DUSE_OPEN_SLL)
	message(STATUS "USE_OPEN_SLL on")
else ()
	message(STATUS "USE_OPEN_SLL off")
endif()

cmake -G "Visual Studio 12 2013 Win64" ../ -DUSE_OPEN_SLL=ON

添加动态库or静态库

#根据宏的定义决定使用动态库或者静态库
#如果定义了MYMATH_STATIC则使用静态库，否则使用动态库
#add_library 表示该target是一个库工程
#add_executable表示该target是一个可执行文件工程
option(MYMATH_STATIC "user mymath static lib" ON)

if(MYMATH_STATIC)
	add_library(mymath STATIC mymath.cpp)
else()
	add_library(mymath SHARED mymath.cpp)
endif()

cmake -G "Visual Studio 12 2013 Win64" ../ -DUSE_MYMATH=OFF

指定项目依赖项（指定项目生成顺序）

#例如当前项目hellow依赖mymath.lib
add_dependencies(hellow mymath)

执行生成事件

add_custom_command

参数含义
PRE_BUILD在目标中执行任何其他规则之前运行
PRE_LINK在编译源代码之后，链接二进制文件或库文件之前运行
POST_BUILD在目标内所有其他规则均已执行后运行
#在VS中我们经常会执行生成后事件，例如生成后复制文件
add_custom_command(TARGET hellow POST_BUILD
  COMMAND ${CMAKE_COMMAND} -E copy_if_different
  ${PROJECT_BINARY_DIR}/bin/mymath.dll ${PROJECT_SOURCE_DIR}/bin/mymath.dll)

指定二进制文件或者库文件生成位置

#一定要在设置target之前设置，否则无效
#二进制文件位置
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
#库文件位置
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)

设置Target的生成目标名称

#修改输出文件的名称，默认和target同名
set_target_properties(hellow PROPERTIES OUTPUT_NAME main)

文件分类source_group

通过上述生成的工程文件没有分类，并且没有包含头文件。下面我们将按照目录结构进行分类（不使用lib）。

在这里插入图片描述
注意涉及函数file和source_group

#获取当前目录下所有的头文件并进行分类
#GLOB-只索引当前目录，不包括子目录
#GLOB_RECURSE-索引当前目录以及包括子目录 
file(GLOB project_header_files ${CMAKE_CURRENT_SOURCE_DIR}/*.h)

#进行头文件，只能是相同类型的文件，否则会失败
source_group("Header Files" ${project_header_files})

#获取mymath目录下的头文件和源文件并且进行分类
#获取mymath目录下所有的文件这里并没有使用aux_source_directory("${CMAKE_CURRENT_SOURCE_DIR}/mymath" maths_file)
file(GLOB math_header_files ${CMAKE_CURRENT_SOURCE_DIR}/mymath/*.h)
file(GLOB math_src_files ${CMAKE_CURRENT_SOURCE_DIR}/mymath/*.cpp)

#source_group有两种写法
#自己定义folder，名称
#source_group("mymath" FILES ${math_header_files} ${math_src_files})
#根据目录结构截取生成目录名称 files的绝对路径去掉${CMAKE_CURRENT_SOURCE_DIR}，即拼成目录名称
source_group(TREE ${CMAKE_CURRENT_SOURCE_DIR} FILES ${math_src_files} ${math_header_files})

#最后一步也是最重要的一步，一定要添加到target里面，否则也不会展示
add_executable(hellow ${all_file} ${project_header_files} ${math_header_files} ${math_src_files})

cmake -G "Visual Studio 12 2013 Win64" ../

此时可以看到文件已经分类，层级分明了。
在这里插入图片描述

配置项目版本号和信息

#设置项目名称和版本
project(Tutorial VERSION 1.0)

#配置头文件传递版本号给源代码
#配置宏定义，配置默认值为ON，如果想关闭 cmake -DUSE_MYMATH=OFF
#option 除了ON之外其他的都默认为OFF
option(USE_MYMATH "user mymath.lib" ON)

#传递字符串给配置文件
set(var_Key "hellow word")
#传递INT给配置文件
set(INT_Key 1)

#输入文件 输出文件
configure_file(hellow_ver.h.in hellow_ver.h)

#由于配置好的文件hellow_ver.h将被写入二进制目录
#所以我们必须将该目录添加到 include 文件的搜索路径中
target_include_directories(hellow PUBLIC 
						"d:/test/include"
                        "${PROJECT_SOURCE_DIR}/mymath"
                        "${PROJECT_BINARY_DIR}"
                        )

hellow_ver.h.in

//配置的项目版本号
#define hellow_VERSION_MAJOR @hellow_VERSION_MAJOR@
#define hellow_VERSION_MINOR @hellow_VERSION_MINOR@

//宏定义
#cmakedefine USE_MYMATH
//注意：${}之间的名称要与cmakedefine后的变量名一样
//变量名称和cmakeLists.txt设置的变量名称相同
#cmakedefine var_Key "@var_Key@”
#cmakedefine INT_Key @INT_Key@

运行之后生成的hellow_ver.h
在这里插入图片描述
如果想取消USE_MYMATH 可以使用 -DUSE_MYMATH=OFF

cmake -G "Visual Studio 12 2013 Win64" ../ -DUSE_MYMATH=OFF

CMake Demo

下面将建立一个简单的Demo，展示一下CMake的简单应用。该工程名称叫cmakedemo，依赖一个mymath库。文件目录结构如下：
在这里插入图片描述

project/CMakeLists.txt

cmake_minimum_required(VERSION 3.10)

project(cmakedemo VERSION 1.0)

option(USE_MYMATH "my math as a lib to use" OFF)
#指定C++执行标准
set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED true)
set(CMAKE_BUILD_TYPE "Debug")

#设置输出目录
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
#so库文件位置
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
#lib文件位置,windows上有效，linux上无效
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)



#所有源文件
aux_source_directory("${CMAKE_CURRENT_SOURCE_DIR}" src_files)

if(NOT USE_MYMATH)
    aux_source_directory("${CMAKE_CURRENT_SOURCE_DIR}/mymath" math_src_files)
else()
    set(math_src_files "")
    add_subdirectory(mymath)
endif()



#所有头文件
#GLOB-只索引当前目录，不包括子目录
#GLOB_RECURSE-索引当前目录以及包括子目录 
file(GLOB_RECURSE header_files ${CMAKE_CURRENT_SOURCE_DIR}/*.h)

#文件分类,必须加入到executable，否则不会分类
#source_group("Source Files" ${src_files} ${math_src_files})
#source_group("Header Files" ${header_files})
source_group(TREE ${CMAKE_CURRENT_SOURCE_DIR} FILES ${src_files} ${math_src_files} ${header_files})

#打印文件
message(STATUS "src_files= ${src_files} ${math_src_files}")
message(STATUS "header_files= ${header_files}")

#添加生成文件
add_executable(main ${src_files} ${math_src_files} ${header_files})

#增加头文件目录
target_include_directories(main PUBLIC 
                        "${CMAKE_CURRENT_SOURCE_DIR}/mymath"
                        )

message(STATUS "include_directories ${CMAKE_CURRENT_SOURCE_DIR}/mymath")

if(USE_MYMATH)
    #添加连接库    
    target_link_libraries(main PUBLIC mymath)
    #添加库目录，这个可以省略，默认会包含进去
    #target_link_directories(main PUBLIC ${CMAKE_ARCHIVE_OUTPUT_DIRECTORY}/${BUILD_TYPE})
endif()

project/mymath/CMakeLists.txt(注意子CMake不要和根CMake变量名称重复)


#如果是win则需要定义export接口
if(CMAKE_HOST_WIN32)
	add_definitions(-DMYPATH_EXPORT)
endif()
#所有源文件
aux_source_directory("${CMAKE_CURRENT_SOURCE_DIR}" math_src_files)

#所有头文件
#GLOB-只索引当前目录，不包括子目录
#GLOB_RECURSE-索引当前目录以及包括子目录 
#注意变量名不要和其他CMake文件重复
file(GLOB_RECURSE math_header_files ${CMAKE_CURRENT_SOURCE_DIR}/*.h)

message(STATUS "mymath CMAKE_CURRENT_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR}")
message(STATUS "mymath math_src_files ${math_src_files}")
message(STATUS "mymath math_header_files ${math_header_files}")
add_library(mymath SHARED ${math_src_files} ${math_header_files})

由于linux下的库不需要像windows那样export所以作为动态库的时候，需要进行环境处理。
project/mymath/mymath.h

#pragma once

#ifdef _WIN32
	#ifdef MYPATH_EXPORT
		#define MYPATH_EXPORT_API extern "C" __declspec(dllexport)
	#else
		#define MYPATH_EXPORT_API extern "C" __declspec(dllimport)
	#endif
#else
	#define MYPATH_EXPORT_API 
#endif // _WIN32


MYPATH_EXPORT_API int add(int a,int b);

cmake ../ -DUSE_MYMATH=ON
cmake --build ./

本文参考:
CMake 教程,至于CMake的安装和测试将在下一章讲解。
CMake判断Release还是Debug环境

函数简单说明

对于CMake，可能存在两种函数：xxxxx和target_xxxx。下面以link_libraries和target_link_libraries来做讲解。
link_libraries：针对全局的，即：CMake的所有模块都会添加该库。
target_link_libraries：针对指定目标的，只有指定目标包含该库。
例如CMake包含连个目标A和B，此时如果通过link_libraries(ws2_32 test)包含ws2_32.lib和test.lib那么A和B都将包含这两个库。但是如果通过target_link_libraries(A PUBLIC ws2_32 test)那么此时仅仅目标A包含这两个库。

CAir2
关注
  • 1
    点赞
  • 踩
  • 11
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
++项目 cmake头文件路径_基于VSCode和CMake进行C/C++开发第六讲CMake
weixin_30569923的博客
01-09 798
6.0：本讲目录本系列视频，B站首发，up主: xiaobing1016前言：CMake是一个跨平台的安装编译工具，可以用简单的语句来描述所有平台的安装(编译过程)。CMake可以说已经成为大部分C++开源项目标配6.1 Cross-platform developmentLet’s assume you have some cross-platform project with C++...
CMake详解
热门推荐
u011150681的博客
12-20 1万+
什么是CMake 在android studio 2.2及以上，构建原生库的默认工具是 CMake。 CMake是一个跨平台的构建工具，可以用简单的语句来描述所有平台的安装(编译过程)。能够输出各种各样的makefile或者project文件。Cmake 并不直接建构出最终的软件，而是产生其他工具的脚本（如Makefile ），然后再依这个工具的构建方式使用。 CMake是一个比mak...
CMAKE
weixin_44020424的博客
09-01 61
CMake 是一个管理源代码构建的工具。最初，CMake 被设计为各种方言的生成器Makefile，如今 CMake 生成现代构建系统，以及NinjaVisual Studio 和 Xcode 等 IDE 的项目文件。CMake 广泛用于 C 和 C++ 语言，但它也可用于构建其他语言的源代码。第一次接触 CMake 的人可能有不同的初始目标。要了解如何构建从互联网下载的源代码包，请从User Interaction Guide。
Cmake在Visual Studio 2019中编译HM项目
最新发布
weixin_49007425的博客
07-03 468
1、在HM中新建build文件夹，在build文件夹中打开cmd或者在任意位置打开cmd进入build文件夹。2、输入命令cmake .. -G "Visual Studio 16 2019" -A x64。4、如果编译成功build文件夹中会生成一堆文件，如下图所示。3、如果使用的VS版本不同可自行调整命令。
一文读懂cmake
xingtianxia710的专栏
05-26 298
CMake - Cross Platform Makefile Generator
Professional CMake pdf
02-01
### 专业知识点：《Professional CMake》概览与核心概念 #### 一、CMake简介与背景 - **定义**：CMake是一款跨平台的自动构建系统，它使用一种简单的域特定语言（DSL）来描述软件编译流程，能够自动生成特定构建...
CMAKE 3.25 windows版本
11-30
CMake是一款跨平台的自动化构建系统，用于管理软件构建过程，尤其在C++项目中广泛应用。CMake 3.25是CMake的一个特定版本，它在先前版本的基础上进行了优化和增强，旨在提供更稳定、高效和功能丰富的构建环境。 在...
Cmake Cmake Cmake Cmake
08-21
cmake-3.24.0-rc5-windows-x86_64
cmake-3.14.0
04-08
安装cmake，若通过yum已经安装cmake,应该 卸载系统的低版本cmake yum remove cmake #卸载yum安装的版本，若无安装则忽略 cd /usr/local/src wget https://cmake.org/files/v3.14/cmake-3.14.0.tar.gz tar vzxf ...
CMake用法详解 使用方法说明
08-13
CMake 用法详解，简单描述了CMake 的使用方法，通过简单的例子
Cmake开发手册详解
10-18
公司的一个项目使用CMake作为跨平台构建工具；业务有需求，当然要好好研读一下官方的技术手册。目前的计划是先把官方手册翻译一下，了解清楚CMake中的各种命令、属性和变量的用法。同时在工作中也会阅读CMake的真实源码，后续会基于此陆续写一些工程中使用CMake的心得。CMake的版本也在不停更新，有些新的命令和变量会随着版本更新添加进来，这是后事了，暂且不管；现在锁定CMake 2.8.3作为手册翻译的版本。
CMake手册详解.pdf
08-08
有目录 CMake2.8.3 主索引 命令名称 用法 描述 命令选项 生成器 命令 属性 全局域属性 目录属性 目标属性 测试属性 源代码属性 Cache Entries属性 兼容性命令 CMake 标准模块 CMake策略 变量 改变行为的变量 描述系统的变量 语言变量 控制构建的变量 提供信息的变量 版权 其他参考资料
CMake手册详解[格式整理+带标签]
12-06
CMAKE,转自博客园大神翻译，可以作为工具书，且经过格式整理的，带标签的，非常方便查阅
CMake入门教程pdf
07-25
CMake入门教程 CMake是一个跨平台的安装（编译）工具，可以用简单的语句来描述所有平台的安装（编译过程）。它能够输出各种各样的makefile或者project文件，能测试编译器所支持的C++特性，类似UNIX下的automake。...
Cmake入门（一文读懂）_cmake 一文读懂
2401_84281712的博客
04-28 829
CMake是一个强大的跨平台构建工具，它能够自动生成用于构建项目的Makefile、Visual Studio项目文件或其他构建系统所需的文件。使用CMake，可以更轻松地管理复杂的C语言项目，使它们易于维护和跨平台。如果对Makefile不了解可以看此文章→Makefile入门。
Cmake 详解
禾刀白水
12-18 452
Cmake
Cmake 最通俗讲解
qq_45871272的博客
04-24 754
Cmake 最通俗讲解（一） Cmake写在一个叫做CMakeLists.txt的文件里面 1. 最基本的操作 为啥说是最基本的？作为小白，在很长一段时间内，使用这些函数就已经足够。如果你也是小白一枚，就可以在这停下去学习其他知识了（比如OpenCV）。 1.1 定义最低Cmake版本 #CMake的最低版本是3.0 #如果Cmake的版本低于3.0，那就无法形成Makefile cmake_m...
如何看懂cmakelist.txt文件
04-26
CMakeList.txt是CMake构建系统使用的文件之一，用于指定项目的构建规则和配置信息。它包含了项目的源代码文件、静态库、共享库等的信息，以及指定编译器和链接器等的信息。要理解CMakeList.txt文件，需要先了解CMake...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值