6 Day：向内核迈进--获取物理内存

Genius!

已于 2022-12-08 13:29:14 修改

阅读量304

点赞数 3

分类专栏：一起来写操作系统吧！文章标签： linux 运维服务器

于 2022-12-04 23:06:12 首次发布

本文链接：https://blog.csdn.net/GeniusLS/article/details/128174561

版权

一起来写操作系统吧！专栏收录该内容

20 篇文章 7 订阅

订阅专栏

前言：

上一章我们已经进入保护模式，推开了探索内核的大门。今天我们要踏入内核世界，拿起我们前几章新手村刚造好的装备，向内存迈进，话不多说我们开始吧。

本日参考资料：

《操作系统真象还原》

一，获取内存

获取内存的方法我们可以参考 linux detect_memory函数一共有三种方法，那就是调用BIOS中断0x15的3个子功能。

0xe820：遍历主机上的所有内存
0xe801：遍历4G内存，分为两组 0~15MB，16MB~4G
0x88：最多检测64MB内存

① int 0x15 子功能 0xe820

该功能有一个好处就是可以返回十分全面的内存信息以及内存布局，他有一个专门的内存信息存储结构ARDS（地址范围描述符）

ARDS

由于我们的操作系统是32位的，我们只需用到ADRS低32位基址和低32位内存长度即可，由于有多种的内存分布，所以返回的信息的形式是迭代式的，即不断返回信息直到返回完毕，int 0x15 0xe820 函数的调用参数如下：

ECX，ES:DI分别存储缓冲区的大小和缓冲区的指针。

调用方法如下：

填写好调用前输入列出的寄存器
执行0x15中断
CF为0时，返回后输出寄存器将有相应的结果

调用函数后，我们要找到最大的那一块内存。正常情况下，不会出现较大的内存区域不可用的情况，除非安装的物理内存极其小。这意味着，在所有返回的 ARDS 结构里，此值最大的内存块一定是操作系统可使用的部分，即主板上配置的物理内存容量。

② int 0x15 子功能 0xe801

此功能只能记录4GB内存，但是对于我们32位系统来说足够了。其中需要有两组寄存器分布记录两块内存。

对于低于15MB的内存用1KB单位记录，单位数量在寄存器AX和CX中，其中AX与CX的最大值为0x3c00（0x3c00*1024 = 15MB）
对于16MB~4GB的内存用64KB单位记录，其单位数量在BX和DX中，大家自己算算吧。

方法参数如下：

调用方法如下：

将AX寄存器写入0xE801
执行中断int 0x15
CF位为0时会有结果。

为什么分成两块内存区域？

这也是历史遗留原因了，早在很久以前，某些ISA设备需要用15MB以上的内存作为缓冲区，所以这一块就一直保留下来被称为memory hole，我个人更喜欢把他理解为内存黑洞。这是操作系统无法访问的一块内存区域。当然现在可以进入BIOS界面来关闭对之前ISA设备的支持。

实例：

我们可以自己设置bochs的内存容量，然后调用int 0x15可以看看结果

这里就可以发现了两个点

1，内存大于17MB时被分为两部分

2，检测内存大小小于实际物理内存大小，这是为什么呢？

解答：

这是因为，有1MB的内存是缓冲区的大小，所以以后我们检测内存的时候要默认+1MB上去

③ int 0x15的子功能 0x88

这个没啥好说，虽然他是最简单的功能，但是其最大也只能是64MB，显示只能显示63MB，原因上述有说。不多说了，我们直接看函数调用吧。

方法参数如下：

二，冻手写代码

书上是三种方法全写上，然后如果第一个不行就用第二个，但是我比较懒，就写第一种了如果有兴趣有能力的可以按书上写(书上有一些小错误，需要注意一下)

loader.S

;loader.s

%include "boot.inc"
section loader vstart=LOADER_BASE_ADDR
LOADER_STACK_TOP equ LOADER_BASE_ADDR
jmp  near loader_start 		    	; 此处的物理地址是:
   
