u-boot.lds分析

原文地址

http://www.cnblogs.com/jxlgzzq/archive/2012/03/29/2422863.html

/*
 指定输出可执行文件是elf格式,
 32位ARM指令,小端
*/

OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")

/* 指定输出文件的平台体系是ARM */
OUTPUT_ARCH(arm)

/*指定可执行映像文件的起始段的段名是_start*/
ENTRY(_start)

SECTIONS
{
/*
 指定可执行image文件的全局入口点，
 通常这个地址都放在ROM(flash)0x0位置。
 必须使编译器知道这个地址，
 通常都是修改此处来完成
*/

/* 起始地址为0x00000000 */
 . = 0x00000000;

/*4字节对齐*/
 . = ALIGN(4);

 /* 代码段*/
 .text :
 {
   /* 代码段第一部分代码*/
  arch/arm/cpu/arm1176/start.o (.text)

    /*其余代码段*/
  *(.text)
 }

 . = ALIGN(4);

/*
 只读数据段，
 所有的只读数据段都放在这个位置
*/
 .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }

 . = ALIGN(4);
 
/* 可读写数据段，
所有的可读写数据段都放在这里*/
 .data : { *(.data) }

 . = ALIGN(4);

/*指定got段,
got段式是uboot自定义的一个段,
非标准段*/
 .got : { *(.got) }

/*
 .=.  前一个表示当前段，
 后一个点表示当前地址，
 根据编译结果来分配地址，
 比写死地址要灵活
*/
 . = .;

/*把__u_boot_cmd_start赋值为当前位置,
即起始位置*/
 __u_boot_cmd_start = .;

/* u_boot_cmd段，
所有的u-boot命令相关的定义都放在这个位置，
因为每个命令定义等长，
所以只要以__u_boot_cmd_start
为起始地址进行查找就可以
很快查找到某一个命令的定义，
并依据定义的命令指针调用
相应的函数进行处理用户的任务*/
 .u_boot_cmd : { *(.u_boot_cmd) }

/*u_boot_cmd段结束位置，
由此可以看出，
这段空间的长度并没有严格限制，
用户可以添加一些u-boot的命令，
最终都会在连接是存放在这个位置。*/
 __u_boot_cmd_end = .;

 

 . = ALIGN(4);

 /*把__bss_start赋值为当前位置,
 即bss段的开始位置*/
 __bss_start = .;

 /*指定bss段，
 这里NOLOAD的意思是这段不需装载，
 仅在执行域中才会有这段*/
 .bss (NOLOAD) : { *(.bss) . = ALIGN(4); }

  /*把_end赋值为当前位置,即bss段的结束位置*/
 _end = .;