随机数生成方法

最新推荐文章于 2022-08-31 01:10:31 发布
最新推荐文章于 2022-08-31 01:10:31 发布
阅读量4.1k 收藏 1
点赞数
分类专栏： Win32/64汇编 文章标签： microsoft null 算法 c 测试 2010
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/G_Spider/article/details/5983112
版权

当代计算机的创始人约翰.冯.诺依曼曾经说过，任何试图以算法生成随机数据的人都将处于一种两难境地。所谓两难说是指随机性与算法确定性之间是不可能完全统一的。所以我们必须有意识地根据需要伪随机序列的随机性才能达到模拟真随机序列的效果。
线性同余伪随机数发生器
目前应用最为广泛的均匀分布伪随面数发生器就是线线同余伪随机发生器(LCG)
LCG的迭代描述公式为：
Xi+1=(a*Xi+c)(mod m)  (1)
式(1)中有三个参数a,c,m。其中m是一个素数，a是m的一个原根，c属于[0,m)，初值x为种子。我们将a,c,m分别叫做乘数、增量、模。

Microsoft Visual C/C++的随机函数rand()就是用的上面相似的算法
其a=214013即343FDh   ,c=2531011即269EC3h   m=2^32 即一个DWORD数据

那你可能会问，x的初值取什么呢？对于rand()，初值为1,即randseek=1,当然也可以通过一个函数srand(int x)将种子更改，这样我们得到的随机数序列就不一样了，通常使用时间戳(用rdtsc指令)

通过简单的写一个c函数，然后OD跟踪一下，就可以得到rand了
#include "stdlib.h"

int main(int argc, char* argv[])
{
int Array[5][5];
int i,j;


//srand(1);
for(i=0;i<=4;i++)
 for(j=0;j<=4;j++)
  Array[i][j] = rand();
for(i=0;i<=4;i++){            //测试输出
 for(j=0;j<=4;j++)
  printf("%d    ",Array[i][j]);
 printf("/n");
}
return 0;
}
//----------------------
跟踪rand得到：
mov eax,dword ptr ds:[40703c];种子赋给eax
imul eax,eax,343fd   ;eax=a*x (有符号乘法)
add eax,269ec3   ;eax=a*x+c
mov dword ptr ds:[40703c],eax;将当前值(下一次的种子)写回
sar eax,10    ;算术右移16位(0~32767)
and eax,7fff   ;取低15位(保证为正数)，即得到了一个随机数
retn
;-----------------------------

下面给出一个完整的例子：

;************************************************************
;*--==--* Rand  example
;*--==--* By G-Spider 2010.11.2
;*--==--* Web:http://blog.csdn.net/G_Spider
;*--==--* -------------------------------------------------------
;*--==--* ml  /c /coff rand.asm  
;*--==--* link /subsystem:console rand.obj
;*--==--* 请保持以上完整性!!
;************************************************************
 .686p
.XMM
 
 .model flat,stdcall
 option casemap:none
 
 include windows.inc
 include user32.inc
 include kernel32.inc
 include msvcrt.inc
 
 includelib user32.lib
 includelib kernel32.lib  
 includelib msvcrt.lib

.data
RandSeed        dd      1       ;默认的种子
fmt0            db      '%f',0dh,0ah,0
fmt1            db      '%6d/32767=',0

.data?
lpA             dd      ?       
lpB             dd      ?    
lpC             dd      ?  
lpFloatA        dd      ?
lpFloatB        dd      ?
lpFloatC        dd      ?
.code
;*************************************
;种子生成函数
;-------------------------------------
_srand  proc seed
        push  seed
        pop   RandSeed
        ret
