PB实现链表数据结构

最新推荐文章于 2022-11-23 22:30:27 发布
最新推荐文章于 2022-11-23 22:30:27 发布
阅读量687 收藏
点赞数
文章标签： PB 链表
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/JasonFriday/article/details/91836043
版权

文章目录

初始化

创建实例并设置数据

n_linked_list ln_linked_list
any la_result[]

ln_linked_list = create n_linked_list
//设置数据
ln_linked_list.setValues({"Arthur","Brandon","Cersei","Davos"})
//查询链表全部数据
ln_linked_list.fetchAll(la_result)

return 0

在这里插入图片描述

插入数据

1.在链表头部插入数据

n_linked_list ln_linked_list
any la_result[]

ln_linked_list = create n_linked_list
//头部插入数据
ln_linked_list.unshift("Arthur")
ln_linked_list.unshift("Brandon")
ln_linked_list.unshift("Cersei")
ln_linked_list.unshift("Davos")
//查询链表全部数据
ln_linked_list.fetchAll(la_result)

return 0

在这里插入图片描述

2.在链表尾部插入数据

n_linked_list ln_linked_list
any la_result[]

ln_linked_list = create n_linked_list
//尾部插入数据
ln_linked_list.push("Arthur")
ln_linked_list.push("Brandon")
ln_linked_list.push("Cersei")
ln_linked_list.push("Davos")
//查询链表全部数据
ln_linked_list.fetchAll(la_result)

return 0

在这里插入图片描述
3.在链表任意位置插入数据

n_linked_list ln_linked_list
any la_result[]

ln_linked_list = create n_linked_list
//设置数据
ln_linked_list.setValues({"Arthur","Brandon","Cersei","Davos"})
//在链表索引为3的元素前插入数据
ln_linked_list.add(3,"addNode")
//查询链表全部数据
ln_linked_list.fetchAll(la_result)

return 0

在这里插入图片描述

删除数据

1.删除并返回链表头部数据

n_linked_list ln_linked_list
any la_result[],la_shift

ln_linked_list = create n_linked_list

//设置数据
ln_linked_list.setValues({"Arthur","Brandon","Cersei","Davos"})

//删除并返回头部数据
ln_linked_list.shift(la_shift)

//查询链表全部数据
ln_linked_list.fetchAll(la_result)

return 0

在这里插入图片描述

2.删除并返回链表尾部数据

n_linked_list ln_linked_list
any la_result[],la_pop

ln_linked_list = create n_linked_list

//设置数据
ln_linked_list.setValues({"Arthur","Brandon","Cersei","Davos"})

//删除并返回尾部数据
ln_linked_list.pop(la_pop)

//查询链表全部数据
ln_linked_list.fetchAll(la_result)

return 0

在这里插入图片描述

3.删除并返回链表任意位置数据

n_linked_list ln_linked_list
any la_result[],la_del

ln_linked_list = create n_linked_list

//设置数据
ln_linked_list.setValues({"Arthur","Brandon","Cersei","Davos"})

//删除并返回索引为3数据
ln_linked_list.del(3,la_del)

//查询链表全部数据
ln_linked_list.fetchAll(la_result)

return 0

在这里插入图片描述

查询数据

1.查询链表全部数据

n_linked_list ln_linked_list
any la_result[]

ln_linked_list = create n_linked_list
//设置数据
ln_linked_list.setValues({"Arthur","Brandon","Cersei","Davos"})
//查询链表全部数据
ln_linked_list.fetchAll(la_result)

return 0

在这里插入图片描述

2.遍历链表数据

n_linked_list ln_linked_list
any la_item
string ls_items

ln_linked_list = create n_linked_list
//设置数据
ln_linked_list.setValues({"Arthur","Brandon","Cersei","Davos"})

//遍历数据
do while ln_linked_list.fetchOne(la_item)
	ls_items += la_item + ";"
loop

return 0

在这里插入图片描述
3.查询链表长度

n_linked_list ln_linked_list
long ll_len

ln_linked_list = create n_linked_list

//设置数据
ln_linked_list.setValues({"Arthur","Brandon","Cersei","Davos"})

//查询链表长度
ll_len = ln_linked_list.length()

return 0

在这里插入图片描述
4.查询链表任意位置的数据

n_linked_list ln_linked_list
any la_get

