WINDOWS:BAT读取配置文件并设置环境变量

1.配置文件内容说明：
        注释用"#"来表示，且只能在当前行开始；
        配置的环境变量格式为：key=value
        示例，在D：/test目录有配置文件"test.env"：

#value0的配置值
value0=key0

2.导入环境变量bat写法：
        eol=#               忽略以指定字符“#”开头的行。可以使用该功能跳过注释。
        delims==         定义使用“=”号符分割内容

for /f "delims== tokens=1* eol=#" %%i in (test.env) do (
	set %%i=%%j
)

3.以配置自定义jdk路径为例，提供完整代码：
        3.1.配置文件"test.env"内容

# 如果系统环境变量已有jdk，则不用配置；如果想使用自己版本的jdk，则填写
CUSTOM_JAVA_HOME=D:/jdk/jdk11

        3.2.脚本“test.bat”加载配置文件并设置环境变量
        说明：本脚本只提供加载环境变量功能，后续的运行程序功能请按需自己编写，环境变量的值会输出到"load-env.log"日志文件。

::开始导入环境变量
echo 时间：%date:~0,10% %time:~0,5% > load-env.log

echo >> load-env.log

：：记录系统的环境变量,赋值给SOURCE_PATH
set SOURCE_PATH=%PATH%

::是否使用自定义jdk 0=不使用，1=使用
set /a useCustomJdk=0
set CUSTOM_JAVA_HOME=
echo -------------环境变量------------->> load-env.log
for /f "delims== tokens=1* eol=#" %%i in (test.env) do (
	if "%%i" == "CUSTOM_JAVA_HOME" (
		if "%%j" neq "" (
			set /a useCustomJdk=1
			echo %%i=%%j >>load-env.log
			set CUSTOM_JAVA_HOME=%%j/bin;
		)
	) else (
		set %%i=%%j
		echo %%i=%%j>> load-env.log
	)
)
echo -------------环境变量------------->> load-env.log

set PATH=%CUSTOM_JAVA_HOME%%SOURCE_PATH%

echo 选择JDK>> load-env.log
if %useCustomJdk% == 0 (
	echo 使用系统JDK
	echo 使用系统JDK>> load-env.log
) else (
	echo 使用自定义JDK
	echo 使用自定义JDK>> load-env.log
)


set check_flag=true
if "true" == "%check_flag%" (
	echo 运行命令"jps -l">> load-env.log
	jps -l>> load-env.log
)
if not %errorlevel% == 0 (
  echo 未找到可执行的jps命令,请配置自定义的JDK后再运行.
  pause
  goto exit
)
::结束导入环境变量