_srand    endp
;*************************************
;m为矩阵的行，n为矩阵的列，生成m*n个随机数
;返回数据首指针
;------------------------------------
rand    proc    m,n     
        local   @lpRand
        mov     eax,m   ;eax作乘数
        mul     n       ;n*m，结果高位在edx中，低位在eax中
        ;-------------------------------------------------
        push    eax
        shl     eax,2
        ;-------------------------------------------------
        ;申请空间
        invoke  VirtualAlloc,NULL,eax,MEM_RESERVE /
                or MEM_COMMIT,PAGE_READWRITE
        .if     eax
                mov     @lpRand,eax         ;分配的指针是页对齐的
                mov     esi,eax
        .else
                xor     eax,eax   ;失败则返回NULL
                ret
        .endif 
        pop     eax       
Loop1:        
        mov    ecx,RandSeed
        imul   ecx,ecx,343FDh
        add    ecx,269EC3h
        mov    RandSeed,ecx
        sar    ecx,10h
        and    ecx,7FFFh
        mov    [esi],ecx
        add    esi,4
        dec    eax
        jnz    Loop1

        mov     eax,@lpRand ;成功则返回0
        ret

rand    endp
;*************************************
;将rand生成的随机整数转成0~1之间的随机数
Int2FloatRand0_1  proc  m,n,lpRand,flag
        local   @lpNewRand
        
        mov     esi,lpRand 
        mov     eax,m   ;eax作乘数
        mul     n       ;n*m，结果高位在edx中，低位在eax中，总共eax=n*m个数
        push    eax     ;保存数据个数在eax中
        shl     eax,2   ;满足四个数据对齐，粒度为4字节，16字节对齐,最好的情形

        ;-------------------------------------------------
        ;申请空间
        invoke  VirtualAlloc,NULL,eax,MEM_RESERVE or MEM_COMMIT,PAGE_READWRITE
        .if     eax
                mov     @lpNewRand,eax  ;分配的指针是页对齐的
                mov     edi,eax
        .else
                xor     eax,eax   ;失败则返回NULL
                ret
        .endif
        
        ;**************************************************
        ;整形转浮点0~1
        mov     eax,38000100H   ;1/7fffh=0.000030518509476
        movd    xmm0,eax
        pslldq  xmm0,12
        movaps  xmm1,xmm0
        psrldq  xmm1,4
        orpd    xmm0,xmm1
        psrldq  xmm1,4
        orpd    xmm0,xmm1
        psrldq  xmm1,4
        orpd    xmm0,xmm1

        movaps  xmm7,xmm0       ;xmm7=1/7fffh,1/7fffh,1/7fffh,1/7fffh

        ;整形转浮点
        pop     eax             ;保存数据个数在eax中
        mov     ecx,eax
        cmp     eax,32
        jl      A002            ;整数个数(<32个)
        
        test    ecx,1Fh         ;是不是32的整数倍？
        jz      A001
        and     ecx,-20h
        and     eax, 1fh        ;剩余的整数(<32个)
        
        ;每128字节=32个数一次
A001:
        cvtdq2ps        xmm0,[esi]
        cvtdq2ps        xmm1,[esi+10h]
        mulps           xmm0,xmm7
        mulps           xmm1,xmm7
        movaps          [edi],xmm0 ;// Write to destination
        movaps          [edi+10h],xmm1
        
        cvtdq2ps        xmm2,[esi+20h]
        cvtdq2ps        xmm3,[esi+30h]
        mulps           xmm2,xmm7
        mulps           xmm3,xmm7        
        movaps          [edi+20h],xmm2 ;// Write to destination
        movaps          [edi+30h],xmm3
        
        cvtdq2ps        xmm4,[esi+40h]
        cvtdq2ps        xmm5,[esi+50h]
        mulps           xmm4,xmm7
        mulps           xmm5,xmm7        
        movaps          [edi+40h],xmm4 ;// Write to destination
        movaps          [edi+50h],xmm5
        
        movaps          xmm0,xmm7       
        cvtdq2ps        xmm6,[esi+60h]
        cvtdq2ps        xmm7,[esi+70h]
        mulps           xmm6,xmm0
        mulps           xmm7,xmm0        
        movaps          [edi+60h],xmm6 ;// Write to destination
        movaps          [edi+70h],xmm7
 
        movaps          xmm7,xmm0        
        add     esi,128
        add     edi,128
        sub     ecx,32
        jnz     A001
        
        ;处理<32个整数(16-8-4-2-1)
        