ln_linked_list = create n_linked_list

//设置数据
ln_linked_list.setValues({"Arthur","Brandon","Cersei","Davos"})

//查询索引为3数据
ln_linked_list.get(3,la_get)

return 0

在这里插入图片描述

其他操作

1.连接链表

n_linked_list ln_linked_list,ln_linked_list2
any la_result[]

ln_linked_list = create n_linked_list
ln_linked_list2 = create n_linked_list

//设置数据
ln_linked_list.setValues({"Arthur","Brandon","Cersei","Davos"})
ln_linked_list2.setValues({"Emily","Fermi","George","Henry","Ivy"})

//连接两个链表
ln_linked_list.concat(ln_linked_list2)

//查询链表全部数据
ln_linked_list.fetchAll(la_result)

return 0

在这里插入图片描述

2.切割链表

n_linked_list ln_linked_list,ln_linked_list2
any la_result1[],la_result2[]

ln_linked_list = create n_linked_list

//设置数据
ln_linked_list.setValues({"Arthur","Brandon","Cersei","Davos"})

//在索引3位置前切割链表
ln_linked_list2 = ln_linked_list.cut(3)

//查询链表全部数据
ln_linked_list.fetchAll(la_result1)
ln_linked_list2.fetchAll(la_result2)

return 0

在这里插入图片描述
3.重置链表

n_linked_list ln_linked_list
any la_result1[],la_result2[]

ln_linked_list = create n_linked_list

//设置数据
ln_linked_list.setValues({"Arthur","Brandon","Cersei","Davos"})
//查询链表全部数据
ln_linked_list.fetchAll(la_result1)

//重置链表
ln_linked_list.reset()
//查询链表全部数据
ln_linked_list.fetchAll(la_result2)

return 0

在这里插入图片描述

源代码

发现BUG请留言或私信，以便修正（QQ：768310524 TEL：18649713925）
这部分代码拷贝到文本编辑器，另存为 n_linked_node.sru

forward
global type n_linked_node from nonvisualobject
end type
end forward

global type n_linked_node from nonvisualobject
end type
global n_linked_node n_linked_node

type variables
public:
	n_linked_node prior_node
	n_linked_node next_node
	
	any value
end variables

forward prototypes
public subroutine concat (n_linked_node node)
end prototypes

public subroutine concat (n_linked_node node);this.next_node = node
node.prior_node = this
end subroutine

on n_linked_node.create
call super::create
TriggerEvent( this, "constructor" )
end on

on n_linked_node.destroy
TriggerEvent( this, "destructor" )
call super::destroy
end on

这部分代码拷贝到文本编辑器，另存为 n_linked_list.sru

forward
global type n_linked_list from nonvisualobject
end type
end forward

global type n_linked_list from nonvisualobject
end type
global n_linked_list n_linked_list

type variables
private:
	n_linked_node first_node
	n_linked_node last_node
	
	n_linked_node prev_node
	
	long length
end variables

forward prototypes
public function long length ()
public function long pop (ref any value)
public function long shift (ref any value)
private function integer _get_node (long i, ref n_linked_node n)
public function integer get (long i, ref any value)
public function integer set (long i, any value)
public subroutine reset ()
public function n_linked_list cut (long i)
public function long add (long i, any value)
public function long push (any value)
public function long unshift (any value)
public subroutine fetchstart ()
public function boolean fetchone (ref any value)
public function long concat (n_linked_list linked_list)
public function long del (long i, ref any value)
public function long fetchall (ref any value[])
public function long setvalues (any value[])
end prototypes

public function long length ();return length
end function

public function long pop (ref any value);if not isvalid(last_node) then return -1

value = last_node.value

if first_node = last_node then
	destroy first_node
	destroy last_node
else
	last_node = last_node.prior_node
	destroy last_node.next_node
end if

length --
return length
end function

public function long shift (ref any value);if not isvalid(first_node) then return -1

value = first_node.value
if first_node = last_node then
	destroy first_node
	destroy last_node
else
	first_node = first_node.next_node
	destroy first_node.prior_node
end if

length --
return length
end function

private function integer _get_node (long i, ref n_linked_node n);if i > length then return -1

n_linked_node node
long ll_var

if i <= length / 2 then
	node = first_node
	ll_var = i
	do while ll_var > 1
		node = node.next_node
		ll_var --
	loop
