ALV TREE DEMO

最新推荐文章于 2024-07-19 09:19:29 发布
最新推荐文章于 2024-07-19 09:19:29 发布
阅读量402 收藏 3
点赞数
分类专栏： ALV知识点 文章标签： sap abap
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/JYH1999/article/details/117023139
版权

导语：关于alv tree网上的资料比较少，在这里分享一个简单的demo这个也是我通过网上找的一个demo自己修改测试了一下，原文章的链接找不到了，后续有时间我会测一下事件，再分享alv tree的资料。

具体代码如下，只需要建一个screen就可以用了，屏幕上的控件我定义的名字就是alv tree，里面的注释还算明确。

*&---------------------------------------------------------------------*
*& Report Z_ALVTREE_TEST
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT z_alvtree_test.

*&---------------------------------------------------------------------*
*&数据对象定义
*&---------------------------------------------------------------------*
DATA:BEGIN OF gs_alv,
       erdat  TYPE vbak-erdat,
       vbeln  TYPE vbak-vbeln,
       posnr  TYPE vbap-posnr,
       matnr  TYPE vbap-matnr,
       kwmeng TYPE vbap-kwmeng,
       vrkme  TYPE vbap-vrkme,
     END OF gs_alv.
DATA gt_alv LIKE TABLE OF gs_alv.
DATA:gs_fcat TYPE lvc_s_fcat,
     gt_fcat TYPE lvc_t_fcat.
DATA:lcl_container TYPE REF TO cl_gui_container, "容器类引用变量
     lcl_tree      TYPE REF TO cl_gui_alv_tree. "树形ALV控制器引用变量
DATA:ok_code   TYPE sy-ucomm, "获取100屏幕触发的功能码
     save_code TYPE sy-ucomm.
*&---------------------------------------------------------------------*
*&事件接受类定义
*&---------------------------------------------------------------------*
CLASS lcl_handle DEFINITION.

  PUBLIC SECTION.
    "定义双击节点事件触发时的处理方法
    METHODS handle_node_dclick
      FOR EVENT node_double_click OF cl_gui_alv_tree
      IMPORTING node_key sender.
    "其中SENDER这个参数是一个隐式的事件参数，是由ABAP对象运行系统提供，它指向了触发这个事件的实例，可以直接使用它来调用这个实例的方法。

ENDCLASS.

CLASS lcl_handle IMPLEMENTATION.

  "定义处理方法的具体实施
  METHOD handle_node_dclick.
    DATA: lt_children TYPE lvc_t_nkey.
*检查被点击的NODE几点下面有无子节点，有则展开节点。
    CALL METHOD sender->get_children
      EXPORTING
        i_node_key  = node_key
      IMPORTING
        et_children = lt_children.

    IF NOT lt_children IS INITIAL.

      CALL METHOD sender->expand_node
        EXPORTING
          i_node_key    = node_key
          i_level_count = 2.
    ELSE.
      SET PARAMETER ID 'AUN' FIELD node_key.
      CALL TRANSACTION 'VA03' AND SKIP FIRST SCREEN.
    ENDIF.
  ENDMETHOD.

ENDCLASS.

START-OF-SELECTION.
  CALL SCREEN 100.
*&---------------------------------------------------------------------*
*& Module STATUS_0100 OUTPUT
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
MODULE status_0100 OUTPUT.
  SET PF-STATUS '100'.
  SET TITLEBAR 'TITLE'.
  IF lcl_tree IS INITIAL.
    PERFORM init_tree.

    CALL METHOD cl_gui_cfw=>flush
      EXCEPTIONS
        cntl_system_error = 1
        cntl_error        = 2.
    IF sy-subrc NE 0.
      CALL FUNCTION 'POPUP_TO_INFORM'
        EXPORTING
          titel = 'Automation Queue failure'
          txt1  = 'Internal error:'
          txt2  = 'A method in the automation queue'
          txt3  = 'caused a failure.'.
    ENDIF.
  ENDIF.