A002:  test    eax,10h
        jz      A003   ;小于16个整数
        sub     eax,10h
        cvtdq2ps        xmm0,[esi]
        cvtdq2ps        xmm1,[esi+10h]
        mulps           xmm0,xmm7
        mulps           xmm1,xmm7
        movaps          [edi],xmm0 ;// Write to destination
        movaps          [edi+10h],xmm1
        
        cvtdq2ps        xmm2,[esi+20h]
        cvtdq2ps        xmm3,[esi+30h]
        mulps           xmm2,xmm7
        mulps           xmm3,xmm7        
        movaps          [edi+20h],xmm2 ;// Write to destination
        movaps          [edi+30h],xmm3
        add     esi,64
        add     edi,64
A003:   test    eax,8
        jz      A004
        sub     eax,8
        cvtdq2ps        xmm0,[esi]
        cvtdq2ps        xmm1,[esi+10h]
        mulps           xmm0,xmm7
        mulps           xmm1,xmm7        
        movaps          [edi],xmm0 ;// Write to destination
        movaps          [edi+10h],xmm1
        add     esi,32
        add     edi,32
        
A004:   test    eax,4
        jz      A005
        sub     eax,4
        cvtdq2ps        xmm0,[esi]
        mulps           xmm0,xmm7
        movaps          [edi],xmm0
        add     esi,16
        add     edi,16
        
A005:   test    eax,2
        jz      A006
        sub     eax,2
        movlpd          xmm1,QWORD PTR [esi]
        cvtdq2ps        xmm0,xmm1
        mulps           xmm0,xmm7
        movlpd          QWORD PTR [edi],xmm0
        add     esi,8
        add     edi,8
        
A006:   test    eax,1
        jz      A007
        sub     eax,1
        movd          xmm1,DWORD PTR [esi]
        cvtdq2ps      xmm0,xmm1
        mulps         xmm0,xmm7
        movd        DWORD PTR [edi],xmm0
        add     esi,4
        add     edi,4                     
A007:
        
        mov     eax,@lpNewRand
        ret
        
Int2FloatRand0_1        endp

;%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
start:

        invoke  rand,5,5 ;默认的种子为1，生成5*5=25个随机数
        .if     eax
                mov     lpA,eax
        .else
                invoke MessageBox,NULL,0,0,0
                ret
        .endif
        ;---------------------------------------
        ;种子为2的随机数输出
        invoke  _srand,2  ;种子取2
        invoke  rand,5,5  ;生成5*5=25个随机数
        .if     eax
                mov     lpB,eax
        .else
                invoke MessageBox,NULL,0,0,0
                ret
        .endif
        
        ;---------------------------------------
        ;种子为时间戳
        rdtsc
        and     eax,7fffffffh
        invoke  _srand,eax  ;种子取2
        invoke  rand,5,5  ;生成5*5=25个随机数
        .if     eax
                mov     lpC,eax
        .else
                invoke MessageBox,NULL,0,0,0
                ret
        .endif
        ;---------------------------------------
        ;将上面生成的随机整数转成0~1之间的单精度浮点
        invoke  Int2FloatRand0_1,5,5,lpA,0
        mov     lpFloatA,eax
        invoke  Int2FloatRand0_1,5,5,lpB,0
        mov     lpFloatB,eax 
        invoke  Int2FloatRand0_1,5,5,lpB,0
        mov     lpFloatC,eax 
         
;**********************************************        
;输出前8个随机数，种子为1（种子为2的类似)
;包括整型随机数和对应的0~1之间的单精度随机数
;----------------------------------------------        
        xor     ecx,ecx   
