MySQL 源码｜50 - 语法解析(V2)：简单表达式（simple_expr）｜V20240910

最新推荐文章于 2024-09-11 08:25:50 发布
最新推荐文章于 2024-09-11 08:25:50 发布
阅读量920 收藏 13
点赞数 16
分类专栏： MySQL源码 文章标签： mysql 源码 语法解析 表达式
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/Changxing_J/article/details/142111215
版权

目录文档：MySQL 源码｜源码剖析文档目录

源码位置（版本 = MySQL 8.0.37）：sql/sql_yacc.yy

前置文档：

在此之前，我们已经梳理了字面值、标识符以及基础语法元素，下面我们来梳理解析基础表达式的 simple_expr 语义组，其中涉及的 symbol 及 symbol 之间的关系如下（图中绿色节点为字符串字面值涉及节点、蓝色节点为其他语义组、灰色节点为其他终结符）：

在这里插入图片描述

语义组：simple_expr
simple_expr:
    literal
  | identifier
  | function_call
  | simple_expr COLLATE collation_name
  | param_marker
  | variable
  | simple_expr || simple_expr
  | + simple_expr
  | - simple_expr
  | ~ simple_expr
  | ! simple_expr
  | BINARY simple_expr
  | (expr [, expr] ...)
  | ROW (expr, expr [, expr] ...)
  | (subquery)
  | EXISTS (subquery)
  | {identifier expr}
  | match_expr
  | case_expr
  | interval_expr
  • 返回值类型：Item 类（item），用于表示查询任何类型表达式的基类。
  • 使用场景：上一级表达式（predicate 语义组）
  • 备选规则和 Bison 语法：
