HBase 与Hive的集成

在hive-site.xml中增加zookeeper的属性，如下：

<property>
       <name>hive.zookeeper.quorum</name>
       <value>node1,node2,node3</value>
</property>

<property>
       <name>hive.zookeeper.client.port</name>
       <value>2181</value>
</property>

增加以上属性就可以创建关联表了

CREATE TABLE student_hive_2(
id string,
name string,
age string
)
STORED BY 'org.apache.hadoop.hive.hbase.HBaseStorageHandler'
WITH SERDEPROPERTIES ("hbase.columns.mapping" = ":key,f1:name,f1:age")
TBLPROPERTIES ("hbase.table.name" = "student_hbase");

:key 指hbase的主键
hbase.columns.mapping： 指定hive的字段与hbase的column的映射
hbase.table.name： 指定创建的hbase的表名

1、内部表[与hbase的表建立映射关系]
a.在hive创建表的时候会同步在hbase中创建表，如果hbase的表已经存在则报错
b.删除hive内部表的时候会同步删除Hbase的表

2、外部表[与hbase的表建立映射关系]
a.在hive创建表的时候要求hbase的表必须已经存在,如果hbase的表不存在则报错
b.删除hive外部表的时候不会删除hbase的表

1．案例一
目标：建立Hive表，关联HBase表，插入数据到Hive表的同时能够影响HBase表。
分步实现：
1）在Hive中创建表同时也会在hbase中生成对应的一张表

CREATE TABLE hive_hbase_emp_table(
empno int,
ename string,
job string,
mgr int,
hiredate string,
sal double,
comm double,
deptno int)
STORED BY 'org.apache.hadoop.hive.hbase.HBaseStorageHandler'
WITH SERDEPROPERTIES ("hbase.columns.mapping" = ":key,info:ename,info:job,info:mgr,info:hiredate,info:sal,info:comm,info:deptno")
TBLPROPERTIES ("hbase.table.name" = "hbase_emp_table");

提示：完成之后，可以分别进入Hive和HBase查看，都生成了对应的表

2）在Hive中创建临时中间表，用于load文件中的数据
提示：不能将数据直接load进Hive所关联HBase的那张表中

CREATE TABLE emp(
empno int,
ename string,
job string,
mgr int,
hiredate string,
sal double,
comm double,
deptno int)
row format delimited fields terminated by '\t';

3）向Hive中间表中load数据

hive> load data local inpath '/home/admin/softwares/data/emp.txt' into table emp;

4）通过insert命令将中间表中的数据导入到Hive关联Hbase的那张表中

hive> insert into table hive_hbase_emp_table select * from emp;

5）查看Hive以及关联的HBase表中是否已经成功的同步插入了数据

Hive：
hive> select * from hive_hbase_emp_table;

HBase：
hbase> scan 'hbase_emp_table'

2．案例二

目标：在HBase中已经存储了某一张表hbase_emp_table，然后在Hive中创建一个外部表来关联HBase中的hbase_emp_table这张表，使之可以借助Hive来分析HBase这张表中的数据。
注：该案例2紧跟案例1的脚步，所以完成此案例前，请先完成案例1。
分步实现：
1）在Hive中创建外部表

CREATE EXTERNAL TABLE relevance_hbase_emp(
empno int,
ename string,
job string,
mgr int,
hiredate string,
sal double,
comm double,
deptno int)
STORED BY 
'org.apache.hadoop.hive.hbase.HBaseStorageHandler'
WITH SERDEPROPERTIES ("hbase.columns.mapping" = 
":key,info:ename,info:job,info:mgr,info:hiredate,info:sal,info:comm,info:deptno") 
TBLPROPERTIES ("hbase.table.name" = "hbase_emp_table");

2）关联后就可以使用Hive函数进行一些分析操作了

hive (default)> select * from relevance_hbase_emp;