;构建gdt及其内部的描述符
   GDT_BASE:   		  dd    0x00000000 
	       	   		  dd    0x00000000

   CODE_DESC:  		  dd    0x0000FFFF 
	           		  dd    DESC_CODE_HIGH4

   DATA_STACK_DESC:  dd    0x0000FFFF
		    		 dd    DESC_DATA_HIGH4

   VIDEO_DESC: 		 dd    0x80000007	       ;limit=(0xbffff-0xb8000)/4k=0x7
	       			 dd    DESC_VIDEO_HIGH4  ; 此时dpl已改为0

   GDT_SIZE   equ   $ - GDT_BASE  ;GDT的大小
   GDT_LIMIT   equ   GDT_SIZE -	1  ;GDT的界限
   
   times 59 dq 0					 ; 此处预留60个描述符的slot
   times 5 db 0

   total_mem_bytes dd 0 ;新增，该地址是0xb00


   ;以下是定义gdt的指针，前2字节是gdt界限，后4字节是gdt起始地址

   gdt_ptr  dw  GDT_LIMIT 
	    dd  GDT_BASE

	;人工对齐:total_mem_bytes4+gdt_ptr6+ards_buf244+ards_nr2 ，共 256 字节(无实际意义)
	ards_buf times 244 db 0
	ards_nr dw 0	;记录ards的数量

	SELECTOR_CODE equ (0x0001<<3) + TI_GDT + RPL0         ; 相当于(CODE_DESC - GDT_BASE)/8 + TI_GDT + RPL0
   SELECTOR_DATA equ (0x0002<<3) + TI_GDT + RPL0	 ; 同上
   SELECTOR_VIDEO equ (0x0003<<3) + TI_GDT + RPL0	 ; 同上 


loader_start:

xor ebx, ebx
mov di, ards_buf
.e820_mem_get_loop:
	mov eax, 0x0000e820
	mov edx, 0x534d4150
	mov ecx, 20
	int 0x15

	jc .error_hlt
	add di, cx
	inc word [ards_nr]
	cmp ebx, 0
	jne .e820_mem_get_loop

	mov cx, [ards_nr]
	mov ebx, ards_buf
	xor edx, edx
.find_max_mem_area:
	mov eax, [ebx]
	add eax, [ebx+8]
	add ebx, 20
	cmp edx, eax	; if ebx >= eax: continue, else ebx = eax
	jge .next_ards
	mov edx, eax
.next_ards:
	loop .find_max_mem_area
	jmp .mem_get_ok


.error_hlt:
	jmp $

.mem_get_ok:
	mov	[total_mem_bytes],edx
	mov byte [gs:0xA0],'G'
	mov byte [gs:0xA1],0xA4
   
	mov byte [gs:0xA2],'e'
	mov byte [gs:0xA3],0xA4
   
	mov byte [gs:0xA4],'n'
	mov byte [gs:0xA5],0xA4
   
	mov byte [gs:0xA6],'i'
	mov byte [gs:0xA7],0xA4
   
	mov byte [gs:0xA8],'u'
	mov byte [gs:0xA9],0xA4
   
	mov byte [gs:0xAA],'s'
	mov byte [gs:0xAB],0xA4
	
;----------------------------------------   准备进入保护模式   ------------------------------------------
									;1 打开A20
									;2 加载gdt
									;3 将cr0的pe位置1


   ;-----------------  打开A20  ----------------
   in al,0x92
   or al,0000_0010B
   out 0x92,al

   ;-----------------  加载GDT  ----------------
   lgdt [gdt_ptr]


   ;-----------------  cr0第0位置1  ----------------
   mov eax, cr0
   or eax, 0x00000001
   mov cr0, eax
   

   jmp  dword SELECTOR_CODE:p_mode_start	     ; 刷新流水线，避免分支预测的影响,这种cpu优化策略，最怕jmp跳转，
					     ; 这将导致之前做的预测失效，从而起到了刷新的作用。

[bits 32]
p_mode_start:
   mov ax, SELECTOR_DATA
   mov ds, ax
   mov es, ax
   mov ss, ax
   mov esp,LOADER_STACK_TOP
   mov ax, SELECTOR_VIDEO
   mov gs, ax

   mov byte [gs:0x140], 'P'
   mov byte [gs:0x141], 0xA4

   jmp $

然后在代码中，我们把总内存放到了 0xb00的位置，于是我们先运行一下，然后输入