备选规则规则含义
simple_ident解析 ident、ident.ident 或 ident.ident.ident，详见 MySQL 源码｜41 - 语法解析(V2)：标识符 IDENT
function_call_keyword解析使用 SQL 2003 规范中关键字作为函数名的函数，详见 MySQL 源码｜43 - 语法解析(V2)：关键字函数
function_call_nonkeyword解析非关键字函数，详见 MySQL 源码｜44 - 语法解析(V2)：非关键字函数
function_call_generic解析除关键字函数、非关键字函数、以及需为避免语法冲突专门处理的函数以外的其他通用函数，详见 MySQL 源码｜45 - 语法解析(V2)：通用函数
function_call_conflict解析避免语法冲突专门处理的函数，详见 MySQL 源码｜46 - 语法解析(V2)：为避免语法冲突专门处理的函数
simple_expr COLLATE_SYM ident_or_text通过 COLLATE 子句覆盖比较操作中的默认排序规则
literal_or_null解析通用字面值或空值字面值，详见 MySQL 源码｜48 - 语法解析(V2)：通用字面值
param_marker解析预编译语句中的占位符，详见 MySQL 源码｜66 - 语法解析(V2)：预编译表达式的参数值
rvalue_system_or_user_variable解析系统变量或用户变量
in_expression_user_variable_assignment解析用户变量赋值语句
set_function_specification解析聚集函数
window_func_call解析窗口函数，详见 MySQL 源码｜38 - 语法解析(V2)：窗口函数
'+' simple_expr解析使用了 + 前缀一元表达式的基础表达式
'-' simple_expr解析使用了 - 前缀一元表达式的基础表达式
'~' simple_expr解析使用了 ~ 前缀一元表达式的基础表达式
not2 simple_expr解析使用了 ! 前缀一元表达式（或 SQL_MODE 为 MODE_HIGH_NOT_PRECEDENCE 时的 NOT 关键字）的基础表达式
row_subquery解析单行子查询，详见 MySQL 源码｜47 - 语法解析(V2)：子查询
'(' expr ')'解析使用括号嵌套的一般表达式（最高级表达式）
ROW_SYM '(' expr ',' expr_list ')'解析 ROW 关键字引导的值列表
EXISTS table_subquery解析 EXISTS 关键字引导的多行子查询，详见 MySQL 源码｜47 - 语法解析(V2)：子查询
'{' ident expr '}'解析用于匹配 ODBC 日期的表达式
MATCH ident_list_arg AGAINST '(' bit_expr fulltext_options ')'用于解析 FULLTEXT 索引的全文搜索子句
BINARY_SYM simple_expr用于解析 BINARY 关键字引导的子句，详见 MySQL 源码｜49 - 语法解析(V2)：CAST、CONVERT 函数和 BINARY 关键字
CAST_SYM '(' expr AS cast_type opt_array_cast ')'用于解析 CAST 函数，详见 MySQL 源码｜49 - 语法解析(V2)：CAST、CONVERT 函数和 BINARY 关键字
CAST_SYM '(' expr AT_SYM LOCAL_SYM AS cast_type opt_array_cast ')'用于解析 CAST 函数，详见 MySQL 源码｜49 - 语法解析(V2)：CAST、CONVERT 函数和 BINARY 关键字
CAST_SYM '(' expr AT_SYM TIME_SYM ZONE_SYM opt_interval TEXT_STRING_literal AS DATETIME_SYM type_datetime_precision ')'用于解析 CAST 函数，详见 MySQL 源码｜49 - 语法解析(V2)：CAST、CONVERT 函数和 BINARY 关键字
CASE_SYM opt_expr when_list opt_else END用于解析 CASE 子句
CONVERT_SYM '(' expr ',' cast_type ')'用于解析 CONVERT 函数，详见 MySQL 源码｜49 - 语法解析(V2)：CAST、CONVERT 函数和 BINARY 关键字
CONVERT_SYM '(' expr USING charset_name ')'用于解析 CONVERT 函数，详见 MySQL 源码｜49 - 语法解析(V2)：CAST、CONVERT 函数和 BINARY 关键字
DEFAULT_SYM '(' simple_ident ')'用于解析 DEFAULT 函数
VALUES '(' simple_ident_nospvar ')'用于解析 VALUES 函数
INTERVAL_SYM expr interval '+' expr %prec INTERVAL_SYM用于解析 INTERVAL 关键字引导的时间长度
simple_ident JSON_SEPARATOR_SYM TEXT_STRING_literal用于解析 Json 格式数据提取语句
simple_ident JSON_UNQUOTED_SEPARATOR_SYM TEXT_STRING_literal用于解析 Json 格式数据提取语句
simple_expr:
          simple_ident
        | function_call_keyword
        | function_call_nonkeyword
        | function_call_generic
        | function_call_conflict
        | simple_expr COLLATE_SYM ident_or_text %prec NEG
          {
            warn_on_deprecated_user_defined_collation(YYTHD, $3);
            $$= NEW_PTN Item_func_set_collation(@$, $1, $3);
          }
        | literal_or_null
        | param_marker { $$= $1; }
        | rvalue_system_or_user_variable
        | in_expression_user_variable_assignment
        | set_function_specification
        | window_func_call
        | simple_expr OR_OR_SYM simple_expr
          {
            $$= NEW_PTN Item_func_concat(@$, $1, $3);
          }
        | '+' simple_expr %prec NEG
          {
            $$= $2; // TODO: do we really want to ignore unary '+' before any kind of literals?
            if ($$ != nullptr) $$->m_pos = @$;
          }
        | '-' simple_expr %prec NEG
          {
            $$= NEW_PTN Item_func_neg(@$, $2);
          }
        | '~' simple_expr %prec NEG
          {
            $$= NEW_PTN Item_func_bit_neg(@$, $2);
          }
        | not2 simple_expr %prec NEG
          {
            $$= NEW_PTN PTI_truth_transform(@$, $2, Item::BOOL_NEGATED);
          }
        | row_subquery
          {
            $$= NEW_PTN PTI_singlerow_subselect(@$, $1);
          }
        | '(' expr ')'
          {
            $$= $2;
            if ($$ != nullptr) $$->m_pos = @$;
          }
        | '(' expr ',' expr_list ')'
          {
            $$= NEW_PTN Item_row(@$, $2, $4->value);
          }
        | ROW_SYM '(' expr ',' expr_list ')'
          {
            $$= NEW_PTN Item_row(@$, $3, $5->value);
          }
        | EXISTS table_subquery
          {
            $$= NEW_PTN PTI_exists_subselect(@$, $2);
          }
        | '{' ident expr '}'
          {
            $$= NEW_PTN PTI_odbc_date(@$, $2, $3);
          }
        | MATCH ident_list_arg AGAINST '(' bit_expr fulltext_options ')'
          {
            $$= NEW_PTN Item_func_match(@$, $2, $5, $6);
          }
        | BINARY_SYM simple_expr %prec NEG
          {
            push_deprecated_warn(YYTHD, "BINARY expr", "CAST");
            $$= create_func_cast(YYTHD, @$, $2, ITEM_CAST_CHAR, &my_charset_bin);
            if ($$ == nullptr)
              MYSQL_YYABORT;
          }
        | CAST_SYM '(' expr AS cast_type opt_array_cast ')'
          {
            $$= create_func_cast(YYTHD, @$, $3, $5, $6);
            if ($$ == nullptr)
              MYSQL_YYABORT;
          }
        | CAST_SYM '(' expr AT_SYM LOCAL_SYM AS cast_type opt_array_cast ')'
          {
            my_error(ER_NOT_SUPPORTED_YET, MYF(0), "AT LOCAL");
          }
        | CAST_SYM '(' expr AT_SYM TIME_SYM ZONE_SYM opt_interval
          TEXT_STRING_literal AS DATETIME_SYM type_datetime_precision ')'
          {
            Cast_type cast_type{ITEM_CAST_DATETIME, nullptr, nullptr, $11};
            auto datetime_factor =
                NEW_PTN Item_func_at_time_zone(@3, $3, $8.str, $7);
            $$ = create_func_cast(YYTHD, @$, datetime_factor, cast_type, false);
            if ($$ == nullptr)
              MYSQL_YYABORT;
          }
        | CASE_SYM opt_expr when_list opt_else END
          {
            $$= NEW_PTN Item_func_case(@$, $3, $2, $4 );
          }
        | CONVERT_SYM '(' expr ',' cast_type ')'
          {
            $$= create_func_cast(YYTHD, @$, $3, $5, false);
            if ($$ == nullptr)
              MYSQL_YYABORT;
          }
        | CONVERT_SYM '(' expr USING charset_name ')'
          {
            $$= NEW_PTN Item_func_conv_charset(@$, $3,$5);
          }
        | DEFAULT_SYM '(' simple_ident ')'
          {
            $$= NEW_PTN Item_default_value(@$, $3);
          }
        | VALUES '(' simple_ident_nospvar ')'
          {
            $$= NEW_PTN Item_insert_value(@$, $3);
          }
        | INTERVAL_SYM expr interval '+' expr %prec INTERVAL_SYM
          /* we cannot put interval before - */
          {
            $$= NEW_PTN Item_date_add_interval(@$, $5, $2, $3, 0);
          }
        | simple_ident JSON_SEPARATOR_SYM TEXT_STRING_literal
          {
            Item_string *path=
              NEW_PTN Item_string(@3, $3.str, $3.length,
                                  YYTHD->variables.collation_connection);
            $$= NEW_PTN Item_func_json_extract(YYTHD, @$, $1, path);
          }
         | simple_ident JSON_UNQUOTED_SEPARATOR_SYM TEXT_STRING_literal
          {
            Item_string *path=
              NEW_PTN Item_string(@3, $3.str, $3.length,
                                  YYTHD->variables.collation_connection);
            Item *extr= NEW_PTN Item_func_json_extract(YYTHD, @$, $1, path);
            $$= NEW_PTN Item_func_json_unquote(@$, extr);
          }
        ;

