【NOIP2016提高A组模拟9.3】树塔狂想曲

版权声明:巴不得你们co呢~ https://blog.csdn.net/Fate_Zero_Saber/article/details/52432269

题目

Description

相信大家都在长训班学过树塔问题,题目很简单求最大化一个三角形数塔从上往下走的路径和。走的规则是:(i,j)号点只能走向(i+1,j)或者(i+1,j+1)。如下图是一个数塔,映射到该数塔上行走的规则为:从左上角的点开始,向下走或向右下走直到最底层结束。

   1
   3 8
   2 5 0
   1 4 3 8
   1 4 2 5 0

   路径最大和是1+8+5+4+4 = 22,1+8+5+3+5 = 22或者1+8+0+8+5 = 22。

   小S觉得这个问题so easy。于是他提高了点难度,他每次ban掉一个点(即规定哪个点不能经过),然后询问你不走该点的最大路径和。
   当然他上一个询问被ban掉的点过一个询问会恢复(即每次他在原图的基础上ban掉一个点,而不是永久化的修改)。

Input

第一行包括两个正整数,N,M,分别表示数塔的高和询问次数。
以下N行,第i行包括用空格隔开的i - 1个数,描述一个高为N的数塔。
而后M行,每行包括两个数X,Y,表示第X行第Y列的数塔上的点被小S ban掉,无法通行。
(由于读入数据较大,c或c++请使用较为快速的读入方式)

Output

M行每行包括一个非负整数,表示在原图的基础上ban掉一个点后的最大路径和,如果被ban掉后不存在任意一条路径,则输出-1。

Sample Input

5 3
1
3 8
2 5 0
1 4 3 8
1 4 2 5 0
2 2
5 4
1 1

Sample Output

17
22
-1
【样例解释】

第一次是
1
3 X
2 5 0
1 4 3 8
1 4 2 5 0
1+3+5+4+4 = 17 或者 1+3+5+3+5=17
第二次:
1
3 8
2 5 0
1 4 3 8
1 4 2 X 0
1+8+5+4+4 = 22
第三次:你们都懂的!无法通行,-1!

Data Constraint
这里写图片描述

比赛时の想法

这题还是十分简单的,设f[i,j]为从第一层走到位置(i,j)可以获得的最大分数。g[i,j]为从最下面一层走到位置(i,j)可以获得的分数,那么经过位置(i,j)可以获得的分数就是f[i,j]+g[i,j]-a[i,j](a[i,j]表示这个位置的权值),那么每一行我们找到一个最大值和次大值并记录下它们的位置,询问的时候就可以以O(1)的时间解决问题了

贴代码

var
    a,f,g:array[0..1005,0..1005]of longint;
    s,t:array[0..1005,1..2]of longint;
    i,j,k,l,m,n,x,y:longint;
function max(x,y:longint):longint;
begin
    if x>y then exit(x) else exit(y);
end;
begin
   // assign(input,'t2.in'); reset(input);
    readln(n,m);
    for i:=1 to n do
    begin
        for j:=1 to i do read(a[i,j]);
        readln;
    end;
    f[1,1]:=a[1,1];
    for i:=2 to n do
        for j:=1 to i do f[i,j]:=max(f[i-1,j-1],f[i-1,j])+a[i,j];
    for i:=1 to n do g[n,i]:=a[n,i];
    for i:=n-1 downto 1 do
        for j:=1 to i do g[i,j]:=max(g[i+1,j],g[i+1,j+1])+a[i,j];
    for i:=2 to n do
    for j:=1 to i do
    begin
        if g[i,j]+f[i,j]-a[i,j]>s[i,1] then
        begin
            s[i,2]:=s[i,1];
            t[i,2]:=t[i,1];
            s[i,1]:=g[i,j]+f[i,j]-a[i,j];
            t[i,1]:=j;
        end else
        if g[i,j]+f[i,j]-a[i,j]>s[i,2] then
        begin
            s[i,2]:=g[i,j]+f[i,j]-a[i,j];
            t[i,2]:=j;
        end;
    end;
    for i:=1 to m do
    begin
        readln(x,y);
        if (x=1) and (y=1) then
        begin
            writeln(-1);
            continue;
        end;
        if t[x,1]=y then writeln(s[x,2]) else writeln(s[x,1]);
    end;
    //close(input);
end.
展开阅读全文

没有更多推荐了,返回首页