else
	node = last_node
	ll_var = length - i + 1
	do while ll_var > 1
		node = node.prior_node
		ll_var --
	loop
end if

n = node
return 0
end function

public function integer get (long i, ref any value);n_linked_node node

if _get_node(i,node) < 0 then return -1

value = node.value
return 0
end function

public function integer set (long i, any value);n_linked_node node

if _get_node(i,node) < 0 then return -1

node.value = value
return 0
end function

public subroutine reset ();destroy first_node
destroy last_node
length = 0
end subroutine

public function n_linked_list cut (long i);n_linked_list linked_list
n_linked_node node,nil

linked_list = create n_linked_list

if _get_node(i,node) < 0 then return linked_list

linked_list.first_node = node
linked_list.last_node = last_node

if isvalid(node.prior_node) then
	node.prior_node.next_node = nil
	last_node = node.prior_node
else
	first_node = nil
	last_node = nil
end if
node.prior_node = nil

linked_list.length = length - i + 1
length = i - 1 

return linked_list
end function

public function long add (long i, any value);n_linked_node node,p,t

if i <= 1 then
	return unshift(value)
elseif i > length then
	return push(value)
end if

t = create n_linked_node
t.value = value

_get_node(i,node)
p = node.prior_node

p.concat(t)
t.concat(node)

length ++
return length
end function

public function long push (any value);n_linked_node node
node = create n_linked_node
node.value = value

if isvalid(last_node) then
	last_node.concat(node)
	last_node = node
else
	first_node = node
	last_node = node
end if

length ++
return length
end function

public function long unshift (any value);n_linked_node node
node = create n_linked_node
node.value = value

if isvalid(first_node) then
	node.concat(first_node)
	first_node = node
else
	first_node = node
	last_node = node
end if

length ++
return length
end function

public subroutine fetchstart ();n_linked_node nil
prev_node = nil
end subroutine

public function boolean fetchone (ref any value);if prev_node = last_node then return false

if isvalid(prev_node) then
	prev_node = prev_node.next_node
else
	if not isvalid(first_node) then return false
	prev_node = first_node
end if

value = prev_node.value
return true




end function

public function long concat (n_linked_list linked_list);n_linked_node fn,ln
long list_length

list_length = linked_list.length()
if list_length <= 0 then return length

linked_list._get_node(1,fn)
linked_list._get_node(list_length,ln)
last_node.concat(fn)
last_node = ln

length += list_length
return length
end function

public function long del (long i, ref any value);n_linked_node node,p,n

if _get_node(i,node) < 0 then return -1

if node = first_node then
	return shift(value)
elseif node = last_node then
	return pop(value)
else
	value = node.value
	p = node.prior_node
	n = node.next_node
	p.concat(n)
	destroy node
end if

return length
end function

public function long fetchall (ref any value[]);n_linked_node node
long i
any la_list[]

node = first_node
do while isvalid(node)
	i += 1
	la_list[i] = node.value
	node = node.next_node
loop

value = la_list
return i
end function

public function long setvalues (any value[]);reset()

long i,n
n_linked_node node[]

n = upperbound(value)
if n <= 0 then return 0

for i = 1 to upperbound(value)
	node[i] = create n_linked_node
	node[i].value = value[i]
next

first_node = node[1]
last_node = node[n]
length = n

if n <= 1 then return length

for i = 1 to n - 1
	node[i].concat(node[i + 1])
next

return length
end function

on n_linked_list.create
call super::create
TriggerEvent( this, "constructor" )
end on

