【NOIP提高组】整除

Description

麦克雷有一个1~n的排列，他想知道对于一些区间，有多少对区间内的数（x，y），满足x能被y整除。

Solution

比赛的时候敲了个莫队，然后用了巧妙的统计方法，在较短时间内处理出答案，成功水到了80分，看了正解后发现只要把莫队改成树状数组统计就可以啦。令 X = [1, R] 的合法对数减去 [1, L - 1] 的合法对数，Y = 一个数属于 [1, L - 1] 另一个数属于 [L, R] 的合法对数，那么答案就是 X - Y。我们先将询问按右端点升序排序，并按原序列顺序从 1 往 n 做，每做到一个位置，便在它左边的数中与它有倍数关系的数的位置加一。用树状数组表示的是第$i$个数从$i$位置到当前右边界的贡献（贡献是指 i <script type="math/tex" id="MathJax-Element-255">i</script>位置倍数在区间的数的个数），那么每当我们遇到一个右端点与当前做的位置相同时，就可以直接将当前总共加的次数减去起点到左端点的区间的和，用树状数组区间求和的功能算出答案。因为维护是单向的，所以要正向反向各做一遍。

Code

var
    x,y,a,t,s,h,ans:array[0..200000] of longint;
    n,m,i,j,z,sum:longint;
procedure qsort(l,r:longint);
var i,j,mid:longint;
begin
    i:=l;j:=r;
    mid:=y[(l+r)div 2];
    repeat
        while y[i]<mid do inc(i);
        while mid<y[j] do dec(j);
        if i<=j then
        begin
            x[0]:=x[i];x[i]:=x[j];x[j]:=x[0];
            y[0]:=y[i];y[i]:=y[j];y[j]:=y[0];
            h[0]:=h[i];h[i]:=h[j];h[j]:=h[0];
            inc(i); dec(j);
        end;
    until i>j;
    if i<r then qsort(i,r);
    if l<j then qsort(l,j);
end;
procedure qsort1(l,r:longint);
var i,j,mid:longint;
begin
    i:=l;j:=r;
    mid:=x[(l+r)div 2];
    repeat
        while x[i]<mid do inc(i);
        while mid<x[j] do dec(j);
        if i<=j then
        begin
            x[0]:=x[i];x[i]:=x[j];x[j]:=x[0];
            y[0]:=y[i];y[i]:=y[j];y[j]:=y[0];
            h[0]:=h[i];h[i]:=h[j];h[j]:=h[0];
            inc(i); dec(j);
        end;
    until i>j;
    if i<r then qsort1(i,r);
    if l<j then qsort1(l,j);
end;
function lowbit(x:longint):longint;
begin
    exit(x and (-x));
end;
procedure add(x:longint);
begin
    repeat
        inc(t[x]);
        x:=x+lowbit(x);
    until x>n;
end;
function get(x:longint):longint;
begin
    if x=0 then exit(0);
    get:=0;
    repeat
        get:=get+t[x];
        x:=x-lowbit(x);
    until x<=0;
end;
begin
    readln(n,m);
    for i:=1 to n do read(a[i]);
    for i:=1 to n do s[a[i]]:=i;
    for i:=1 to m do readln(x[i],y[i]);
    for i:=1 to m do h[i]:=i;
    qsort(1,m);
    z:=1;
    for i:=1 to n do
    begin
        for j:=1 to n div a[i] do
            if s[a[i]*j]<=i then add(s[a[i]*j]);
        while (z<=m)and(y[z]=i) do
        begin
            ans[h[z]]:=get(y[z])-get(x[z]-1);
            inc(z);
        end;
        if z>m then break;
    end;
    fillchar(t,sizeof(t),0);
    qsort1(1,m);
    z:=m;
    for i:=n downto 1 do
    begin
        for j:=2 to n div a[i] do
            if s[a[i]*j]>=i then add(s[a[i]*j]);
        while (z>0)and(x[z]=i) do
        begin
            ans[h[z]]:=ans[h[z]]+get(y[z])-get(x[z]-1);
            dec(z);
        end;
        if z=0 then break;
    end;
    for i:=1 to m do writeln(ans[i]);
end.