East_MrChiu的笔记本

天下难事,必作于易;天下大事,必作于细。

【Oracle】PL/SQL——异常错误处理


异常情况处理(EXCEPTION) 是用来处理正常执行过程中未预料的事件, 程序块的异常处理预定义的错误 和 自定义错误, 由于 PL/SQL 程序块一旦产 生异常而没有指出如何处理时, 程序就会自动终止整个程序运行.

异常错误可以分为三种类型:

1)预定义异常

2)非预定义异常

3)用户自定义异常

这里进行分别说明

预定义异常处理



例子:

SET SERVEROUTPUT ON

DECLARE 
    V_SAL EMPLOYEES.SALARY%TYPE;

BEGIN
	SELECT E.SALARY INTO V_SAL FROM EMPLOYEES E WHERE E.DEPARTMENT_ID = 100;
	DBMS_OUTPUT.put_line(V_SAL);
	
EXCEPTION
	--预定义异常
	WHEN TOO_MANY_ROWS THEN DBMS_OUTPUT.put_line('得到的行数太多了!');
        WHEN OTHERS THEN DBMS_OUTPUT.put_line('出现其他类型错误!');
END;
/  
结果:

非预定义异常处理

首先必须对非定义的 ORACLE 错误进行定义。步骤如下:

1. 在 在 PL/SQL 块的定义部分定义异常情况:

      <异常情况> EXCEPTION;

2. 将其定义好的异常情况,与标准的 ORACLE 错误联系起来,使用 PRAGMA EXCEPTION_INIT 语句:

      PRAGMA EXCEPTION_INIT(< 异常情况>, < 错误代码>);

3. 在PL/SQL 块的异常处理部分对异常情况做出相应处理。

例子:

SET SERVEROUTPUT ON

DECLARE 
    E_DELETEID_EXCEPTION EXCEPTION;
    PRAGMA EXCEPTION_INIT(E_DELETEID_EXCEPTION, -02292);

BEGIN
    DELETE FROM EMPLOYEES E WHERE E.EMPLOYEE_ID = 100;

EXCEPTION
     --非预定义异常
    WHEN E_DELETEID_EXCEPTION THEN DBMS_OUTPUT.put_line('违反完整约束条件!不可删除此用户。');
    WHEN OTHERS THEN DBMS_OUTPUT.put_line('出现其他类型错误!');
END;
/  

用户自定义异常处理

当与一个异常错误相关的错误出现时,就会隐含触发该异常错误。 用户定义的异常错误是通过显式使用 RAISE 语句来触发。当引发一个异常错误时,控制就转向EXCEPTION 块异常错误部分,执行错误处理代码。

对于这类异常情况的处理,步骤如下:

1. 在 在 PL/SQL 块的定义部分定义异常情况:

     < 异常情况> EXCEPTION;

2. RAISE < 异常情况>;

3. 在 PL/SQL 块的异常情况处理部分对异常情况做出相应的处理。

例子:

SET SERVEROUTPUT ON

DECLARE 
    E_TOO_LOW_SAL EXCEPTION;		
    V_SAL EMPLOYEES.SALARY%TYPE;

BEGIN
    SELECT E.SALARY INTO V_SAL FROM EMPLOYEES E WHERE E.EMPLOYEE_ID = 140;
	
    IF V_SAL < 10000 THEN
        RAISE E_TOO_LOW_SAL;
    END IF;

EXCEPTION
    --用户自定义异常
    WHEN E_TOO_LOW_SAL THEN DBMS_OUTPUT.put_line('用户工资低于10000。');
    WHEN OTHERS THEN DBMS_OUTPUT.put_line('出现其他类型错误!');
END;
/  



阅读更多
版权声明:本文为博主原创文章,未经博主允许不得转载。 https://blog.csdn.net/East_MrChiu/article/details/70196345
个人分类: 数据库
想对作者说点什么? 我来说一句

ORACLE 异常错误处理

2012年03月02日 68KB 下载

没有更多推荐了,返回首页

不良信息举报

【Oracle】PL/SQL——异常错误处理

最多只允许输入30个字

加入CSDN,享受更精准的内容推荐,与500万程序员共同成长!
关闭
关闭