on n_linked_list.destroy
TriggerEvent( this, "destructor" )
call super::destroy
end on
JasonFriday
关注
  • 0
    点赞
  • 踩
  • 0
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
数据结构之链表
epleone的专栏
03-13 972
题目： 1.已知单链表L是一个递增有序链表，设计一个算法，删除表中data值在大于等于min并且小于等于max之间的节点，同时释放删除节点的空间，分析时间复杂度 2.设计一个算法就地逆置单链表 3.已知三个递增有序单链表A,B,C，长度分别为m,n和p设计一个算法使链表A 仅包含三个表中均包含的数据元素，且没有重复，并释放无用节点。限定算法的时间复杂度为O(m+n+p) 链表结构体 typ
PB 代码模拟按键 API函数keybd_event 及相应的键值说明
happymagic的专栏
01-04 2958
Subroutine keybd_event(char bVk, char bScan, ulong dwFlags, ref ulong dwExtraInfo) Library "USER32.DLL" 函数定义如：  ulong ll_ExtraInfo char lc_shift, lc_tab lc_shift=char(16) lc_tab=char(9)  keybd_event(...
PB外部函数调用及方法
jackxiong
08-19 2822
//如何在PB中实现延时：subroutine Sleep(long dwMilliseconds) library "kernel32.dll"延时1秒则调用： Sleep(1000)    //单位是毫秒。     //调用API函数步骤：1、在适当的位置声明函数，如窗口内，Application内，UserObject内，定义在Local External Function或Globa...
PB数据表结构
03-03
ＰＢ数据表结构资料，供学习ＰＢ者使用草考 ＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿ 没分下不了的，可以直接联系我
C语言中数据结构之链表归并排序实例代码
08-30
本文主要介绍了C语言中数据结构之链表归并排序实例代码的相关知识点，通过对链表归并排序的实现，帮助读者深入了解链表数据结构的应用。 一、链表数据结构 链表是一种常用的数据结构，链表的每个节点都包含两部分...
c++数据结构实验：多项式相加
07-11
总的来说，这个实验展示了如何使用链表数据结构实现多项式相加，涉及到了链表的插入、遍历和合并操作，同时也体现了C++面向对象编程的思想，通过类封装多项式操作。理解这些概念对于学习数据结构和算法以及深入C++...
C数据结构之双链表详细示例分析
12-31
/*******双向链表的初始化********/NODE *Init_link(void){ int i; NODE *phead,*pb,*pi; phead = (NODE *)malloc(sizeof(NODE)); printf(“please input num:\n”); scanf(“%d”,&(phead->num)); phead->p
数据结构与算法-算法设计题
最新发布
12-23
本话题主要涉及线性表、排序算法和链表操作，这些都是数据结构与算法设计的关键组成部分。 线性表是一种基本的数据结构，通常由一系列相同类型元素构成，可以顺序存储或链式存储。在这个题目中，我们看到两个关于...
pb调用DLL文件
a78782295的专栏
09-11 3802
LiveJournal Tags: pb c 参数对应 MICROSOFT         PB(16Bit)         PB(32Bit) Bool                    Boolean         Boolean Char*                 Ref string       Ref String Colorref
在PB程序中动态修改表结构？
yishanhai的专栏
11-13 1264
  问：ORACLE 7.3 ＋ PB，在Oracle的SQL＊PLUS中可以很容易修改表结构，但如何在PB程序中动态修改表结构？比如将某一字段的长度扩大？答：用动态SQL语句，举例如下:　　string ls_Mysql 　　ls_Mysql=″alter table department modify dept_name varchar2(12)″　　sqlca.autoc
PB结构化存储与解析JSON
热门推荐
JasonFriday的博客
03-30 1万+
forward global type n_json from nonvisualobject end type type st_item from structure within n_json end type type st_name_exp from structure within n_json end type end forward type st_item from struct...
数据交换格式 - PB(protocol buffer)，xml，json，array
迟来大师的博客
12-04 3242
PB 扩充容易， 二进制 序列化简单 json xml 数组
如何在PB中调用F1控件如何插入图片（原创）
欢迎来到 Balloonman2002 之家,:)
01-05 2831
一、API声明：SUBROUTINE  CopyMemory(ref METAHEADER Destination , ref blob Source, long Length)  LIBRARY "kernel32"  Alias for "RtlMoveMemory"SUBROUTINE  CopyMemory2(ref blob Destination , ref blob Source
pb 结构
weixin_30301183的博客
06-23 769
pb中的结构structure,存储多种数据类型，相当于多个数据类型的数组，而且结构中也可以存数组。创建：直接new里面创建，创建后可以把它当作一个父对象（str_structure），想使用时，根据需求创建不同作用域的结构（全局，事件，局部），gstr_...,istr_...,lstr_...。 结构很好用，可以直接当成一个全局变量的容器，可以避免定义过多不同类型的全局变量，也可以作为参数传...
数据结构算法Day03
Winnow_的博客
11-23 358
数据结构关于单链表、循环链表的一些算法学习
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值