ENDMODULE.
*&---------------------------------------------------------------------*
*& Form INIT_TREE
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM init_tree .
  "1.实例化容器对象
  lcl_container = cl_gui_container=>screen0.

  "2.实例化TREE控制器
  CREATE OBJECT lcl_tree
    EXPORTING
      parent                      = lcl_container "绑定容器
      node_selection_mode         = cl_gui_column_tree=>node_sel_mode_single
      item_selection              = 'X'
      no_html_header              = 'X'
      no_toolbar                  = ''
    EXCEPTIONS
      cntl_error                  = 1
      cntl_system_error           = 2
      create_error                = 3
      lifetime_error              = 4
      illegal_node_selection_mode = 5
      failed                      = 6
      illegal_column_name         = 7.
  IF sy-subrc <> 0.
    MESSAGE e208(00) WITH '实例化ALV TREE控制器失败！'.     "
  ENDIF.
  "3.设置NODE描述字段信息
  DATA l_hierarchy_header TYPE treev_hhdr.
  PERFORM build_hierarchy_header CHANGING l_hierarchy_header.
  "4.设置ALV字段
  PERFORM frm_fillfield USING: 'ERDAT' '日期',
                               'VBELN' '单号',
                               'POSNR' '行号',
                               'MATNR' '物料',
                               'KWMENG' '数量',
                               'VRKME' '单位'.

  "5设置ALV显示字段
  CALL METHOD lcl_tree->set_table_for_first_display
    EXPORTING
      is_hierarchy_header = l_hierarchy_header
    CHANGING
      it_fieldcatalog     = gt_fcat
      it_outtab           = gt_alv. "此表必须一直为空，且为全局变量
  "6.设置根节点，填充叶节点数据
  PERFORM create_hierarchy.
  "7.注册事件
  PERFORM register_events.
* 更新汇总字段
  CALL METHOD lcl_tree->update_calculations.
*前端显示数据
  CALL METHOD lcl_tree->frontend_update.
ENDFORM.
*&---------------------------------------------------------------------*
*&      Form  build_hierarchy_header
*&---------------------------------------------------------------------*
*       build hierarchy-header-information
*----------------------------------------------------------------------*
*      -->P_L_HIERARCHY_HEADER  strucxture for hierarchy-header
*----------------------------------------------------------------------*
FORM build_hierarchy_header CHANGING
                               p_hierarchy_header TYPE treev_hhdr.

  p_hierarchy_header-heading = '日期'.
  p_hierarchy_header-tooltip = '节点依据'.
  p_hierarchy_header-width = 50.
  p_hierarchy_header-width_pix = ''.

ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_FILLFIELD
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*&      --> P_
*&      --> P_
*&---------------------------------------------------------------------*
FORM frm_fillfield USING p_fieldname TYPE lvc_fname
                          p_coltext TYPE lvc_txtcol.

  CLEAR gs_fcat.
  gs_fcat-fieldname = p_fieldname.
  gs_fcat-coltext = p_coltext.
  IF p_fieldname = 'ERDAT' OR p_fieldname = 'VBELN' OR p_fieldname = 'POSNR' .
    gs_fcat-no_out = 'X'."隐藏右侧输出的MATNR/WERKS/LGORT字段
  ELSEIF p_fieldname = 'KWMENG'.
    gs_fcat-qfieldname = 'VRKME'.
    gs_fcat-do_sum = 'X'."数量汇总
    gs_fcat-h_ftype = 'SUM'.
    gs_fcat-ref_field = 'KWMENG'.
    gs_fcat-ref_table = 'VBAP'.
    gs_fcat-outputlen = '30'.
  ELSEIF p_fieldname = 'MAKTX'.
    gs_fcat-outputlen = '30'.
  ENDIF.
  APPEND gs_fcat TO gt_fcat.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form CREATE_HIERARCHY
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM create_hierarchy .
  DATA: ls_node      LIKE gs_alv,
        ls_alv       LIKE gs_alv,
        lt_alv       LIKE TABLE OF gs_alv,
        l_last_erdat TYPE vbak-erdat,
        l_last_vbeln TYPE vbak-vbeln.
  DATA: l_erdat_key TYPE lvc_nkey,
        l_vbeln_key TYPE lvc_nkey,
        l_last_key  TYPE lvc_nkey,
        l_top_key   TYPE lvc_nkey.
  DATA l_node_text TYPE lvc_value.



  SELECT a~erdat,
         b~vbeln,
         b~posnr,
         b~matnr,
         b~kwmeng,
         b~vrkme
    INTO TABLE @lt_alv
    FROM vbak AS a
    INNER JOIN vbap AS b ON a~vbeln = b~vbeln.

