VBA 用户窗体的应用（二）

今天继续讲用户窗体的应用啦.

一、文字版进度条

昨天的进度条都是现实长度的那种进度条，有时候安装或者卸载文件，我们会发现有个文字型滴进度条，如何实现呢？

Sub processFile()
    Dim sFile As String, lfile As String
    Dim path As String
    Dim i As Integer
    path = "E:\新建文件夹\达拉崩吧\黑白\"
    
    sFile = Dir(path)
    
    UserForm1.Caption = "处理中……"
    UserForm1.Show 0
    
    Do While sFile <> ""
        With UserForm1.ListBox1
            .AddItem sFile & "已完成"
            .TopIndex = Application.Max(.ListCount, .ListCount - 6)
        End With
        sFile = Dir
    Loop
    
    UserForm1.Caption = "已处理完成"
    
End Sub

二、创建向导

要创建这样一个向导，需要怎么做呢？

Private Sub cmdBack_Click()

    Me.MultiPage1.Value = Me.MultiPage1.Value - 1
    Me.cmdFor.Enabled = True
    
    If Me.MultiPage1.Value = 0 Then
        Me.cmdBack.Enabled = False
    End If
End Sub

Private Sub cmdExit_Click()
    Unload Me
End Sub

Private Sub cmdFor_Click()
    Me.MultiPage1.Value = Me.MultiPage1.Value + 1
    Me.cmdBack.Enabled = True
    
    If Me.MultiPage1.Value = 2 Then
        Me.cmdFor.Enabled = False
    End If
End Sub

Private Sub cmdOk_Click()
    Dim str As String
    Dim gender As String
    
    If Me.optNan.Value Then gender = "男"
    If Me.optNv.Value Then gender = "女"
    str = "你的名字是：" & Me.txtName.Text & vbNewLine & _
        "你的性别是：" & gender & vbNewLine & _
        "你的地址是：" & Me.txtAddr.Text
    MsgBox str
End Sub

Private Sub UserForm_Initialize()
    With Me.MultiPage1
        .Style = fmTabStyleNone
        .Value = 0
    End With
    Me.cmdBack.Enabled = False
End Sub

明天继续~