{题解}[jzoj1298]牛棚(graze2.pas/c/cpp)

jzoj1298

Description

FJ有N(2<=N<=1,500)头牛编号为1到N,FJ新盖了S(N<=S<=1,000,000)个牛棚，编号为1到S，S个牛棚排成一排，相邻牛棚距离为1。
每个牛棚只能住一头牛，每头牛都选择了一个牛棚P_i来休息，当两头牛离得太近时就会变得很暴躁，FJ想移动一些牛到其他牛棚使得他们之间的间距尽可能大，同时FJ又希望这N-1个间距尽可能相似。
具体一点说，FJ希望所有间距与(S-1)DIV(N-1)最多相差1，而且希望这N-1个间距尽可能多的等于(S-1)DIV(N-1)。例如4个牛住8个牛棚，可以有以下方案：1,3,5,8或1,3,6,8，但1,2,4,7或1,2,4,8是不符合要求的。
帮助FJ用最少的移动距离满足要求。

真没什么必要化简

Idea

考虑DP，计算当前的点，并以此转移
首先定义
$D=(S-1)DIV(N-1)$
Tips:题目中
均指间距大于等于D小于等于(D+1)，
坑了不看样例解释的同学

稍加思索，我们发现
对于这样的
InitStall:| A | C | E | . | . | . | . | D | B | . |
FinalStall:| A | . | C | . | E | . | . | D | . | B |
是优于
FinalStall①:| B | . | C | . | E | . | . | A | . | D |
FinalStall②:| C | . | E | . | A | . | . | D | . | B |
FinalStall③:| E | . | C | . | D | . | . | A | . | B |
… …
(自行理解)
也就是说，
我们可以对InitStall排序
设f[i,j]为计算到第i头牛的位置，
在前(i-1)个间距中，有j个长度为(D+1)的，(i-j-1)个长度为D)的，
最少移动距离

于是我们就可以计算第i个点了，设它的位置为T
那么$T=j*(d+1)+(i-j-1)*d+1$
通过这个可推出方程
$f_{i,j}=min(f_{i-1,j-1}+|T-p_i|,f_{i,j-1}+|T-p_i|)$
Tips:记得简化式子哦~

Code

//By white_elephant
var a:Array[1..1500]of longint;
    f:Array[1..1500,-1..1500]of longint;
    D,n,i,j,x,s,y,l:longint;
procedure swap(var a,b:longint);
    var c:longint;
begin
    c:=a; a:=b; b:=c;
end;
procedure qsort(h,t:longint);
    var l,r,m:longint;
begin
    l:=h; r:=t;
    m:=a[(h+t)>>1];
    repeat
        while a[l]<m do inc(l);
        while m<a[r] do dec(r);
        if l<=r then
        begin
            swap(a[l],a[r]);
            inc(l); dec(r);
        end;
    until l>r;
    if h<r then qsort(h,r);
    if l<t then qsort(l,t);
end;
function min(p,q:longint):longint;
begin
    if p<q then exit(p) else exit(q);
end;
begin
    assign(input,'graze2.in'); reset(input);
    assign(output,'graze2.out'); rewrite(output);
    read(n,s);
    for i:=1 to n do read(a[i]);
    qsort(1,n);
    fillchar(f,sizeof(f),$7f);
    f[1,0]:=a[1]-1;
    x:=(s-1)div(n-1);
    y:=(s-1)mod(n-1);
    for i:=2 to n do
    begin
        s:=min(i-1,y);
        f[i,0]:=f[i-1,0]+abs(a[i]-i*x+x-1);
        for j:=1 to s do f[i,j]:=min(f[i-1,j-1],f[i-1,j])+abs(a[i]-i*x+x-j-1);
    end;
    writeln(f[n,y]);
    close(output); close(input);
end.