*  SELECT d~matnr,
*         d~werks,
*         d~lgort,
*         d~labst,
*         a~meins,
*         t~maktx
*  INTO CORRESPONDING FIELDS OF TABLE @lt_alv UP TO 200 ROWS
*  FROM mard AS d INNER JOIN mara AS a
*  ON d~matnr = a~matnr
*  LEFT OUTER JOIN makt AS t
*  ON d~matnr = t~matnr
*  WHERE t~spras = @sy-langu.

  SORT lt_alv BY erdat vbeln.

  "添加祖节点
  CALL METHOD lcl_tree->add_node
    EXPORTING
      i_relat_node_key = ''
      i_relationship   = cl_gui_column_tree=>relat_last_child
      i_node_text      = '单据查询'
    IMPORTING
      e_new_node_key   = l_top_key. "祖节点标识
  "按照工厂->仓库层次设置节点，设置”叶片“，填充"叶片"数据
  LOOP AT  lt_alv INTO ls_alv.
    "设置日期节点
    IF l_last_erdat NE ls_alv-erdat.
      l_last_erdat = ls_alv-erdat.
      "若此次循环到的工厂与上一次不相同，则创造新的工厂节点
      "ADD NODE
      CLEAR l_node_text.
      l_node_text = ls_alv-erdat.
      CALL METHOD lcl_tree->add_node
        EXPORTING
          i_relat_node_key = l_top_key "处于祖节点之下
          i_relationship   = cl_gui_column_tree=>relat_last_child
          i_node_text      = l_node_text
          is_outtab_line   = ls_node
        IMPORTING
          e_new_node_key   = l_erdat_key. "日期节点标识
      CLEAR l_last_vbeln."当创建新的日期节点时，清空上一个日期节点
    ENDIF.

    "设置单号节点
    IF l_last_vbeln NE ls_alv-vbeln.
      l_last_vbeln = ls_alv-vbeln.
      "若此次循环到的库存点点与上一次不相同，则创造新的库存节点
      "ADD NODE
      CLEAR l_node_text.
      l_node_text = ls_alv-vbeln.
      CALL METHOD lcl_tree->add_node
        EXPORTING
          i_relat_node_key = l_erdat_key "处于日期节点之下
          i_relationship   = cl_gui_column_tree=>relat_last_child
          i_node_text      = l_node_text
          is_outtab_line   = ls_node
        IMPORTING
          e_new_node_key   = l_vbeln_key. "单号节点标识
    ENDIF.
    "设置”叶片“，填充"叶片"数据
    CLEAR l_node_text.
    l_node_text = ls_alv-posnr.
    CALL METHOD lcl_tree->add_node
      EXPORTING
        i_relat_node_key = l_vbeln_key "处于单号节点之下
        i_relationship   = cl_gui_column_tree=>relat_last_child
        i_node_text      = l_node_text
        is_outtab_line   = ls_alv "有数据
      IMPORTING
        e_new_node_key   = l_last_key. "行号节点标识

  ENDLOOP.

ENDFORM.
*&---------------------------------------------------------------------*
*& Form REGISTER_EVENTS
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM register_events .
  "注册前端后后端事件
  DATA: lt_events        TYPE cntl_simple_events,
        l_event          TYPE cntl_simple_event,
        l_event_receiver TYPE REF TO lcl_handle.

*1。获取已注册的前端事件
  CALL METHOD lcl_tree->get_registered_events
    IMPORTING
      events = lt_events.
  "2.添加前端双击时间
  l_event-eventid = cl_gui_column_tree=>eventid_node_double_click.
  APPEND l_event TO lt_events.

*3.重新设置前端注册时间
  CALL METHOD lcl_tree->set_registered_events
    EXPORTING
      events                    = lt_events
    EXCEPTIONS
      cntl_error                = 1
      cntl_system_error         = 2
      illegal_event_combination = 3.
  IF sy-subrc <> 0.
    MESSAGE e208(00) WITH '注册前端事件失败！'.                      "#EC NOTEXT
  ENDIF.
*--------------------
  "4.注册后端事件
  CREATE OBJECT l_event_receiver.
  SET HANDLER l_event_receiver->handle_node_dclick FOR lcl_tree.
ENDFORM.
*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND_0100  INPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE user_command_0100 INPUT.
  save_code = ok_code.
  CLEAR ok_code.

  CASE save_code.
    WHEN 'EXIT' OR 'BACK' OR 'CANC'.
      "释放容器，退出程序
      CALL METHOD lcl_container->free.
      LEAVE PROGRAM.
    WHEN OTHERS.
      "为正确调用工具栏按钮功能，必须调用该方法
      CALL METHOD cl_gui_cfw=>dispatch.

  ENDCASE.

  CALL METHOD cl_gui_cfw=>flush.