@@:
        push    ecx
        mov     esi,lpA
        invoke  crt_printf,offset fmt1,DWORD ptr [esi+ecx*4]
        pop     ecx
        push    ecx
        
        mov     edi,lpFloatA
        fld     DWORD PTR [edi+ecx*4]
        sub     esp,8
        fstp    QWORD PTR [esp]
        push    offset fmt0
        call    crt_printf
        add     esp,12
        pop     ecx
        inc     ecx
        test    ecx,7
        jnz     @B
;**********************************************  
;释放       
        invoke  VirtualFree,lpA,0,MEM_RELEASE
        invoke  VirtualFree,lpB,0,MEM_RELEASE
        invoke  VirtualFree,lpC,0,MEM_RELEASE
        invoke  VirtualFree,lpFloatA,0,MEM_RELEASE 
        invoke  VirtualFree,lpFloatB,0,MEM_RELEASE
        invoke  VirtualFree,lpFloatC,0,MEM_RELEASE
     
        
        invoke ExitProcess,0

end start

 

 

 

 

G_Spider
关注
  • 0
    点赞
  • 踩
  • 1
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
C#可用于登录验证码的四位随机数生成方法
12-26
本文实例讲述了C#可用于登录验证码的四位随机数生成方法。分享给大家供大家参考。具体实现方法如下： 这里提供了两种方法，调用其一即可： 代码如下: using System; using System.Collections.Generic; using ...
产生随机数的方法
Amanda的博客
03-22 624
产生随机数的方法 package day02; /** * 如何獲取隨機數 * @author Amanda * java中有龐大的類庫，其中有個數學類，Math類，位於java.lang包；這是Java核心包； * 規定：使用核心包的類，不需要導包 String也是核心包的類 * * Math類有random()方法 * 使用該方法可以得到一個double類型的 ...
生成随机数的方法
yiXin_Chen的博客
08-05 1025
1. 使用Math工具类 2. 使用Random随机数伪类
随机数的生成方法
qq_39231486的博客
07-05 8141
1、Math.random()方法 在Math类中存在一个random()方法，用于产生随机数字，这个方法默认生成大于等于0.0小于1.0的double型随机数，即[0,1)虽然Math.random()方法只可以产生[0,1)之间的double型数字，其实只要在Math.random()语句上稍加处理，就可以使用这个方法产生任意范围的随机数。 公式：(数据类型)(最小值+Math.random()*(最大值-最小值+1)) flag =(int)Math.floor(2*Math.random(.
随机数生成方法及其应用
心城追梦的博客
04-19 5454
一、前言 最近公司的一个项目，需要对一个功能模块进行性能验证，具体什么模块就不说了，验证过程中需要生成大量的随机数，因为程序是跑在一个单片机平台上的，所以没有像PC上的程序那样可以有各种随机数API调用，第一个想法是用个定时器不断的计数，将计数器的值当做随机数，但是需要在一个for循环里不断生成大量随机数，运行速度很快，定时器时间基本没太大变化，产生的数据关联性太强，所以这个想法落空了。第二个想...
c#与js随机数生成方法
09-03
主要介绍了c#与js随机数生成方法,实例分析了C#与js生成随机数的技巧,具有一定参考借鉴价值,需要的朋友可以参考下
JS简单随机数生成方法
01-19
本文实例讲述了JS简单随机数生成方法。分享给大家供大家参考，具体如下： <!doctype html> <html> <head> <meta charset=utf-8> <title>随机数</title> </head> <body&...
随机数的产生方法
weixin_43777451的博客
11-28 494
第一种：rand（） srand((unsigned int)time(0)); //设置随机种子 int a = rand()%10+ 1;//产生1-10的随机数 int a = rand()%10;//产生0- 9的随机数 int i=rand()%80+20;//产生20-100的随机数 int i=rand()%80+21;//产生21-100的随机数 ...
随机数产生方法
changcheng18的专栏
09-26 471
随机数的产生： 现在的C编译器都提供了一个基于ANSI标准的伪随机数发生器函数，用来生成随机数。它们就是rand()和srand()函数。这二个函数的工作过程如下：  1) 首先给srand()提供一个种子，它是一个unsigned int类型，其取值范围从0~65535；  2) 然后调用rand()，它会根据提供给srand()的种子值返回一个随机数(在0到32767之间)  3) 根
生成随机数的常用方法
qq_34850932的博客
09-05 319
常用的生成随机数的方式； 效率有10倍的差距
生成随机数的若干种方法
虚幻私塾
08-31 1148
自定义变量: 例如 10 个数字+52 个字符（26位英文字母大小写）key=“abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789”
随机数的三种生成方式
灰色的小熊的博客
02-28 7019
       // 第一种生成验证码的方式 String string = ""; for (int i = 0; i &lt; 4; i++) { string += (int) (Math.random() * 10); } // 第二种生成方式 String substring = UUID.randomUUID().toString().replace("-", "") ...
关于如何产生随机数的几种方法汇总！（2018.07.08）
weixin_41812301的博客
07-09 1691
    在学习java过程中，特别是一些游戏程序或者登录验证码等会涉及到随机数这个对象，因此对此汇总一下我说了解到的获得0到100之前的随机数的几种方法：   java.util.Random类中提供了多种产生随机数的方法：其中使用最多的就是随机整数,1.通过Random() 构造方法实例化的对象产生随机数　  Random r=new Random();　特点：每次运行产生的随机数都不一样。  ...
利用rdtsc生成随机数
hermit_f的博客
09-10 634
rdtsc指令是得到CPU自启动以后的运行周期数，在586以上的CPU上存在。 rdtsc指令返回的是自开机始CPU的周期数，返回的是一个64位的值，存在 EDX：EAX 中（高32在EDX，低32位在EAX）。 rdtsc指令有很多用处，比如计算微秒甚至纳秒级时间，或进一步计算程序运行速度等等，这里介绍下利用rdtsc指令生成随机数。#include <conio.h> #include <i
利用计算机可产生随机数,利用计算机内部计数器生成真随机数原理及实现
weixin_33899835的博客
06-28 526
一、手动产生随机数方法计数器是精密器件不能直接产生随机数，但可以让其为产生随机数服务。每个计算机都有其工作频率称为主频，与之相对应的是时钟周期，下面的程序段DWORD n;_asm//嵌入汇编语言{rdtsc//读计数器值mov n,eax//计数器低位值进入n}的作用是读取自开机以来CPU经历的时钟周期数的低32位数值(高位值变化缓慢在此无用)放到变量 n中，每调用一次 n的数值等于其现有数值加...
Mendix开发-竞赛随机组队小程序
weixin_37751064的博客
03-19 3655
最近部门准备开展竞赛活动，我们通过mendix快速开发了一个小程序实现随机组队的功能。 一.需求 1.两个成员组成1队。 2.将所有成员等分在两个大组里，相同大组的成员不能在同一小队。（总参与人数恰好为偶数） 二.数据模型 在mendix新建项目GroupApp，定义GroupModule的Domain Model如下图。Group为大组，Person为成员，Team为最后随机产生的队伍。 三.首页 四.人员录入 五.随机分组 ...
随机数生成器
weixin_30897233的博客
02-05 196
指令集真好玩 #pragma GCC optimize("Ofast") #pragma GCC optimize("unroll-loops") #pragma GCC target("sse,sse2,sse3,ssse3,sse4,popcnt,abm,mmx,avx,tune=native") #include<cstdio> #include "immin...
java随机数生成方法
最新发布
04-22
2. 使用java.security.SecureRandom类，这是一个更安全的随机数生成器，可以生成高质量的随机数，特别是在需要更高的安全性时使用。 代码示例： 1. 使用Random类生成随机整数： ``` Random rand = new Random(); int...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值