JSON_SEPARATOR_SYM 终结符用于解析 -> 符号；

JSON_UNQUOTED_SEPARATOR_SYM 终结符用于解析 ->> 符号。

opt_expr 语义组用于解析可选的一般表达式（expr 语义组）。

语义组：rvalue_system_or_user_variable

rvalue_system_or_user_variable 语义组用于解析系统变量（@@ 开头）和用户变量（@ 开头）。

备选规则规则含义
'@' ident_or_text解析用户变量
'@' '@' opt_rvalue_system_variable_type rvalue_system_variable解析系统变量
rvalue_system_or_user_variable:
          '@' ident_or_text
          {
            $$ = NEW_PTN PTI_user_variable(@$, $2);
          }
        | '@' '@' opt_rvalue_system_variable_type rvalue_system_variable
          {
            $$ = NEW_PTN PTI_get_system_variable(@$, $3,
                                                 @4, $4.prefix, $4.name);
          }
        ;
语义组：opt_rvalue_system_variable_type

opt_rvalue_system_variable_type 语义组用于解析 GLOBAL 关键字、LOCAL 关键字或 SESSION 关键字。

  • 返回值类型：enum_var_type 枚举值（var_type），包含 OPT_DEFAULT、OPT_SESSION、OPT_GLOBAL、OPT_PERSIST 和 OPT_PERSIST_ONLY
  • Bison 语法如下：
