Review-动态树(Bzoj2049)

2049: [Sdoi2008]Cave 洞穴勘测

Time Limit: 10 Sec   Memory Limit: 259 MB
Submit: 3398   Solved: 1550
[ Submit][ Status]

Description

辉辉热衷于洞穴勘测。某天，他按照地图来到了一片被标记为JSZX的洞穴群地区。经过初步勘测，辉辉发现这片区域由n个洞穴（分别编号为1到n）以及若干通道组成，并且每条通道连接了恰好两个洞穴。假如两个洞穴可以通过一条或者多条通道按一定顺序连接起来，那么这两个洞穴就是连通的，按顺序连接在一起的这些通道则被称之为这两个洞穴之间的一条路径。洞穴都十分坚固无法破坏，然而通道不太稳定，时常因为外界影响而发生改变，比如，根据有关仪器的监测结果，123号洞穴和127号洞穴之间有时会出现一条通道，有时这条通道又会因为某种稀奇古怪的原因被毁。辉辉有一台监测仪器可以实时将通道的每一次改变状况在辉辉手边的终端机上显示：如果监测到洞穴u和洞穴v之间出现了一条通道，终端机上会显示一条指令 Connect u v 如果监测到洞穴u和洞穴v之间的通道被毁，终端机上会显示一条指令 Destroy u v 经过长期的艰苦卓绝的手工推算，辉辉发现一个奇怪的现象：无论通道怎么改变，任意时刻任意两个洞穴之间至多只有一条路径。因而，辉辉坚信这是由于某种本质规律的支配导致的。因而，辉辉更加夜以继日地坚守在终端机之前，试图通过通道的改变情况来研究这条本质规律。然而，终于有一天，辉辉在堆积成山的演算纸中崩溃了……他把终端机往地面一砸（终端机也足够坚固无法破坏），转而求助于你，说道：“你老兄把这程序写写吧”。辉辉希望能随时通过终端机发出指令 Query u v，向监测仪询问此时洞穴u和洞穴v是否连通。现在你要为他编写程序回答每一次询问。已知在第一条指令显示之前，JSZX洞穴群中没有任何通道存在。

Input

第一行为两个正整数n和m，分别表示洞穴的个数和终端机上出现过的指令的个数。以下m行，依次表示终端机上出现的各条指令。每行开头是一个表示指令种类的字符串s（"Connect”、”Destroy”或者”Query”，区分大小写），之后有两个整数u和v (1≤u, v≤n且u≠v) 分别表示两个洞穴的编号。

Output

对每个Query指令，输出洞穴u和洞穴v是否互相连通：是输出”Yes”，否则输出”No”。（不含双引号）

Sample Input

样例输入1 cave.in
200 5
Query 123 127
Connect 123 127
Query 123 127
Destroy 127 123
Query 123 127
样例输入2 cave.in

3 5
Connect 1 2
Connect 3 1
Query 2 3
Destroy 1 3
Query 2 3

Sample Output

样例输出1 cave.out
No
Yes
No


样例输出2 cave.out

Yes
No

HINT

数据说明 10%的数据满足n≤1000, m≤20000 20%的数据满足n≤2000, m≤40000 30%的数据满足n≤3000, m≤60000 40%的数据满足n≤4000, m≤80000 50%的数据满足n≤5000, m≤100000 60%的数据满足n≤6000, m≤120000 70%的数据满足n≤7000, m≤140000 80%的数据满足n≤8000, m≤160000 90%的数据满足n≤9000, m≤180000 100%的数据满足n≤10000, m≤200000 保证所有Destroy指令将摧毁的是一条存在的通道本题输入、输出规模比较大，建议c\c++选手使用scanf和printf进行I\O操作以免超时

Ps：动态树模板题，复习用。

Code：

program pro;
const
    maxn=30000;
type point=record l,r,fa,pp,data:longint; bj:boolean; end;
var
    node:array[0..maxn]of point;
    pos:array[0..maxn]of longint;
    tot,n,m:longint;
 
procedure swap(var x,y:longint);
var
    k:longint;
begin
    k:=x; x:=y; y:=k;
end;
 