ENDMODULE.

效果展示在这里插入图片描述
作者：小飞猪猪猪猪猪猪猪–CSDN

小飞猪猪猪猪猪猪猪
关注
  • 0
    点赞
  • 踩
  • 3
    收藏
    觉得还不错? 一键收藏
  • 打赏
    打赏
  • 1
    评论
专栏目录
【ABAP】ALV Tree demo(WBS元素分层显示)
Mac的SAP专栏
08-01 7113
按层次显示WBS编码及描述，附加节点双击展开事件和Item双击跳转CJ03功能。  因为本人懒，本例代码都是从标准的BCALV_TREE_01和BCALV_TREE_02拷贝过来修改的，结构不好请别见怪。  REPORT  zmac_alvtree_test. DATA: g_alv_tree         TYPE REF TO cl_gui_alv_tre
abap tree control demo
fengyeyu090813的专栏
08-29 2143
最终效果图 代码：REPORT ZTEST_HSS3. INCLUDE ZTEST_HSS3_DATA. INCLUDE ZTEST_HSS3_FRM. INCLUDE ZTEST_HSS3_PBO. INCLUDE ZTEST_HSS3_PAI. INITIALIZATION. *START-OF-SELECTION. CREATE OBJECT G_APP
SAP ABAP之BOM物料递归查询方法汇总以及树状TREE ALV展示BOM物料层级
yishangbing的博客
03-30 5689
注意：gt_stpo_alv这个表必须是空的，否则显示的数据会出错，至于表结构跟随STPOX表即可。2、利用递归的方法，对第一层的子组件逐一遍历，类似的再去查询MAST表和STPO表，获取。请注意，此处必须释放容器，不然TREE ALV只会渲染一次，下一次调用还是上一次的数据。1、从MAST表获取BOM的物料清单，根据物料清单去查询STPO表从而获取。导读：最近和BOM物料干上了，记录一下我的开发过程和学到的东西。已经尽可能的简化步骤了，网上的资料都是步骤很繁琐的。的物料组件，（订单数量在STKO表），
SAP ABAP Tree 开发
最新发布
m0_38069169的博客
07-19 491
SAP ABAP Tree 开发，顺手开发一个自定义表管理程序。
alv tree
SAP 我候着
06-25 1479
*&---------------------------------------------------------------------**& Report  BCALV_TREE_SIMPLE_DEMO                                      **&                                                  
ALV-TREE
chibei9260的博客
04-17 633
****要注意创建相应程序的屏幕0100**** 在一些情况下，输出的ALV可能用树形结构更容易展现数据之间的相互关联，为了输出ALV-TREE主要用到的是容器类（如CL_GUI_CONTAINER或CL_GUI_CUSTOM_CONTAINER等）和ALV-TREE控制器类CL_GUI_A...
ALV tree标准DEMO
anchangong3418的博客
03-28 211
BCALV_TREE_01 ALV 树控制：构建层次树 BCALV_TREE_02 ALV 树控制：事件处理 BCALV_TREE_03 ALV 树控制：使用自己的上下文菜单 BCALV_TREE_04 ALV 树控制：添加按钮到工具栏 ...
ALV_TREE（二：cl_gui_simple_tree…
weixin_30753873的博客
01-22 193
树形展示 首先创建屏幕， 画个容器，命名TREE DATA: wa_container_treeTYPEscrfnameVALUE'TREE',"*定制对象 wa_custom_container_treeTYPEREFTOcl_gui_custom_container,"*客户对象 ...
ALV Tree
weixin_30402085的博客
11-09 116
找相关的alv tree demo：se38 -> bcalv_tree* 1.创建对话屏幕 由于ALV没有专门实现的控件，需要先在对话屏幕100上增加一个用户自定义控件区域（Custom Control），名为CONTAINER1 2.demo源码 *&---------------------------------------------------------...
动态平衡二叉树demo
08-04
- `alvtree.cpp`：可能包含了AVL树的主要实现代码，包括节点定义、插入、删除、旋转等操作。 - `建立平衡二叉树.cpp`：可能包含了主程序代码，初始化和管理AVL树。 - `建立平衡二叉树Dlg.cpp/h`：可能与GUI对话框...
ALV平衡树实现
hxy1625309592的博客
12-15 687
1.1 基本介绍 平衡二叉树又称AVL树，是一种最早的自平衡二分搜索树结构，它是具有如下性质的二叉树: 左、右子树是平衡二叉树; 所有结点的左、右子树深度之差的绝对值≤1。 满二叉树一定是平衡二叉树，高度最低。 完全二叉树也是平衡二叉树，叶子节点深度相差不为1 为了方便起见，给每个结点附加一个数字 = 该结点左子树与右子树的深度差。这个数字称为结点的平衡因子。这样，可以得到AVL树的其它性质(可以证明) : 任一结点的平衡因子只能取: -1、0、1，如果树中任意一个结点的平衡因子的绝对值大于1,则这棵二
閑的時候 做一個屏幕 分割器 、 tablecontrol 、tablestrip 、 alv oo 還有什麽？ 類似于PA30 的效果吧
SAPer
03-21 3747
主要學習的博客轉自：http://www.abaptech.com/2008/07/alv-grid-demo/ 先記錄下爲何要用繁體吧。oh 前兒去學guitar 遇見了個外國人，在中國3、4年， 一口流利的普通話，自愧不如，人家外語怎麽就這麽好。了解到原是教中國厤史的老師，我對於祖國的歷史局限于初高中那點底子，唉。留下個聯係方式，居然是繁體的中文名字，我，慚愧，所以，開始用繁體，希望潛移默化的起到些作用吧。言歸正傳！！！！！！！！！！！！大概框架：左邊是2個tree， 涉及到的幾個類，不分先後順序：  
ABAP ALV Tree
居士爱吃泡面的博客
12-08 1786
Code listing for: ZDDTEST001 Description: ALV TREE TEST *&---------------------------------------------------------------------* *& Report  ZDDTEST001 *& *&---------------------
平衡二叉树（ALV树）
W2001r的博客
11-28 1551
一、AVL树简介   AVL树的名字来源于它的发明作者G.M. Adelson-Velsky 和 E.M. Landis。AVL树是最先发明的自平衡二叉查找树（Self-Balancing Binary Search Tree,简称平衡二叉树）。   平衡二叉树定义(AVL)：它或者是一颗空树，或者具有以下性质的二叉排序树：它的左子树和右子树的深度之差(平衡因子)的绝对值不超过1，且它的左子树和右子树都是一颗平衡二叉树。   平衡因子：将二叉树上某个节点的左子树高度减去右子树高度的值称为该节点的平衡因子BF
ALV tree应用实例
liangziyisheng的专栏
12-07 2544
本文演示如何使用cl_gui_alv_tree_simple在屏幕上展示一个alv tree 下面是一段实例代码，基本思路是这样的： 1.在屏幕上建立一块区域，基于该区域创建一个custom container 2.在创建好的custom container里面创建一个alv tree控件 3.取数 4.设置alv tree的相关属性，包括fieldcatelog和sorted talb
ooalv tree
yong_yang7644的博客
02-03 234
&amp;--------------------------------------------------------------------- *&amp; Report Z_ALV_TEST_008 *&amp; &amp;--------------------------------------------------------------------- *&amp; *&amp;...
创建list ALV tree[RS_TREE_LIST_DISPLAY]
banin4739的博客
08-30 210
ABAP程序中的ALV显示是很常用的一种数据展示手段，除了常规的alv，有时也会用到ALV tree这种有层次结构的展示方式更好的展现数据，下面介绍一个创建list alv tree的方法： 1）用函数RS_TREE_CONSTRUCT构造alv 树的层次结构， alv tree的节点类型(node type)分两种：T和P，区别如下：区别就是个文件夹的图标。 &amp...
ALV TREE + 动态显示列
阿土工作室
12-18 2653
以下程序不代表企业PRD中的真实程序.程序中带有 select * 的代码请见谅,由于并不十分影响此程序性能,因此没有修改.Description: YCOR1005_N 单船收入成本表 *---------------------------------------------------------------------** PROGRAM ID : Y
ALV Tree的使用
Violinlins
04-28 341
*&---------------------------------------------------------------------* *& Report YTEST00A *&---------------------------------------------------------------------* *&Violin 2021/3/10 *&----------------------------------------------...
评论 1
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

小飞猪猪猪猪猪猪猪

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值