opt_rvalue_system_variable_type:
          %empty          { $$=OPT_DEFAULT; }
        | GLOBAL_SYM '.'  { $$=OPT_GLOBAL; }
        | LOCAL_SYM '.'   { $$=OPT_SESSION; }
        | SESSION_SYM '.' { $$=OPT_SESSION; }
        ;
语义组：rvalue_system_variable

rvalue_system_variable 语义组用于解析 ident_or_text 或 ident_or_text.ident。

  • 返回值类型：LEX_STRING 结构体（lexer.lex_str）
  • Bison 语法如下：
rvalue_system_variable:
          ident_or_text
          {
            $$ = Bipartite_name{{}, to_lex_cstring($1)};
          }
        | ident_or_text '.' ident
          {
            // disallow "SELECT @@global.global.variable"
            if (check_reserved_words($1.str)) {
              YYTHD->syntax_error_at(@1);
              MYSQL_YYABORT;
            }
            $$ = Bipartite_name{to_lex_cstring($1), to_lex_cstring($3)};
          }
        ;

ident_or_text 语义组解析标识符、任意未保留关键字、单引号 / 双引号字符串或用户自定义变量；

ident 语义组解析标识符或任意未保留关键字。

语义组：in_expression_user_variable_assignment

in_expression_user_variable_assignment 语义组用于解析用户自定义变量的赋值语句。

in_expression_user_variable_assignment:
          '@' ident_or_text SET_VAR expr
          {
            push_warning(YYTHD, Sql_condition::SL_WARNING,
                         ER_WARN_DEPRECATED_SYNTAX,
                         ER_THD(YYTHD, ER_WARN_DEPRECATED_USER_SET_EXPR));
            $$ = NEW_PTN PTI_variable_aux_set_var(@$, $2, $4);
          }
        ;

SET_VAR 终结符解析 := 符号。

语义组：not2

not2 语义组用于匹配 ! 运算符或 SQL_MODE 开启了 HIGH_NOT_PRECEDENCE 时 NOT 关键字。

not2:
          '!' { push_deprecated_warn(YYTHD, "!", "NOT"); }
        | NOT2_SYM
        ;
语义组：ident_list_arg

ident_list_arg 语义组用于解析包含外层括号或不包含外层括号的标识符的、逗号分隔的、任意数量的标识符。

  • 返回值类型：PT_item_list 对象（item_list2）
  • 使用场景：MATCH 语句
  • Bison 语法如下：
ident_list_arg:
          ident_list          { $$= $1; }
        | '(' ident_list ')'  { $$= $2; }
        ;

语义组ident_list 用于解析使用逗号分隔的任意数量标识符，详见 MySQL 源码｜41 - 语法解析(V2)：标识符 IDENT。

语义组：fulltext_options

fulltext_options 语义组用于解析全文搜索的配置信息。

fulltext_options:
          opt_natural_language_mode opt_query_expansion
          { $$= $1 | $2; }
        | IN_SYM BOOLEAN_SYM MODE_SYM
          {
            $$= FT_BOOL;
            DBUG_EXECUTE_IF("simulate_bug18831513",
                            {
                              THD *thd= YYTHD;
                              if (thd->sp_runtime_ctx)
                                YYTHD->syntax_error();
                            });
          }
        ;

opt_natural_language_mode 语义组用于解析可选的 IN NATURAL LANGUAGE MODE；

opt_query_expansion 语义组用于解析可选的 WITH QUERY EXPANSION。

语义组：opt_natural_language_mode

opt_natural_language_mode 语义组用于解析可选的 IN NATURAL LANGUAGE MODE。

  • 返回值类型：int 类型（num）
  • Bison 语法如下：
opt_natural_language_mode:
          %empty { $$= FT_NL; }
        | IN_SYM NATURAL LANGUAGE_SYM MODE_SYM  { $$= FT_NL; }
        ;
语义组：opt_query_expansion

opt_query_expansion 语义组用于解析可选的 WITH QUERY EXPANSION。

  • 返回值类型：int 类型（num）
  • Bison 语法如下：
opt_query_expansion:
          %empty { $$= 0;         }
        | WITH QUERY_SYM EXPANSION_SYM          { $$= FT_EXPAND; }
        ;
语义组：when_list

when_list 语义组用于解析 CASE 子句中任意数量的 WHEN {expr} THEN {expr} 子句。