procedure normal(x:longint);
begin
    if node[x].bj then
    begin
        node[x].bj:=false;
        node[node[x].l].bj:=not node[node[x].l].bj;
        node[node[x].r].bj:=not node[node[x].r].bj;
        swap(node[x].l,node[x].r);
    end;
end;
 
procedure left(x:longint);
var
    fa:longint;
begin
    fa:=node[x].fa;
    node[x].pp:=node[fa].pp; node[fa].pp:=0; node[fa].r:=node[x].l;
    if node[x].l>0 then node[node[x].l].fa:=fa;//!!
    node[x].fa:=node[fa].fa;
    if node[fa].fa>0 then
    begin
            if fa=node[node[fa].fa].l then node[node[fa].fa].l:=x
            else node[node[fa].fa].r:=x;
    end;
    node[fa].fa:=x;
    node[x].l:=fa;
end;
 
procedure right(x:longint);
var
    fa:longint;
begin
    fa:=node[x].fa;
    node[x].pp:=node[fa].pp; node[fa].pp:=0; node[fa].l:=node[x].r;
    if node[x].r>0 then node[node[x].r].fa:=fa;//!!
    node[x].fa:=node[fa].fa;
    if node[fa].fa>0 then
    begin
        if fa=node[node[fa].fa].l then node[node[fa].fa].l:=x
        else node[node[fa].fa].r:=x;
    end;
    node[fa].fa:=x;
    node[x].r:=fa;
end;
 
procedure splay(x:longint);
var
    fa:longint;
begin
    while node[x].fa>0 do
    begin
        fa:=node[x].fa;
        normal(fa);
        if node[fa].l>0 then normal(node[fa].l);
        if node[fa].r>0 then normal(node[fa].r);
        if x=node[fa].l then right(x) else left(x);
    end;
end;
 
procedure access(x:longint);
var
    fa,real:longint;
begin
    splay(x);
    normal(x);
    fa:=node[x].r;
    node[x].r:=0;
    node[fa].fa:=0; node[fa].pp:=x;
 
    fa:=node[x].pp;
    while fa>0 do
    begin
        splay(fa);
        normal(fa);
        real:=node[fa].r;
        node[fa].r:=x;
        node[real].fa:=0; node[real].pp:=fa;
        node[x].fa:=fa; node[x].pp:=0;
        x:=fa;
        fa:=node[x].pp;
    end;
    splay(x);
end;
 
procedure evert(x:longint);
begin
    access(x);
    splay(x);
    node[x].bj:=not node[x].bj;
    normal(x);
end;
 
procedure link(x,y:longint);
begin
    evert(x); //!!
    splay(x);
    normal(x);
    access(y);
    splay(y);
    normal(y);
    node[x].l:=y;
    node[y].fa:=x;
end;
 
procedure cut(x,y:longint);
begin
    evert(x);
    access(y);
    splay(y);
    normal(y);
    node[node[y].l].fa:=0;
    node[y].l:=0;
end;
 
function getroot(x:longint):longint;
begin
    access(x);
    splay(x);
    normal(x);
    while (node[x].l>0) do x:=node[x].l;
    splay(x);
    exit(x);
end;
 
procedure maketree(x:longint);
var
    now,i:longint;
begin
    inc(tot); now:=tot;
    pos[x]:=now;
    with node[x] do
    begin
        l:=0; r:=0; fa:=0; pp:=0; data:=x;
    end;
end;
 
procedure main;
var
    i,j,u,v:longint;
    ch:char;
begin
    readln(n,m);
    tot:=0;
    fillchar(pos,sizeof(pos),0);
    for i:=1 to n do maketree(i);
    for i:=1 to m do
    begin
        read(ch);
        case ch of
        'C':
        begin
            for j:=1 to 7 do read(ch);
            readln(u,v);
            link(pos[u],pos[v]);
        end;
        'D':
        begin
            for j:=1 to 7 do read(ch);
            readln(u,v);
            cut(pos[u],pos[v]);
        end;
        'Q':
        begin
            for j:=1 to 5 do read(ch);
            readln(u,v);
            u:=node[getroot(u)].data; v:=node[getroot(v)].data;
            if u=v then writeln('Yes') else writeln('No');
        end;
        end;
    end;
end;
 
begin
    main;
end.