when_list:
          WHEN_SYM expr THEN_SYM expr
          {
            $$= new (YYMEM_ROOT) mem_root_deque<Item *>(YYMEM_ROOT);
            if ($$ == nullptr)
              MYSQL_YYABORT;
            $$->push_back($2);
            $$->push_back($4);
          }
        | when_list WHEN_SYM expr THEN_SYM expr
          {
            $1->push_back($3);
            $1->push_back($5);
            $$= $1;
          }
        ;
语义组：opt_else

opt_else 语义组用于解析可选的 ELSE {expr} 子句。

opt_else:
          %empty       { $$= nullptr; }
        | ELSE expr    { $$= $2; }
        ;
语义组：set_function_specification

set_function_specification 语义组用于解析聚集函数和 GROUPING 函数超聚合结果。

  • 返回值类型：Item 类（item），用于表示查询任何类型表达式的基类。
  • Bison 语法如下：
set_function_specification:
          sum_expr
        | grouping_operation
        ;

sum_expr 语义组用于解析既是窗口函数，又是聚集函数的函数，详见 MySQL 源码｜37 - 语法解析(V2)：聚集函数。

语义组：grouping_operation

grouping_operation 语义组用于解析 GROUPING() 函数超聚合结果。

  • 返回值类型：Item 类（item），用于表示查询任何类型表达式的基类。
  • Bison 语法如下：
grouping_operation:
          GROUPING_SYM '(' expr_list ')'
          {
            $$= NEW_PTN Item_func_grouping(@$, $3);
          }
        ;
长行
关注
  • 16
    点赞
  • 踩
  • 13
    收藏
    觉得还不错? 一键收藏
  • 打赏
    打赏
  • 0
    评论
专栏目录
庖丁解牛｜图解 MySQL 8.0 优化器查询转换篇
阿里云云栖号
10-19 1044
简介：本篇介绍子查询、分析表和JOIN的复杂转换过程 一 背景和架构 在《庖丁解牛-图解MySQL 8.0优化器查询解析篇》一文中我们重点介绍了MySQL最新版本8.0.25关于SQL基本元素表、列、函数、聚合、分组、排序等元素的解析、设置和转换过程，本篇我们继续来介绍更为复杂的子查询、分区表和JOIN的复杂转换过程，大纲如下： Transformation remove_redundant_subquery_clause :Permanently remove redundant parts ..
xmljava系统源码-fin-expr:Java的表达式计算器。专注精准，可用于金融系统
06-06
java系统源码 FinExpr: an expression evaluator (support custom functions and variables) FinExpr: 一个表达式计算工具（支持添加自定义函数和变量） Brief introduction FinExpr is an expression evaluator ...
MySQL 源码｜69 - 语法解析(V2)：位表达式（bit_expr）｜V20240911
长行
09-11 166
在梳理了简单表达式语义组后，我们继续梳理比高级一层的bit_expr。
MySQL 源码｜70 - 语法解析(V2)：谓语表达式（predicate）｜V20240911
最新发布
长行
09-11 240
在梳理了简单表达式语义组和位表达式bit_expr后，我们继续梳理比bit_expr高级一层的predicate。
MySQL 源码｜38 - 语法解析(V2)：窗口函数｜V20240908
长行
09-08 2142
MySQL 解析窗口函数时，根据该函数是否同时为聚集函数，分为sum_expr语义组（针对同时也是聚集函数的窗口函数）和语义组（针对不是聚集函数的窗口函数）。在本节中，我们首先来梳理。
MySQL 源码｜66 - 语法解析(V2)：预编译表达式的参数值｜V20240905
长行
09-05 360
根据中梳理的 MySQL 词法解析逻辑，终结符用于匹配预处理语句中的占位符。下面我们通过使用了该终结符的语义组出发，梳理预处理语句的占位符。
MySQL 源码｜43 - 语法解析(V2)：关键字函数｜V20240908
长行
09-08 791
MySQL 解析函数时，根据函数名是否为关键字、是否可能引起冲突等，拆分为和这 4 个语义组。在本节中，我们首先来梳理。
MySQL 源码｜49 - 语法解析(V2)：CAST、CONVERT 函数和 BINARY 关键字｜V20240910
长行
09-10 310
在基础表达式语义组中，直接规定了类型转换函数CASTCONVERT和关键字BINARY引导的类型转换语法的备选规则，这 3 个函数官方文档和标准语法详见。在梳理。
01mysql
monkey的博客
12-29 2339
--------笔记1--------- 一. MySQL基础篇 (一) Linux(CentOS 7)安装MySQL 5.6 卸载 1 查看MySQL软件 rpm -qa|grep mysql yum repolist all | grep mysql 2 卸载 yum remove -y mysql mysql-libs mysql-common #卸载mysql rm -rf /var/lib/mysql #删除mysql下的数据文件 rm /etc/my.cnf #删除mysql配置文件
庖丁解牛-图解MySQL 8.0优化器查询转换篇
阿里云云栖号
09-18 941
简介：在《庖丁解牛-图解MySQL 8.0优化器查询解析篇》一文中我们重点介绍了MySQL最新版本8.0.25关于SQL基本元素表、列、函数、聚合、分组、排序等元素的解析、设置和转换过程，本篇我们继续来介绍更为复杂的子查询、分区表和JOIN的复杂转换过程。 作者 | 道客 来源 | 阿里技术公众号 一 背景和架构 在《庖丁解牛-图解MySQL 8.0优化器查询解析篇》一文中我们重点介绍了MySQL最新版本8.0.25关于SQL基本元素表、列、函数、聚合、分组、排序等元素的解析、设置和转换过程，本.
ExprEval.rar_ExprEval_java 计算器_java表达式运算_jep-3.1.0-trial.jar_表达式
09-21
Java表达式运算的核心在于表达式解析器。在提供的"jep-3.1.0-trial.jar"中，JEP（Java Expression Parser）是一个强大的库，用于解析和求值数学表达式。JEP库提供了API，开发者可以通过这些接口来构建、解析和评估...
str-expr.zip_STR_expr_visual c_表达式计算
09-21
表达式计算源代码
mysql用时间戳还是时间存储比较好
qq_42572322的博客
09-05 503
TIMESTAMP 通常占用的空间比 DATETIME 少，如果你对存储空间有限制，或者你需要存储大量的时间戳数据，TIMESTAMP 可能是更好的选择。- 如果你的应用需要在不同的时区中使用时间数据，或者需要自动处理夏令时的变化，使用 TIMESTAMP 可能更方便。- 考虑到不同的数据库系统和应用程序可能对时间类型的支持不同，选择一个能够满足你当前和未来需求的时间类型是很重要的。- 对于需要频繁进行日期和时间范围查询的场景，DATETIME 类型可能更适合，因为它允许更灵活的日期和时间计算。
MySQL表操作及约束
2301_77479435的博客
09-06 1045
MySQL表操作及约束
MySQL的 where 1=1会不会影响性能
ning的博客
09-07 568
通过分析和实验，我们可以得出结论：在现代的MySQL版本中，使用where 1=1并不会对查询性能产生显著影响，因为MySQL的优化器会对其进行常量折叠优化。然而，选择最合适的方法还需要考虑你的具体使用场景和ORM框架。在任何情况下，编写清晰、可维护的代码始终是最重要的。版权声明：本博客内容为原创，转载请保留原文链接及作者信息。参考文章MySQL中where 1=1真的会影响性能么？MySQL的 where 1=1会不会影响性能？看完官方文档就悟了！
mysql的整理
weixin_71113035的博客
09-05 344
插入数据、修改数据、删除数据、SQL语句的执行顺序、外键、多表查询、分类（内连接等）、存储引擎、SQL的性能分析
数据库运维实操优质文章文档分享（含Oracle、MySQL等） | 2024年8月刊
Era666的博客
09-10 1304
本文为大家整理了墨天轮数据社区2024年8月发布的优质技术文章、文档，主题涵盖Oracle、MySQL、PostgreSQL等主流数据库系统以及国产数据库的技术实操！
MySQL 大量 IN 的查询优化
xchenhao 的博客
09-09 388
MySQL 大量 IN 的查询优化
error: C2780: “unknown-type std::invoke(_Callable &&) noexcept(<expr>)”: 应输入 1 个参数，却提供了 8 个
05-26
这个错误通常是因为你在使用 `std::invoke` 的时候传递了错误的参数。`std::invoke` 的第一个参数应该是一个可调用的对象（比如函数指针、成员函数指针、重载函数对象等），后面的参数是用于调用这个可调用对象的参数。请检查你的代码，看看是否有参数传递错误的情况。如果你需要更详细的帮助，请提供更多的代码信息。
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

长行

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值